Question

我想在字符串处理中使用NVL2函数，例如

some_variable := nvl2 (other_variable, '.' || other_variable, '');

为此，我收到错误消息

PLS-00201: identifier 'NVL2' must be declared

令人惊讶的是，

some_variable := nvl (other_variable, '');

除了使用if-then-end之外，还有什么帮助吗？

谢谢扬

Answer 1

根据此link，nvl2仅适用于SQL，不适用于PLSQL

您可以像下面这样使用

select nvl2 (other_variable, '.' || other_variable, '') into some_variable from dual;

Answer 2

您还可以在PL / SQL中直接使用一个case表达式（这样可以避免上下文往返于SQL引擎）：

DECLARE
  v_chk VARCHAR2(1);
  v_not_null VARCHAR2(1) := 'B';
  v_null VARCHAR2(1) := 'C';
  v_res VARCHAR2(1);
BEGIN
  v_res := CASE WHEN v_chk IS NOT NULL THEN v_not_null
                ELSE v_null
           END;
  dbms_output.put_line('v_chk = "'||v_chk||'", v_res = "'||v_res||'"');

  v_chk := 'A';
  v_res := CASE WHEN v_chk IS NOT NULL THEN v_not_null
                ELSE v_null
           END;
  dbms_output.put_line('v_chk = "'||v_chk||'", v_res = "'||v_res||'"');
END;
/

v_chk = "", v_res = "C"
v_chk = "A", v_res = "B"

Answer 3

我创建了一个函数，因此我可以像在plsql中使用nvl2一样使用它，它也可能适合您的目的

create or replace FUNCTION NVL2
( p_value                  IN VARCHAR2,
  p_newval_if_not_null     IN VARCHAR2,
  p_newval_if_null         IN VARCHAR2 ) RETURN VARCHAR2 DETERMINISTIC IS

BEGIN

  IF p_value IS NOT NULL THEN
    RETURN(p_newval_if_not_null);
  ELSE
    RETURN(p_newval_if_null);
  END IF;

END;

然后可以根据需要重新创建它以使用不同的数据类型

varchar处理中使用的PL / SQL中的NVL与NVL2

3 个答案: