Question

我想使用CL_SALV_TABLE从类实例中显示一个表。但是，我的表是只读的，并且必须将其传递给CHANGING参数，这是不允许的。

如何将动态引用复制到可以传递的内容上？该属性的数据类型可以是任何表。

对类CL_SALV_TABLE的方法FACTORY的调用失败；的 T_TABLE的实际参数受写保护。

DATA(lv_attribute) = 'mt_attribute'. "Dynamic name of class attribute        
ASSIGN lr_appclass->(lv_attribute) TO FIELD-SYMBOL(<lt_table>).

cl_salv_table=>factory( 
          IMPORTING r_salv_table = DATA(lr_salv_table) 
          CHANGING  t_table      = <lt_table> ).

Answer 1

您可以使用RTTS生成动态变量。

要生成具有相同原始类型的动态内部表：

DATA: lo_table_desc TYPE REF TO cl_abap_tabledescr, " RTTS table descriptor
      lrt_copy      TYPE REF TO DATA.               " temp data ref
FIELD-SYMBOLS:
               <lt_copy> TYPE ANY TABLE.

" original type determination
lo_table_desc ?= cl_abap_tabledescr=>describe_by_data( {HERE_GOES_THE_MEMBER_TABLE} ).

" dynamic allocation
CREATE DATA lrt_copy TYPE HANDLE lo_table_desc.
ASSIGN lrt_copy->* TO <lt_copy>.

" {NOW_USE_<lt_copy>}

Answer 2

无需运行时键入：

ASSIGN lr_appclass->('MT_ATTRIBUTE') TO FIELD-SYMBOL(<member>).
DATA(copied_member) = copy( <member> ).
ASSIGN copied_member->* TO FIELD-SYMBOL(<table>).

cl_salv_table=>factory(
  IMPORTING
    r_salv_table = DATA(lr_salv_table)
  CHANGING
    t_table      = <table> ).

使用

METHODS copy
  IMPORTING
    data          TYPE any
  RETURNING
    VALUE(result) TYPE REF TO data.

METHOD copy.
  CREATE DATA result LIKE data.
  ASSIGN result->* TO FIELD-SYMBOL(<result>).
  <result> = data.
ENDMETHOD.

我添加了方法copy来澄清正在发生的事情。其代码也可以添加到主函数中。

将只读变量传递给CHANGING参数

2 个答案: