Question

我使用Labview生成一个Excel报告，该报告本质上是将数组粘贴到电子表格中。电子表格中存在空白，例如：

但是因为我要在电子表格中插入一个数组，所以空白是空的，但并不是空白。

当我运行vba代码使用“ IsEmpty”检查每个单元格时，它将返回true。但是，如果我使用“ ISBLANK”运行excel公式，则返回false。我已经尝试了以下方法，但是它不会使单元格空白。

If IsEmpty(Cells(r,c)) Then
    Cells(r,c).Value = ""
    Cells(r,c).ClearContents
    Cells(r,c) = ""

我想使单元格为空白而不必删除它们。这是因为我试图在我的VBA代码中使用.End，但它并没有止步不前。

Answer 1

您无需检查IsEmpty()，而是：

If Cells(r, c).Value = "" Then Cells.ClearContents

这将删除 Nulls 。 Null是指零长度的字符串。

Answer 2

这可能有点过分，但是对您有用：

Sub tgr()

    Dim ws As Worksheet
    Dim rClear As Range
    Dim aData As Variant
    Dim lRowStart As Long
    Dim lColStart As Long
    Dim i As Long, j As Long

    Set ws = ActiveWorkbook.ActiveSheet
    With ws.UsedRange
        If .Cells.Count = 1 Then
            ReDim aData(1 To 1, 1 To 1)
            aData = .Value
        Else
            aData = .Value
        End If
        lRowStart = .Row
        lColStart = .Column
    End With

    For i = LBound(aData, 1) To UBound(aData, 1)
        For j = LBound(aData, 2) To UBound(aData, 2)
            If Len(Trim(aData(i, j))) = 0 Then
                If rClear Is Nothing Then
                    Set rClear = ws.Cells(lRowStart + i - 1, lColStart + j - 1)
                Else
                    Set rClear = Union(rClear, ws.Cells(lRowStart + i - 1, lColStart + j - 1))
                End If
            End If
        Next j
    Next i

    If Not rClear Is Nothing Then rClear.ClearContents

End Sub

如何在VBA中使单元格“空白”，而不是“空”

2 个答案: