Question

我有一个如下所示的数据透视表：

问题：捐赠者不会像捐赠者那样累加总数。这是因为捐赠者的年龄范围是根据礼物的日期确定的，并且在一年的时间内捐赠者可以跨越年龄范围。

请求：我希望DAX公式将捐助者限制在一个范围内。在理想的世界中，这将基于他们在一年中的大部分时间所处的年龄范围而定，但我会选择任意保留其中一个来解决。我相信在SQL中，您可以通过分区和排名来解决这个问题。

基础表格样本：

| Donation_ID | Donor_ID | Donation_Date | Amount | age at time of gift | summary_range |
|-------------|----------|---------------|--------|---------------------|---------------|
|           1 |      100 | 3/15/2017     |    400 |                  39 | <40           |
|           2 |      101 | 4/3/2017      |     50 |                  69 | 60-69         |
|           3 |      100 | 5/30/2017     |     15 |                  40 | 40-49         |
|           4 |      101 | 10/7/2017     |     20 |                  69 | 60-69         |
|           5 |      100 | 1/23/2018     |    220 |                  40 | 40-49         |
|           6 |      101 | 2/17/2018     |     25 |                  70 | 70+           |

更新-我在DaxStudio中使用了以下代码。但是随后在Excel中失败，并说“ summaryizecolumns不能具有外部过滤器上下文”。根据下一页底部的脚注，显然这只是Excel的局限性：https://www.sqlbi.com/articles/introducing-summarizecolumns/

EVALUATE(

// filter context of the pivot table EXCEPT no filter on age range
var fc = CALCULATETABLE(
    data_table,
    data_table[Donation_Date] >= date(2017,3,1),
    data_table[Donation_Date] <= date(2018,2,28)
)

var hh = SUMMARIZECOLUMNS(data_table[Donor_ID], data_table[summary_range],data_table[age at time of gift], fc)

var ranked = 
ADDCOLUMNS(
    hh,
    "RankByAge",
    RANKX (
        FILTER(
            SUMMARIZECOLUMNS(
                data_table[Donor_ID],data_table[age at time of gift],
                hh
            ),
            data_table[Donor_ID] = EARLIER(data_table[Donor_ID])
        ),
    data_table[age at time of gift],
    ,
    desc,
    DENSE
    )
)

return 

// ultimately need to count the rows rather than just return them
// the second criteria would come from the filter context in Excel
FILTER(ranked, [RankByAge] = 1 && [summary_range] = "<40" )

)

Answer 1

我认为最简单的方法是创建几个计算列以代替使用。

让我们通过为每个捐赠者选择最新捐赠的年龄来创建一个独特的年龄。

MaxAge =
    CALCULATE(
        MAX(data_table[ageattimeofgift]),
        ALLEXCEPT(data_table, data_table[Donor_ID])
    )

然后查找与此年龄相关的范围。

MaxRange =
    LOOKUPVALUE(
        data_table[summary_range],
        data_table[ageattimeofgift],
        data_table[MaxAge]
    )

在数据透视表中使用它代替summary_range。

（注意：如果需要，您也可以按会计年度对MaxAge进行分区，以便捐赠者可以在分别查看年份时在组之间移动。）

一种更动态的方法是使用一种可以在过滤器上下文中读取的度量。

Distinct Donors =
VAR CurrentRange =
    VALUES ( data_table[summary_range] )
VAR Summary =
    SUMMARIZE (
        ALLSELECTED ( data_table ),
        data_table[Donor_ID],
        "MaxAge", MAX ( data_table[ageattimeofgift] ),
        "Amount", SUM ( data_table[Amount] )
    )
VAR MaxRange =
    ADDCOLUMNS (
        Summary,
        "MaxRange",
        LOOKUPVALUE (
            data_table[summary_range],
            data_table[ageattimeofgift], [MaxAge]
        )
    )
RETURN
COUNTROWS(
  FILTER(
    MaxRange,
    CONTAINS(
        CurrentRange,
        [summary_range],
        [MaxRange]
    )
  )

）

请注意，我使用的是SUMMARIZE而不是SUMMARIZECOLUMNS。有关这些功能在不同环境中的区别和局限性的更多信息，请参阅this article。

您可以在RETURN之后使用以下内容来获取相应的金额。

SUMX ( FILTER ( MaxRange, [MaxRange] IN CurrentRange ), [Amount] )

注意：上面的IN语法是较新的功能。使用CONTAINS函数可向后兼容。

需要DAX公式来排名和消除重复项

1 个答案: