Question

由于此question使用列表，因此我想使用DCG解决它。在此过程中，我意识到可以使用半上下文。（DCG Primer）

最初的问题是返回列表中的项目计数，但是如果两个相同的项目彼此相邻，则不要增加计数。

虽然我的代码适用于某些测试用例，但对于其他测试用例却失败。这只是一个失败的条款。在使用调试器查看代码时，似乎在我认为应该取消绑定该第二个状态变量（即返回的列表）时，将其绑定到该子句的调用上。编辑解决了以下部分问题。

我正在使用SWI-Prolog 8.0。

引起问题的子句：

count_dcg(N0,N),[C2] -->
    [C1,C2],
    { N is N0 + 1 }.

注意：C1被标记为Singleton variables: [C1]

通常我会将C1更改为_，但是在这种情况下，我需要指出当前正在处理的第一项和第二项是不同的。换句话说，它利用统一的失败作为警惕。

使用Listing / 1查看DCG，发现使用_可能是个问题，但不确定。

count_dcg(C, B, A, E) :-
    A=[_, F|D],
    B is C+1,
    G=D,
    E=[F|G].

使用DCG解决问题的正确方法是什么？

请参阅后续question。

当前源代码

% empty list
% No semicontext (push back) needed because last item in list.
count_dcg(N,N) --> [].

% single item in list
% No semicontext (push back) needed because only one item removed from list.
count_dcg(N0,N) -->
    [_],
    \+ [_],
    { N is N0 + 1 }.

% Semicontext (push back) needed because two items removed from list.
% Need second item to stay on list.
count_dcg(N,N),[C] -->
    [C,C].

% Semicontext (push back) needed because two items removed from list.
% Need second item to stay on list.
count_dcg(N0,N),[C2] -->
    [C1,C2],
    { N is N0 + 1 }.

count(L,N) :-
    DCG = count_dcg(0,N),
    phrase(DCG,L).

测试用例

:- begin_tests(count).

test(1,[nondet]) :-
    count([],N),
    assertion( N == 0 ).

test(2,[nondet]) :-
    count([a],N),
    assertion( N == 1 ).

test(3,[nondet]) :-
    count([a,a],N),
    assertion( N == 1 ).

test(4,[nondet]) :-
    count([a,b],N),
    assertion( N == 2 ).

test(5,[nondet]) :-
    count([b,a],N),
    assertion( N == 2 ).

test(6,[nondet]) :-
    count([a,a,b],N),
    assertion( N == 2 ).

test(7,[nondet]) :-
    count([a,b,a],N),
    assertion( N == 3 ).

test(8,[nondet]) :-
    count([b,a,a],N),
    assertion( N == 2 ).

:- end_tests(count).

运行测试

?- run_tests.
% PL-Unit: count ..
ERROR: c:/question_110.pl:80:
        test 3: failed

ERROR: c:/question_110.pl:84:
        test 4: failed

ERROR: c:/question_110.pl:88:
        test 5: failed

ERROR: c:/question_110.pl:92:
        test 6: failed

ERROR: c:/question_110.pl:96:
        test 7: failed

ERROR: c:/question_110.pl:100:
        test 8: failed

 done
% 6 tests failed
% 2 tests passed
false.

编辑1

意识到需要对两个谓词进行尾部调用

% Semicontext (push back) needed because two items removed from list.
% Need second item to stay on list.
count_dcg(N0,N),[C] -->
    [C,C],
    count_dcg(N0,N).

% Semicontext (push back) needed because two items removed from list.
% Need second item to stay on list.
count_dcg(N0,N),[C2] -->
    [C1,C2],
    { 
        C1 \== C2,
        N1 is N0 + 1 
    },
    count_dcg(N1,N).

代码仍然无法正常工作，但这解释了为什么在我期望状态变量未绑定时绑定状态变量的原因。

编辑2

虽然我不希望使用DCG半上下文，但是使用半上下文的变体作为先行代码，但是代码有效。不要将其发布为答案，因为我希望答案要么在子句标题上显示DCG代码与半上下文一起工作，要么解释为什么这是错误的。

lookahead(C),[C] -->
    [C].

% empty list
% No lookahead needed because last item in list.
count_3_dcg(N,N) --> [].

% single item in list
% No lookahead  needed because only one in list.
count_3_dcg(N0,N) -->
    [_],
    \+ [_],
    { N is N0 + 1 }.

% Lookahead needed because two items in list and
% only want to remove first item.
count_3_dcg(N0,N) -->
    [C1],
    lookahead(C2),
    { C1 == C2 },
    count_3_dcg(N0,N).

% Lookahead needed because two items in list and
% only want to remove first item.
count_3_dcg(N0,N) -->
    [C1],
    lookahead(C2),
    {
        C1 \== C2,
        N1 is N0 + 1
    },
    count_3_dcg(N1,N).

count(L,N) :-
    DCG = count_3_dcg(0,N),
    phrase(DCG,L).

运行测试

?- run_tests.
% PL-Unit: count ........ done
% All 8 tests passed
true.

Answer 1

不需要推回列表或提前行的另一种解决方案：

count_dcg(N0,N) -->
    [C], {N1 is N0 + 1}, count_dcg(N1,N,C).
count_dcg(N,N) -->
    [].

count_dcg(N0,N,C) -->
    [C],
    count_dcg(N0,N,C).
count_dcg(N0,N,C) -->
    [C1],
    {C \== C1, N1 is N0 + 1},
    count_dcg(N1,N,C1).
count_dcg(N,N,_) -->
    [].

count(L,N) :-
    phrase(count_dcg(0,N),L).

无法转换为DCG Semicontext

1 个答案: