Question

我一直在提供一个看起来像这样的输入文件：

HasPrecision

，它需要像这样结束：

ID          PID   PPID   C STIME  TTY            TIME  CMD
adz110     5344   5334   0 08:47  pts/2     00:00:00  bash
dmq292     6908   6854   0 08:53  pts/1     00:00:00  bash
adz110     7227   7150   0 08:54  pts/9     00:00:00  who
erg474     7466   7461   0 08:54  pts/10    00:00:00  ls
dmq292     7966   7960   0 08:55  pts/13    00:00:00  assign1.sh if of
xle135     8636   8628   0 08:58  pts/15    00:00:00  bash
xle135     8983   8636   0 08:59  pts/15    00:00:00  ssh ctf.cs.utsarr.net
zeh458     9057   1980   0 08:59  pts/7     00:00:00  vim prog.c
HanSolo    9150   9139   0 08:59  pts/16    00:00:00  ps -af

到目前为止，我提出的内容位于我写下的file.awk中：

User: adz110
    bash
    who
User: dmq292
    bash
    assign1.sh if of
User: erg474
    ls
User: xle135
    bash
    ssh ctf.cs.utsarr.net
User: zeh458
    vim prog.c
Earliest  Start  Time:
adz110    5344   5334 0 08:47  pts/2     00:00:00  bash

Latest  Start  Time
xle135    8983   8636   0 08:59  pts /15    00:00:00  ssh ctf.cs.utsarr.net

因此，不是为每个用户名与[a-z] [0-9] {3}匹配的用户打印，而是打印cmd和用户名，不带任何空格。我在理解关联数组和使用特殊变量（例如NR，RS等）时遇到很多麻烦。

Answer 1

您只想对第一个字段应用正则表达式，并以适合打印输出的格式为内存中的每个用户收集值。

请注意列表是固定宽度的；因此程序名称和参数位于第55列开始的字段中。类似，时间戳记位于第28-32列。

awk 'NR > 1 && $1 ~ /^[a-z]{3}[0-9]{3}$/ {
  when = substr($0, 28, 5)
  command = substr($0, 55)  
  if ($1 in user) {
      # Append this command to previous value
      user[$1] = user[$1] ORS "    " command
  } else {
      # Create a new item in this associative array
      user[$1] = "    " command
  }
  if (NR==2 || when > max) { max=when; maxcmd = $0 }
  if (NR==2 || when < min) { min=when; mincmd = $0 }
}
END {
    # XXX TODO: sort array?
    for (u in user) printf "User %s:\n%s\n", u, user[u]
    print "Earliest start time"; print mincmd
    print "Lastest start time"; print maxcmd
}' filename

因此，当我们第一次看到特定用户时，他们将不在users中，因此我们将以四个空格缩进的第一个命令作为该键在关联数组中的值。如果再次看到它们，我们将在值的另一行后加上换行符（ORS），并在前面加上四个空格。

NR是当前行号-我们跳过NR==1以避免捕获标题行，并且使用NR==2我们知道这是我们正在处理的第一行，因此将max和min设置为其基准值。

理想情况下，您还应该将时间戳规范化为规范形式，以便您可以在“ 21:23”之前对“昨天21:24”进行排序，但是我不打算用这个简单的答案。您可能也想在其他各个地方添加装饰。（或者也许您可以依靠输入似乎按流程开始时间排序的事实？）

如果您希望对用户名进行排序，则GNU Awk内置了数组排序功能。对于其他Awks，您将需要编写自己的简单排序函数，或使用外部管道。

Answer 2

尝试一下，file.awk：

$1 !~ /[a-z]{3}[0-9]{3}/ {next;}
!fstTime {fstTime=$5; lstTime=$5; first=$0; last = $0;}
!($1 in a) {a[$1];users[++ind]=$1;}
{   cmd=$8; for(i=9;i<=NF;i++) cmd=cmd OFS $i;
    cmds[$1] = cmds[$1] ? cmds[$1] "\n    " cmd : "    " cmd;
    if ($5 < fstTime) { fstTime=$5; first=$0; }
    if ($5 > lstTime) { lstTime=$5; last = $0; }
}
END { 
    for(i=1;i<=length(a);i++) {
        print "User: " users[i];
        print cmds[users[i]];
    }
    print "Earliest  Start  Time:\n" first "\n\nLatest  Start  Time:\n" last; 
}

