Question

我一直在寻找一种方法，以最简单的方式向我的技术文盲办公室分发宏。

根据我的研究，将宏保存到.xlam加载项似乎朝着正确的方向发展。

是否还可以通过这种方式设置自定义功能区选项卡？

到目前为止，我还没有找到任何指南，我们的办公室安全也可能会阻止某些途径。

编辑：使用W-Hit的出色解决方案，并按照指示设置文件夹结构，它无疑有助于通过DeployAddIn子例程更轻松地部署更新。

我还发现将DeployAddIn和InstallAddin子例程放入它们自己的自定义功能区选项卡中很有用！

但是，我遇到了InstallAddin子例程的问题：如何在VBA中格式化XML文本而又不会遇到语法错误。

我发现每个元素的开头都必须有mso，例如<button> becomes <mso:button>和一行中的每个“带有语音标记的部分”都必须具有““双语音标记”。

使用此安装功能的最简单方法可能是将代码保存并编辑到活动文件中，然后在Notepad ++中打开C：\ Users [用户名] \ AppData \ Local \ Microsoft \ Office \ Excel.officeUI。然后只需执行查找并替换以添加多余的引号并将其粘贴到代码的ribbonXML =“在此处插入文本”部分，确保将其用最终的语音标记封装，以将整个部分标记为文本字符串。

我可能还会考虑在此处添加额外的功能...具有一个输入框或用户窗体，可让您此时粘贴代码，而无需输入VBA编辑器将其粘贴。

Answer 1

我目前正在执行此操作，这是设置过程中的一个较深层次的过程，但一旦运行就可以顺利进行。

第一步是创建一个文件夹结构，其中包含您作为管理员的.xlam文件的测试和生产副本。

2nd，在生产文件夹中，右键单击所有.xlam文件，然后将属性中的属性设置为“只读”。如果您不这样做，那么如果其中有其他人，您将永远无法更新该插件。

3，当您对测试文件中的代码进行更新时，只需将生产文件替换为更新的文件，然后再次更改为只读。用户只需要关闭所有excel实例并重新打开即可获得该加载项的最新副本。

以下是我用来将测试文件移至生产环境的管理员加载项。

Sub DeployAddIn()
'Author       : Ken Puls (www.excelguru.ca)
'Macro Purpose: To deploy finished/updated add-in to a network
'               location as a read only file

    Dim strAddinDevelopmentPath As String
    Dim strAddinPublicPath As String
    Dim FSO As New FileSystemObject

    'Set development path
    ChDrive "R:"
    ChDir "R:\addins\PROJECTS"
    strAddinDevelopmentPath = Application.GetOpenFilename()
    If strAddinDevelopmentPath = "False" Then
        Exit Sub
    ElseIf InStr(strAddinDevelopmentPath, "\PRODUCTION\") > 1 Then
        If MsgBox("You've Selected a Production File To Replace a Production File. Would You Like To Continue Anyway?", vbYesNo) = vbNo Then
            Exit Sub
        End If
    End If

    'Get Desitination path
    strAddinPublicPath = Replace(strAddinDevelopmentPath, "TESTING", "PRODUCTION")

    'Create dir if it doesn't exist
    On Error Resume Next
    MkDir Left(strAddinPublicPath, InStrRev(strAddinPublicPath, "\") - 1)
    On Error GoTo 0

    'Turn off alert regarding overwriting existing files
    Application.DisplayAlerts = False

    'overwrite existing file
    On Error Resume Next
    SetAttr strAddinPublicPath, vbNormal
    On Error GoTo 0
    FSO.CopyFile strAddinDevelopmentPath, strAddinPublicPath, True
    SetAttr strAddinPublicPath, vbReadOnly

    'Resume alerts
    Application.DisplayAlerts = True
End Sub

4，我还写了一个宏来更改自定义功能区。下面的链接，以及Ron deBruin的站点非常有用。 https://grishagin.com/vba/2017/01/11/automatic-excel-addin-installation.html 从officeUI文件获得正确的文本后，自动执行插件加载的代码

Sub InstallAddin()
    'Adapted from https://grishagin.com/vba/2017/01/11/automatic-excel-addin-installation.html
    Dim eai As Excel.AddIn
    Dim alreadyinstalled As Boolean
    Dim ribbonXML As String

    'check if already installed
    For Each eai In Application.AddIns
        If eai.Name = "Main addin.xlam" Then
            eai.Installed = False
            Exit For
        End If
    Next

    'add and install the addin
    Set eai = Application.AddIns.Add("path to Main addin.xlam", False)
    eai.Installed = True

    'append quick access ribbon xml to add button
    ClearCustRibbon
    LoadNewRibbon

    'have to close addin for it to load properly the first time
    Workbooks("Main addin.xlam").Close

End Sub

Sub ClearCustRibbon()
'https://social.msdn.microsoft.com/Forums/vstudio/en-US/abddbdc1-7a24-4664-a6ff-170d787baa5b/qat-changes-lost-when-using-xml-to-modify-ribbon-excel-2016-2016?forum=exceldev
Dim hFile As Long
Dim ribbonXMLString As String

hFile = FreeFile
OfficeUIFilePath = Environ("USERPROFILE") & "\AppData\Local\Microsoft\Office\Excel.officeUI"

ribbonXMLString = "<mso:customUI           xmlns:mso=""http://schemas.microsoft.com/office/2009/07/customui"">" & _
"<mso:ribbon>" & _
"<mso:qat>" & _
"<mso:sharedControls>" & _
"</mso:sharedControls>" & _
"</mso:qat>" & _
"</mso:ribbon>" & _
"</mso:customUI>"

Open OfficeUIFilePath For Output Access Write As hFile
Print #hFile, ribbonXMLString
Close hFile

End Sub

Sub LoadNewRibbon()
Dim hFile As Long

hFile = FreeFile
OfficeUIFilePath = Environ("USERPROFILE") & "\AppData\Local\Microsoft\Office\Excel.officeUI"

ribbonXML = "your ribbon text here"

Open OfficeUIFilePath For Output Access Write As hFile
Print #hFile, ribbonXML
Close hFile
End Sub

***重要提示----如果手动安装外接程序，请确保在提示将文件保存到本地计算机时选择否。如果将其保存到本地计算机，它将创建一个本地副本，并且如果您对网络副本进行更改或需要修复错误，它将永远不会更新。

还有更多技巧，但是您最需要调整它们以适合您的操作方式。希望有帮助。

使用自定义功能区按钮将宏作为外接程序部署到整个办公室

1 个答案: