Question

我有一个工作简单的自定义OS（暂时不做很多事情：D）。现在，我正在使用不支持键盘的程序集文件（boot.s）。

汇编文件（boot.s）：

# set magic number to 0x1BADB002 to identified by bootloader 
.set MAGIC,    0x1BADB002
# set flags to 0
.set FLAGS,    0
# set the checksum
.set CHECKSUM, -(MAGIC + FLAGS)
# set multiboot enabled
.section .multiboot
# define type to long for each data defined as above
.long MAGIC
.long FLAGS
.long CHECKSUM
# set the stack bottom 
stackBottom:
# define the maximum size of stack to 512 bytes
.skip 512
# set the stack top which grows from higher to lower
stackTop:
.section .text
.global _start
.type _start, @function

_start:
  # assign current stack pointer location to stackTop
    mov $stackTop, %esp
  # call the kernel main source
    call KERNEL_MAIN
    cli
# put system in infinite loop
hltLoop:
    hlt
    jmp hltLoop
.size _start, . - _start

我认为这是缺少的部分，但是它是intel语法，因此我无法使用它。

load_idt:
mov edx, [esp + 4]
lidt [edx]
sti
ret

read_port:
mov edx, [esp + 4]
in al, dx   
ret

write_port:
mov edx, [esp + 4]    
mov al, [esp + 4 + 4]  
out dx, al  
ret

keyboard_handler:                 
call keyboard_handler
iretd

我正在使用以下命令编译boot.s：

as --32 boot.s -o boot.o

有人可以帮我将键盘部分（英特尔语法）翻译成AT＆T吗？：）

Answer 1

此Stackoverflow Answer中提供了有关如何将NASM Intel语法转换为GAS的AT＆T语法的信息，此IBM article提供了许多有用的信息。您的代码尤其如下所示：

load_idt:
    mov 4(%esp), %edx
    lidt (%edx)
    sti
    ret

read_port:
    mov 4(%esp), %edx
    in %dx, %al
    ret

write_port:
    mov 4(%esp), %edx
    mov 8(%esp), %al
    out %al, %dx
    ret

keyboard_handler:                 
    call keyboard_handler
    iret

通常最大的区别是：

使用AT＆T语法，源位于左侧，目标位于右侧，而英特尔则相反。
在AT＆T语法中，寄存器名前面带有%
使用AT＆T语法，立即值前面带有$
内存操作数可能是最大的不同。 NASM使用 [segment：disp + base + index * scale] 代替GAS的 segment：disp（base，index，scale）语法。

其他观察结果

我建议将堆栈从multiboot部分移到.bss部分。 BSS节通常不会在输出可执行文件中占用空间（假设其中一个正在使用健全的或默认的链接描述文件）。可以在.text部分之后以这种方式定义堆栈：

.section .bss
    .lcomm stackBottom 512
stackTop:

组装：用于自定义操作系统键盘支持的引导加载程序

1 个答案:

其他观察结果