XSLT-如何基于分隔符分割字符串并将值分配给多个属性

时间：2019-03-13 23:47:41

标签： xml xslt split xslt-1.0

输入XML：

<testng-results>
<suite>
    <test>
        <class>
            <test-method status="PASS" description="Test_ID:123,Test_Name:Test ABC,Product:Product ABC"></test-method>
            <test-method status="PASS" description="Test_ID:456,Test_Name:Test XYZ,Product:Product XYZ"></test-method>
        </class>
    </test>
</suite>
</testng-results>

我当前的XSLT：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
   <xsl:template match="/">
  <Suite>
     <xsl:for-each select="testng-results/suite/test/class/test-method">
        <test>
           <xsl:attribute name="status">
              <xsl:value-of select="@status" />
           </xsl:attribute>
           <xsl:attribute name="Test_ID">
              <xsl:value-of select="" />
           </xsl:attribute>
           <xsl:attribute name="Test_Name">
              <xsl:value-of select="" />
           </xsl:attribute>
           <xsl:attribute name="Product">
              <xsl:value-of select="" />
           </xsl:attribute>
        </test>
     </xsl:for-each>
  </Suite>

预期输出XML：

<?xml version="1.0" encoding="UTF-8"?>
<Suite>
   <test status="PASS" Test_ID="123" Test_Name="Test ABC" Product="Product ABC" />
   <test status="PASS" Test_ID="456" Test_Name="Test XYZ" Product="Product XYZ" />
</Suite>

我必须从'description'值中获取字符串，并拆分这些值以生成输出xml。

我已经读到XSLT 2.0更好地配备了字符串标记化功能。但是，我只能使用XSLT 1.0。

3 个答案:

答案 0 :(得分：1)

我提出了这种方法。这很粗糙，但是可以肯定，因为它仅基于标准XSLT元素和功能：

（要标记化，它实现了一种递归算法。）

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

<xsl:output method="xml" version="1.0" indent="yes"/>

<xsl:template match="/">
    <Suite>
        <xsl:apply-templates select="testng-results/suite/test/class/test-method"></xsl:apply-templates>
    </Suite>
</xsl:template>

<xsl:template match="test-method">
    <test>
        <xsl:call-template name="tokenize-to-attrs">
            <xsl:with-param name="s" select="@description"/>
        </xsl:call-template>
    </test> 
</xsl:template>

<xsl:template name="tokenize-to-attrs">
    <xsl:param name="s"/>
    <xsl:variable name="pair" select="substring-before($s, ',')"/>
    <xsl:if test="$pair">
        <xsl:call-template name="to-attr">
            <xsl:with-param name="s" select="$pair"/>
        </xsl:call-template>
        <xsl:call-template name="tokenize-to-attrs">
            <xsl:with-param name="s" select="substring-after($s, ',')"/>
        </xsl:call-template>
    </xsl:if>
    <xsl:if test="not($pair)">
        <xsl:call-template name="to-attr">
            <xsl:with-param name="s" select="$s"/>
        </xsl:call-template>
    </xsl:if>
</xsl:template>

<xsl:template name="to-attr">
    <xsl:param name="s"/>
    <xsl:variable name="name" select="substring-before($s, ':')"/>
    <xsl:variable name="value" select="substring-after($s, ':')"/>
    <xsl:attribute name="{$name}">
        <xsl:value-of select="$value"/>
    </xsl:attribute>
</xsl:template>

</xsl:stylesheet>

答案 1 :(得分：1)

您可以使用命名模板通过使用xsl:call-template检索适当的值来实现此目的。

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
   <xsl:template match="/">
      <Suite>
         <xsl:for-each select="testng-results/suite/test/class/test-method">
            <test>
               <xsl:attribute name="status">
                  <xsl:value-of select="@status" />
               </xsl:attribute>
               <xsl:attribute name="Test_ID">
                  <xsl:call-template name="subElem">
                      <xsl:with-param name="str" select="@description" />
                      <xsl:with-param name="itemName" select="'Test_ID'" />
                  </xsl:call-template>
               </xsl:attribute>
               <xsl:attribute name="Test_Name">
                  <xsl:call-template name="subElem">
                      <xsl:with-param name="str" select="@description" />
                      <xsl:with-param name="itemName" select="'Test_Name'" />
                  </xsl:call-template>
               </xsl:attribute>
               <xsl:attribute name="Product">
                  <xsl:call-template name="subElem">
                      <xsl:with-param name="str" select="@description" />
                      <xsl:with-param name="itemName" select="'Product'" />
                  </xsl:call-template>
               </xsl:attribute>
            </test>
         </xsl:for-each>
      </Suite>
  </xsl:template>

  <xsl:template name="subElem">
      <xsl:param name="str" />
      <xsl:param name="itemName" />
      <xsl:variable name="res" select="substring-after(substring-after($str,$itemName),':')" />
      <xsl:choose>
          <xsl:when test="contains($res,',')">
              <xsl:value-of select="substring-before($res,',')" />
          </xsl:when>     
          <xsl:otherwise>
              <xsl:value-of select="$res" />
          </xsl:otherwise>
      </xsl:choose>
  </xsl:template>

</xsl:stylesheet>

按名称检索各个项目。

其输出为： 

<?xml version="1.0"?>
<Suite>
    <test status="PASS" Test_ID="123" Test_Name="Test ABC" Product="Product ABC"/>
    <test status="PASS" Test_ID="456" Test_Name="Test XYZ" Product="Product XYZ"/>
</Suite>

答案 2 :(得分：1)

如果处理器支持EXSLT str:tokenize()扩展功能，则可以执行以下操作：

XSLT 1.0 + EXSLT 

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:str="http://exslt.org/strings"
extension-element-prefixes="str">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:template match="/testng-results">
    <Suite>
        <xsl:for-each select="suite/test/class/test-method">
            <test status="{@status}" >
                <xsl:for-each select="str:tokenize(@description, ',')">
                    <xsl:attribute name="{substring-before(., ':')}">
                        <xsl:value-of select="substring-after(., ':')" />
                    </xsl:attribute>
                </xsl:for-each>
            </test>
        </xsl:for-each>
    </Suite>
</xsl:template>

</xsl:stylesheet>

否则，您可以使用字符串函数提取3个必需值中的每一个：

XSLT 1.0 

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:template match="/testng-results">
    <Suite>
        <xsl:for-each select="suite/test/class/test-method">
            <test 
                status="{@status}" 
                Test_ID="{substring-before(substring-after(@description, 'Test_ID:'), ',') }" 
                Test_Name="{substring-before(substring-after(@description, 'Test_Name:'), ',') }" 
                Product="{substring-after(@description, 'Product:')}"/>
        </xsl:for-each>
    </Suite>
</xsl:template>

</xsl:stylesheet>
相关问题
最新问题