awk -f file.awk fileToTest.txt产生：

User: adz110
    bash
    who
User: dmq292
    bash
    assign1.sh if of
User: erg474
    ls
User: xle135
    bash
    ssh ctf.cs.utsarr.net
User: zeh458
    vim prog.c
Earliest  Start  Time:
adz110     5344   5334   0 08:47  pts/2     00:00:00  bash

Latest  Start  Time:
xle135     8983   8636   0 08:59  pts/15    00:00:00  ssh ctf.cs.utsarr.net

如果您希望zeh458 9057 1980 0 08:59 pts/7 00:00:00 vim prog.c是Latest Start Time:行，只需将($5 > lstTime)更改为($5 >= lstTime)就可以了。

Answer 3

您的输入文件中有一个混乱之处（您的命令输出同时显示一些进程，例如xle135和zeh458）。因此，我想出的解决方案将对输入文件进行排序（如果需要，也可以放置命令），然后它将从所有条目中找出最大和最小时间段。如果某些东西具有相同的时间戳，它将不连接它们的值（尽管我们也可以这样做）；相反，它将打印最新排序的（仅带有最新时间戳）。

awk '
/^ID/{
  next
}
{
  split($5,array,":")
  seconds=array[1]*60+array[2]
}
FNR==NR{
  a[$1]++
  tim[seconds]=$0
  next
}
a[$1]==2{
  print "User: " $1  ORS "    " $NF
  getline
  sub(/.*:00/,"")
  print"  " $0
}
a[$1]==1{
  val=$0
  sub(/.*:00/,"",val)
  print "User: " $1 ORS "    " val
}
{
  min=min<seconds?(min?min:seconds):seconds
  max=max>seconds?max:seconds
}
END{
  print "Earliest  Start  Time:" ORS tim[min] ORS "Latest  Start  Time" ORS tim[max]
}
' <(sort -k1,5 Input_file)  <(sort -k1,5 Input_file)

输出如下。

User: adz110
    bash
    who
User: dmq292
    bash
    assign1.sh if of
User: erg474
      ls
User: HanSolo
      ps -af
User: xle135
    bash
    ssh ctf.cs.utsarr.net
User: zeh458
      vim  prog.c
Earliest  Start  Time:
adz110     5344   5334   0 08:47  pts/2     00:00:00  bash
Latest  Start  Time
zeh458     9057   1980   0 08:59  pts/7     00:00:00  vim  prog.c

Answer 4

假设如果给定用户多次运行同一命令，则您希望该命令在该用户的输出中多次出现：

$ cat tst.awk
NR == 1 { next }
/^[a-z]{3}[0-9]{3}/ {
    user = $1
    users[user]

    cmd = $0
    sub(/([^[:space:]]+[[:space:]]+){7}/,"",cmd)
    cmds[user,++numCmds[user]] = cmd

    stime = $5
    if ( (earliestStime == "") || (stime < earliestStime) ) {
        earliestStime = stime
        earliestData  = $0
    }
    if ( (latestStime == "") || (stime > latestStime) ) {
        latestStime = stime
        latestData  = $0
    }
}
END {
    for (user in users) {
        printf "User: %s\n", user
        for (cmdNr=1; cmdNr<=numCmds[user]; cmdNr++) {
            printf "   %s\n", cmds[user,cmdNr]
        }
    }

    print "\nEarliest  Start  Time:"
    print earliestData

    print "\nLatest  Start  Time:"
    print latestData
}

。

$ awk -f tst.awk file
User: xle135
   bash
   ssh ctf.cs.utsarr.net
User: zeh458
   vim prog.c
User: dmq292
   bash
   assign1.sh if of
User: erg474
   ls
User: adz110
   bash
   who

Earliest  Start  Time:
adz110     5344   5334   0 08:47  pts/2     00:00:00  bash

Latest  Start  Time:
xle135     8983   8636   0 08:59  pts/15    00:00:00  ssh ctf.cs.utsarr.net

如果输出中用户或命令的顺序很重要，请告诉我们该顺序应该是什么，并且将很容易进行调整，例如通过保留输入顺序或在END部分中的每个循环之前使用GNU awk设置PROCINFO["sorted_in"]。

使用AWK显示格式化的记录

4 个答案: