Question

我有一对大小相等的数组，我将它们称为键和值。

例如：

对键进行排序，并将与每个键关联的值相关联排序。如何删除与每个键关联的值重复及其对应的密钥？

也就是说，我想将上述内容压缩为：

1: 99
1: 100
1: 103
2: 103 <-- This should remain, since key is different
2: 105
3: 45
3: 67

我查看了 Thrust 中提供的流压缩功能，但是无法找到任何这样做的东西。这有可能吗？推力？或者我是否需要编写自己的内核来标记重复项模板，然后删除它们？

Answer 1

对键进行排序，并且还对与每个键关联的值进行排序。因此，我们可以考虑对键值对进行排序。 thrust::unique如果可以将这两个向量看作单个向量，它将直接在此工作。这可以通过使用zip_iterator将每个位置的2个项目（键值）压缩为单个元组来实现。

以下是如何在原地实现此功能，并将键值向量修剪为仅包含唯一元素：

typedef thrust::device_vector< int >                IntVector;
typedef IntVector::iterator                         IntIterator;
typedef thrust::tuple< IntIterator, IntIterator >   IntIteratorTuple;
typedef thrust::zip_iterator< IntIteratorTuple >    ZipIterator;

IntVector keyVector;
IntVector valVector;

ZipIterator newEnd = thrust::unique( thrust::make_zip_iterator( thrust::make_tuple( keyVector.begin(), valVector.begin() ) ),
                                     thrust::make_zip_iterator( thrust::make_tuple( keyVector.end(), valVector.end() ) ) );

IntIteratorTuple endTuple = newEnd.get_iterator_tuple();

keyVector.erase( thrust::get<0>( endTuple ), keyVector.end() );
valVector.erase( thrust::get<1>( endTuple ), valVector.end() );

如果要压缩并生成单独的结果流，则需要为您的类型编写自己的二元谓词，以查看元组的两个元素。 thrust::zip_iterator可用于从单独的数组中形成虚拟元组迭代器。

一个完整的工作示例，说明如何执行此操作：

#include <iostream>
#include <thrust/tuple.h>
#include <thrust/functional.h>
#include <thrust/device_vector.h>
#include <thrust/iterator/zip_iterator.h>
#include <thrust/unique.h>

// Binary predicate for a tuple pair
typedef thrust::tuple<int, int> tuple_t;
struct tupleEqual
{
  __host__ __device__
    bool operator()(tuple_t x, tuple_t y)
    {
      return ( (x.get<0>()== y.get<0>()) && (x.get<1>() == y.get<1>()) );
    }
};

typedef thrust::device_vector<int>::iterator  intIterator;
typedef thrust::tuple<intIterator, intIterator> intIteratorTuple;
typedef thrust::zip_iterator<intIteratorTuple> zipIterator;
typedef thrust::device_vector<tuple_t>::iterator tupleIterator;

int main(void)
{
  thrust::device_vector<int> k(9), v(9);
  thrust::device_vector<tuple_t> kvcopy(9);

  k[0] = 1; k[1] = 1; k[2] = 1; 
  k[3] = 1; k[4] = 1; k[5] = 2;
  k[6] = 2; k[7] = 3; k[8] = 3;

  v[0] = 99;  v[1] = 100; v[2] = 100;
  v[3] = 100; v[4] = 103; v[5] = 103;
  v[6] = 105; v[7] = 45;  v[8] = 67;

  zipIterator kvBegin(thrust::make_tuple(k.begin(),v.begin()));
  zipIterator kvEnd(thrust::make_tuple(k.end(),v.end()));
  thrust::copy(kvBegin, kvEnd, kvcopy.begin());

  tupleIterator kvend = 
        thrust::unique(kvcopy.begin(), kvcopy.end(), tupleEqual());

  for(tupleIterator kvi = kvcopy.begin(); kvi != kvend; kvi++) {
    tuple_t r = *kvi;
    std::cout << r.get<0>() << "," << r.get<1>() << std::endl;
  }

  return 0;
}

Answer 2

通过一点准备就可以进行流压缩。您基本上可以为每个键值对启动一个线程，检查前一个键值对是否等于，如果不是：在与这些对相同大小的单独数组中设置一个标志（int = 1）。所有其他标志仍未设置（int = 0）。然后根据标志数组流式传输键值对的压缩。

Thrust：删除键值数组中的重复项

2 个答案: