Question

我正在使用SPARQL和Python向DBPedia发出请求。

可悲的是，当我发送带有特殊字符（如括号）的请求时，总是会出错。

我试图用反斜杠将其转义（如下面的代码所示），但是它不起作用。

我读到我可以指定整个URI，但它也不起作用（但是我可能没有以正确的方式完成操作）。

有人考虑到我已有的请求，是否还有其他选择，或者可以提供一个示例，说明如何使用整个URI编写请求？

query = """
    PREFIX : <http://dbpedia.org/resource/>
    SELECT DISTINCT ?s ?p ?o WHERE {
       {
           ?s ?p ?o
           FILTER (?s=:Grimaldi_\(crater\))

       }
    }
    """

这是我得到的错误：

QueryBadFormed: QueryBadFormed: a bad request has been sent to the endpoint, probably the sparql query is bad formed.

Response:   b"Virtuoso 37000 Error SP030: SPARQL compiler, line 0: Bad character '\\' (0x5c) in SPARQL expression at '\\'\n\nSPARQL query:\n\n#output-format:application/sparql-results+json\n\n PREFIX : <http://dbpedia.org/resource/>\nSELECT DISTINCT ?s ?p ?o WHERE {\n {\n ?s ?p ?o\n FILTER (?s=:Grimaldi_\\(crater\\))\n\n }\n}\n"

Answer 1

full URI definitely works，如-

SELECT DISTINCT ?s ?p ?o WHERE {
   {
       ?s ?p ?o
       FILTER ( ?s = <http://dbpedia.org/resource/Grimaldi_(crater)> )
   }
}

Virtuoso v7处理带反斜杠的前缀名称时存在一个打开的错误（例如:Grimaldi_\(crater\)和PREFIX : <http://dbpedia.org/resource/>，或者更常见的dbr:Grimaldi_\(crater\)和{{1 }}）。请将您的声音添加到the github issue中，以提高其优先级。

前缀名称中的反斜杠转义现在可以在支持DBpedia实例的Virtuoso 7（0 {20.3230，从commit 5f68a2e2f2, 2019-04-01开始）中正常运行。

Answer 2

我们已解决此问题（特定于7.x，而不是更新的8.x版本），并将其应用于DBpedia-Snapshot和DBpedia-Live实例后面的Virtuoso实例。

查询：

PREFIX : <http://dbpedia.org/resource/>
SELECT DISTINCT ?s ?p ?o WHERE {
       {
           ?s ?p ?o
           FILTER (?s=:Grimaldi_\(crater\))

       }
    }

实时DBpedia快照SPARQL查询定义： Link

实时DBpedia-实时SPARQL查询定义： Link

另一个基于URL中逗号（,）的示例。请注意，原始查询已更改为添加反斜杠（\）以使其起作用。

查询：

PREFIX dbo: <http://dbpedia.org/ontology/>
PREFIX dbp: <http://dbpedia.org/property/>
PREFIX dbr: <http://dbpedia.org/resource/>
PREFIX grs: <http://www.georss.org/georss/>
PREFIX geo: <http://www.w3.org/2003/01/geo/wgs84_pos#>

SELECT ?label ?country ?isPartOf ?_type ?capital ?lcity ?geopoint
WHERE {
        { dbr:Eraring\,_New_South_Wales rdfs:label ?label  .  FILTER(LANGMATCHES(LANG(?label), "en"))}
          UNION{OPTIONAL{dbr:Eraring\,_New_South_Wales dbo:country ?country} }
          UNION{OPTIONAL{dbr:Eraring\,_New_South_Wales dbo:isPartOf ?isPartOf}}
          UNION{OPTIONAL{dbr:Eraring\,_New_South_Wales <http://purl.org/linguistics/gold/hypernym> ?_type}}
          UNION{OPTIONAL{dbr:Eraring\,_New_South_Wales dbo:capital ?capital}}
          UNION{OPTIONAL{dbr:Eraring\,_New_South_Wales dbo:largestCity ?lcity}}
          UNION{OPTIONAL{dbr:Eraring\,_New_South_Wales grs:point ?geopoint}}
  }

实时SPARQL查询定义： Link

如何在SPARQL前缀名称中转义特殊字符？

2 个答案: