Question

我们想使用'awk'插入数组中的数据。我有一个数组

1 1 3 3 ...
3 3 5 3
5 5 6 5
6 6 6 5

我们想要获得的

1 1 3 3 ...
2 2 4 4
3 3 5 3
4 4 5.5 4
5 5 6 5
6 6 6 5

这样做可以使我们拥有一个完整的数组，该数组覆盖代表时间轴的第一列的所有可能数据。第2列及更多是数据。矩阵的大小为4x110100。我们有这个脚本：

awk '
{
  P[$1]=$2
  I[i++]=$1
} 
END{
  j=0; s=I[j]; t=I[j+1]
  for(i=m;i<=n;i++){
    if(I[j+2] && i>t){
    j++; s=I[j]; t=I[j+1]
    }                        
  print i,P[s]+(i-s)*(P[t]-P[s])/(t-s)
  }                                     
}' m=1 n=6 f1.dat > f2.dat

但是它只对前两列做

我们如何将插值扩展到整个数组？我尝试使用“ for”或“ while”脚本，但无法实现目标...

Answer 1

您可以通过仅跟踪当前行和上一行来做到这一点：

BEGIN {
    # initialise "previous" line
    getline;
    for (i=0; i<=NF; i++) p[i] = $i;
}
{
    # print previous line
    print p[0];

    # check if column 1 has skipped
    if ( (d = $1-p[1]) > 1 ) {

        # if so, insert (d-1) new rows
        for (i=1; i<d; i++) {

            # interpolate values for each column
            for (c=1; c<=NF; c++) {
                printf "%s%s",
                    p[c] + (i/d)*($c-p[c]), # linear interpolation
                    c==NF ? ORS : OFS;      # avoid trailing spaces
            }
        }
    }

    # update previous line
    for (i=0; i<=NF; i++) p[i] = $i;
}
END {
    # print the final line
    print p[0];
}

如何在'awk'中插值数组？

1 个答案: