Question

我有一个Antlr4语法，在尝试解析表达式时会陷入无限循环。

运行Antlr 4.7版 Java 1.8

表达式看起来像这样：

monkey =Å

但是如果正确的变量是字符串，它就可以工作：

monkey =“Å”

或者看起来像这样：

monkey = A

Antlr在卡住之前打印的最后一条消息是：

第1行：5行输入不匹配”，预计{NUMBER，STRING，BOOLEAN， 'EMPTY'，'NULL'}

可悲的是，我不是Antlr的专家，我已经尝试阅读它，但无法弄清楚。

这是我的语法文件：

grammar MyObjectFilter;


/*
 * Lexer rules
*/

fragment DIGIT : [0-9] ;

NUMBER     : DIGIT+ ([.,] DIGIT+)?;
// Non-greedy String expression that also removes the quotes from the    string
STRING     : '"' ( '\\"' | . )*? '"'  {setText(getText().substring(1, getText().length()-1));} ; 
BOOLEAN    : 'true' | 'false';
EMPTY      : 'EMPTY';
NULL       : 'NULL';

// Remove the $ sign from the start of the identifier
IDENTIFIER : [a-zA-Z][a-zA-Z0-9._-]* ;
VALUE      : [0-9]*;

AND        : '&&' ;
OR         : '||' ;
NOT        : '!' ;
NEQ        : '!=' ;
GT         : '>' ;
GE         : '>=' ;
LT         : '<' ;
LE         : '<=' ;
EQ         : '=' ;
LPAREN     : '(' ;
RPAREN     : ')' ;

WS         : [ \r\t\u000C\n]+ -> skip;

/*
 * Parser rules
*/
parse
: expression EOF
;

expression
: LPAREN expression RPAREN                       #parenExpression
| NOT expression                                 #notExpression
| left=identifier op=comparator right=value      #comparatorExpression
| left=expression op=binary right=expression     #binaryExpression
;

identifier
: IDENTIFIER 
;

value
: STRING | NUMBER | BOOLEAN | EMPTY | NULL
;

comparator
: GT | GE | LT | LE | EQ | NEQ
;

binary
: AND | OR
;

使用以下方法初始化它：

InputStream stream = new ByteArrayInputStream(definition.getBytes(StandardCharsets.UTF_8));
MyObjectFilterLexer lexer = new MyObjectFilterLexer(CharStreams.fromStream(stream, StandardCharsets.UTF_8));
MyObjectFilterParser parser = new WTObjectFilterParser(new CommonTokenStream(lexer));

//This is where it get stuck.
ExpressionContext expr = parser.expression();

我最好的猜测是它无法确定表达式的EOF。

Answer 1

有一个词法分析器规则，它匹配零宽度标记（数量无限）：

VALUE      : [0-9]*;

将其更改为：

VALUE      : [0-9]+;

Antlr4Åchar字符无限循环

1 个答案: