Question

大概有许多emacs用户，我有自己的emacs配置文件~/.emacs.d/init.el，用于以自己喜欢的方式配置emacs。因此，当我开始使用新机器时，会将我的emacs配置文件复制到其中。现在，问题在于我的emacs配置文件取决于我通过emacs软件包管理器安装的一些软件包，但是由于缺少软件包，我无法成功安装软件包。

我当然可以在没有配置文件（emacs -q的情况下启动emacs，但是问题是只有默认存储库可用，因此我无法实际安装为了成功启动而需要安装的软件包带有我的配置文件的emacs。

因此，我通常要做的是暂时注释掉我的emacs配置文件中的内容，以便能够成功安装软件包，然后取消注释并使用完整配置重新启动emacs。但这很麻烦，在我注释掉所有需要的内容之前，通常需要尝试几次。当然，肯定有更好的方法让我丢失了吗？

Answer 1

您可以将用于安装所需软件包的初始化elisp放在单独的文件中，然后启动emacs -q，然后加载并评估软件包elisp文件。

我在自己的文件中使用以下代码来处理软件包。这段代码还定义了我正在使用的软件包，并允许动态添加和加载软件包。

如果您首先从init.el加载此文件，那么您也许可以照常启动Emacs，并且缺少的必需软件包将自动安装。

更新

使用defvar定义软件包列表变量的方式使我有些不安。我已经阅读并修复了以下代码，现在将其defvar变量my-packages-package-list，然后setq固定到要安装的软件包列表中。据我了解，这是定义和使用变量的更惯用的方式。结果，此代码现在已字节编译，没有任何警告。

对于感兴趣的人，可以在here和Emacs` manual中找到使用defvar和setq的一些信息。

(require 'package)

(setq package-archives '(("gnu" . "https://elpa.gnu.org/packages/")
                         ;; ("marmalade" . "https://marmalade-repo.org/packages/")
                         ("melpa" . "https://melpa.org/packages/")
             ("org" . "https://orgmode.org/elpa/")))


(setq package-archive-priorities '(("melpa" . 10)
                   ("gnu" . 5)
                   ("org" . 2)
                   ;; ("marmalade" . 0)
                   ))

(package-initialize)

(when (not package-archive-contents)
  (package-refresh-contents))

;; the following code will install packages listed in myPackages if
;; they are not already installed
;; https://realpython.com/emacs-the-best-python-editor/

(defvar my-packages-package-list "List of custom packages to install.")

;;; this allows for dynamically update and install packages while
;;; Emacs is running, by modifying this list, and then evaluating it
;;; and tha mapc expression below it
(setq my-packages-package-list
      '(;; add the ein package (Emacs ipython notebook)
    ein

    ;; python development environment
    elpy

    ;; beutify python code
    py-autopep8

    ;; git emacs interface
    magit

    ;; debuggers front end
    realgud

    ;; multiple major mode for web editing
    ;; multi-web-mode

    ;; major mode for editing web templates
    web-mode

    ;; docker modes
    docker-compose-mode
    dockerfile-mode

    ;; list library for emacs
    dash
    ;; collection of useful combinators for emacs lisp
    dash-functional

    ;; major modes for yaml
    yaml-mode

    ;; major modes for markdown
    markdown-mode

    ;; major modes for lua
    lua-mode

    ;; major modes for fvwm config files
    fvwm-mode

    ;; treat undo history as a tree
    undo-tree

    ;; flychek
    ;; flychek-clojure
    ;; flychek-pycheckers

    ;; Clojure for the brave and true - below; amit - some packages
    ;; commented out by me until I'll be sure they are needed

    ;; makes handling lisp expressions much, much easier
    ;; Cheatsheet: http://www.emacswiki.org/emacs/PareditCheatsheet
    paredit

    ;; key bindings and code colorization for Clojure
    ;; https://github.com/clojure-emacs/clojure-mode
    clojure-mode

    ;; extra syntax highlighting for clojure
    clojure-mode-extra-font-locking

    ;; integration with a Clojure REPL
    ;; https://github.com/clojure-emacs/cider
    cider

    ;; allow ido usage in as many contexts as possible. see
    ;; customizations/navigation.el line 23 for a description
    ;; of ido
    ;; ido-ubiquitous

    ;; Enhances M-x to allow easier execution of commands. Provides
    ;; a filterable list of possible commands in the minibuffer
    ;; http://www.emacswiki.org/emacs/Smex
    ;; smex

    ;; project navigation
    ;; projectile

    ;; colorful parenthesis matching
    rainbow-delimiters

    ;; solarized theme
    solarized-theme

    ;; edit html tags like sexps
    ;; tagedit

    ;; help finding keys
    which-key

    ;; xkcd
    xkcd

    ;; Clojure exercises
    4clojure
))

(mapc #'(lambda (package)
    (unless (package-installed-p package)
      (package-install package)))
      my-packages-package-list)

Answer 2

您可以做的是声明您使用的软件包。然后添加一些每次打开Emacs时运行的代码。它检查该列表中的每个软件包是否已安装。如果不是，它将安装它。

我的config file中的一个简短示例：

;; first, declare repositories
(setq package-archives
      '(("gnu" . "http://elpa.gnu.org/packages/")
        ("marmalade" . "http://marmalade-repo.org/packages/")
        ("melpa" . "http://melpa.org/packages/")))

;; Init the package facility
(require 'package)
(package-initialize)
;; (package-refresh-contents) ;; this line is commented 
;; since refreshing packages is time-consuming and should be done on demand

;; Declare packages
(setq my-packages
      '(cider
        projectile
        clojure-mode
        expand-region
        helm
        jinja2-mode
        magit
        markdown-mode
        paredit
        wrap-region
        yaml-mode
        json-mode))

;; Iterate on packages and install missing ones
(dolist (pkg my-packages)
  (unless (package-installed-p pkg)
    (package-install pkg)))

你很好。

使用init.el和软件包安装在新计算机上设置emacs

2 个答案: