Question

当我尝试使用具有开关表达式的gradle构建Java代码时，会引发此错误。

error: switch expressions are a preview feature and are disabled by default.

我尝试运行./gradlew build --enable-preview，该方法也不起作用。

我正在使用Gradle 5.3.1

Answer 1

您需要配置JavaCompile任务，以便gradle在编译时将此选项传递给Java编译器。

类似的事情应该起作用：

tasks.withType(JavaCompile).each {
    it.options.compilerArgs.add('--enable-preview')
}

要运行应用/测试，我们需要添加jvmArgs 示例：

test {
    jvmArgs(['--enable-preview'])
}

Answer 2

这里是使用Gradle Kotlin DSL的另一版本，可在build.gradle.kts中使用：

plugins {
    `java-library`
}

repositories {
    mavenCentral()
}

java {
    sourceCompatibility = JavaVersion.VERSION_12
}

tasks.withType<JavaCompile> {
    options.compilerArgs.add("--enable-preview")
}
tasks.test {
    useJUnitPlatform()
    jvmArgs("--enable-preview")
}

dependencies {
    testImplementation("org.junit.jupiter:junit-jupiter-api:5.4.2")
    testImplementation("org.junit.jupiter:junit-jupiter-engine:5.4.2")
}

Answer 3

目前似乎没有一个单独的地方可以定义它。您应该对所有任务类型（编译，测试运行时或与Java exec相关的任务）执行此操作。我发现自己完全被覆盖：

tasks.withType(JavaCompile) {
    options.compilerArgs += "--enable-preview"
}

tasks.withType(Test) {
    jvmArgs += "--enable-preview"
}

tasks.withType(JavaExec) {
    jvmArgs += '--enable-preview'
}

如何使用Gradle启用Java 12预览功能？

3 个答案: