Question

我正在尝试对国际象棋进行基于属性的测试。我设置了以下类型类

class Monad m => HasCheck m where                                                   
    isCollision :: Coord -> m Bool

检查给定坐标是否包含冲突或超出范围。

现在我有一个函数可以为骑士生成允许动作的移动集，如下所示：

collisionKnightRule :: HasCheck m => Coord -> m (Set Coord)                      
collisionKnightRule =                                                            
    Set.filterM isCollision . knightMoveSet                                      


-- | Set of all moves, legal or not                                              
knightMoveSet :: Coord -> Set Coord                                              
knightMoveSet (x,y) =                                                            
    Set.fromList                                                                 
        [ (x+2,y-1),(x+2,y+1),(x-2,y-1),(x-2,y+1)                                
        , (x+1,y-2),(x+1,y+2),(x-1,y-2),(x-1,y+2)                                
        ]                                                                        



knightMoves :: HasCheck m => Coord -> m (Set Coord)                              
knightMoves pos =                                                                
    do  let moveSet =                                                            
                knightMoveSet pos                                                
        invalidMoves <- collisionKnightRule pos                                        
        return $ Set.difference moveSet invalidMoves

以及HasCheck类的实例以获取任意坐标

instance HasCheck Gen where                                                      
    isCollision _ =                                                              
         Quickcheck.arbitrary

，因此在以后进行测试时，我想确保生成的移动集是所有可能移动的正确子集。

knightSetProperty :: Piece.HasCheck Gen                                          
    => (Int,Int)                                                                 
    -> Gen Bool                                                                  
knightSetProperty position =                                                     
    do  moves <- Piece.knightMoves position                                      
        return $ moves `Set.isProperSubsetOf` (Piece.knightMoveSet position)

-- ... later on

it "Knight ruleset is subset" $                                          
            quickCheck knightSetProperty

这当然会失败，因为骑士可能无法移动到任何地方，这意味着它不是适当的子集，而是相同的集合。但是，报告的错误不是特别有用

*** Failed! Falsifiable (after 14 tests and 3 shrinks):  
(0,0)

这是因为quickcheck不会报告isCollision的生成值。因此，我想知道如何使quickCheck报告isCollision的生成值？

Answer 1

好的，我觉得这应该可以用其他方式解决。但是，我提出了以下受handler pattern启发的解决方案。

我将HasCheck类型类更改为一条记录，如下所示：

data Handle = MakeHandle                                                                   
    { isCollision   :: Coord -> Bool                                                   
    }

，然后将所有代码重构为使用handle而不是HasCheck。

collisionKnightRule :: Handle -> Coord -> (Set Coord)                            
collisionKnightRule handle =                                                     
    Set.filter (isCollision handle) . knightMoveSet                              


-- | Set of all moves, legal or not                                              
knightMoveSet :: Coord -> Set Coord                                              
knightMoveSet (x,y) =                                                            
    Set.fromList                                                                 
        [ (x+2,y-1),(x+2,y+1),(x-2,y-1),(x-2,y+1)                                
        , (x+1,y-2),(x+1,y+2),(x-1,y-2),(x-1,y+2)                                
        ]                                                                        


-- | Set of illegal moves                                                        
knightRuleSet :: Handle -> Coord -> (Set Coord)                                  
knightRuleSet =                                                                  
    collisionKnightRule                                                          


knightMoves :: Handle -> Coord -> (Set Coord)                                    
knightMoves handle pos =                                                         
    let                                                                          
        moveSet =                                                                
            knightMoveSet pos                                                    

        invalidMoves =                                                           
            knightRuleSet handle pos                                             
    in                                                                           
        Set.difference moveSet invalidMoves

这样做的缺点是我担心对于有状态代码，在传递过时的句柄（即I.E.）时，很容易引入错误。有多种真相优点是，这对于Haskell的新手来说可能更容易理解。现在，我们可以使用Quickcheck的Function类型类对函数进行模拟，并将它们作为参数传递给它，以创建模拟处理机：

knightSetProperty ::                                                                 
    Fun (Int,Int) Bool                                                               
    -> (Int,Int)                                                                     
    -> Gen Bool                                                                      
knightSetProperty (Fun _ isCollision) position =                
    let                                                                              
        handler = 
            Piece.MakeHandle isCollision                           
        moveSet =                                                                      
            Piece.knightMoves handler position                                       
    in                                                                               
        return $ moveSet `Set.isProperSubsetOf` (Piece.knightMoveSet position)

现在这会以一个反例正常失败：

*** Failed! Falsifiable (after 53 tests and 74 shrinks):     
{_->False}
(0,0)

使用类型类约束进行快速检查并报告生成的值？

1 个答案: