Question

已经有一个Thread没有帮助。我希望能够链接发布配置的 Foo.lib 和调试配置的 Foo_d.lib ，我怎么能实现这个目标？如果我这样做：

target_link_libraries(MyEXE debug Foo_d)
target_link_libraries(MyEXE optimized Foo)

然后我的项目中有两个库用于调试配置？为什么没有发布选项？

非常感谢！

Answer 1

target_link_libraries采用一个列表，您不需要调用它两次。以下内容适用：

target_link_libraries(MyEXE debug Foo_d optimized Foo)

为了回答另一个答案的评论中提出的问题，使用多个库的工作原理如下：

target_link_libraries(MyEXE
    debug Foo1_d optimized Foo1
    debug Foo2_d optimized Foo2)

请注意，如果您还将库构建为CMake项目的一部分，则无需指定debug或optimize。 CMake会为您选择合适的。

Answer 2

解决方案是：

SET(LINK_LIBRARY optimized Foo debug Foo_d)
target_link_libraries(MyEXE ${LINK_LIBRARY})

Answer 3

当您的图书馆是项目的一部分或您是图书馆时，没有任何问题使用find_package命令的配置模式导入它（请参阅documentation和example）。如果您无法修改第三方，那么它将生成<package>Config.cmake （它可能不使用cmake工具或你不想这样做）答案是模仿这样的过程：

add_library(foo STATIC IMPORTED)
set_target_properties(foo PROPERTIES IMPORTED_LOCATION_DEBUG "/path/to/foo-d.lib")
set_target_properties(foo PROPERTIES IMPORTED_LOCATION_RELEASE "/path/to/foo.lib")

target_link_libraries(MyEXE foo)

请注意，与＆＃34;调试＆＃34; /＆＃34;优化＆＃34;功能这样的方法不仅限于调试/发布配置：

set_target_properties(foo PROPERTIES IMPORTED_LOCATION_MINSIZEREL "/path/to/foo-small.lib")

你也有一些像INTERFACE_INCLUDE_DIRECTORIES这样的好东西：

set_target_properties(foo PROPERTIES INTERFACE_INCLUDE_DIRECTORIES "/path/to/foo/includes")

include_directories("/path/to/foo/includes") # this line not needed
target_link_libraries(MyEXE foo) # this command will add "/path/to/foo/includes" for you

和传递链接：

add_library(boo STATIC IMPORTED)
set_target_properties(boo PROPERTIES IMPORTED_LOCATION_DEBUG "/path/to/boo-d.lib")
set_target_properties(boo PROPERTIES IMPORTED_LOCATION_RELEASE "/path/to/boo.lib")

add_library(foo STATIC IMPORTED)
set_target_properties(foo PROPERTIES IMPORTED_LOCATION_DEBUG "/path/to/foo-d.lib")
set_target_properties(foo PROPERTIES IMPORTED_LOCATION_RELEASE "/path/to/foo.lib")

set_target_properties(foo PROPERTIES INTERFACE_LINK_LIBRARIES boo) # foo depends on boo

target_link_libraries(MyEXE foo) # boo will be linked automatically

当然，您可以使用常规的cmake命令，例如find_library和find_package(... MODULE)来估算位置，而不是硬编码。

Answer 4

如果您的调试/发布库遵循某种模式，例如调试版的_d，您可以避免重复自己：

set (MY_LIBS
    foo
    bar
    baz
)

# Generate the list of files to link, per flavor.
set (LINK_LIST "")
foreach(x ${MY_LIBS})
    list (APPEND LINK_LIST debug ${x}_d optimized ${x})
endforeach()

target_link_libraries (mytarget
    commonlib1
    commonlib2
    ${LINK_LIST}
    )

这将生成相应的

debug foo_d optimized foo
debug bar_d optimized bar

target_link_libraries期望的行。

Answer 5

将target_link_libraries与调试和优化参数一起使用对我的cmake 3.14.6不起作用。如果遇到此错误，请尝试使用以下类型的代码：

set (FreeImage debug "FreeImageD" optimized "FreeImage")
set (Glog debug "glogd" optimized "glog")
set (EXTRA_LIBS ${FreeImage} ${Glog})
target_link_libraries(TexCompressor ${EXTRA_LIBS})

它只是将调试/优化对更改为变量定义。它适用于我的版本。

调试和发布库与CMAKE链接（VISUAL STUDIO）

5 个答案: