旧版BIOS引导程序可在第二阶段引导实模式代码
我正在编写自己的操作系统。到目前为止，我的代码超过了512个字节，太大了，无法容纳在简单的引导扇区中。
我知道我现在必须编写一个引导加载程序，该加载程序可以读取可能大于或小于单个512字节扇区的任意代码。
引导加载程序需要：
- 用作磁盘签名为0xaa55的启动记录。
- 从内存地址0x7E00开始，从任意长度的LBA 1（LBA 0是引导扇区）开始读取第二阶段（测试代码）。
- 使用FAR JMP将控制权转移到0x0000：0x7E00。
- 可用作1.44 MiB软盘映像，用于QEMU，BOCHS，VirtualBox等模拟器。
- 可以在USB记忆棒上传输和使用它，并在BIOS设置为使用软盘驱动器（FDD）仿真引导USB的情况下在真实硬件上进行测试。 注意：Some bootloaders放在USB驱动器上时效果不佳。
- 将启动驱动器传递到DL中的第二阶段。
- 清除所有段寄存器并将SS：SP设置为0x0000：0x7C00（从引导加载程序的下方向下生长）。
这也可以作为一个很好的起点，用于在涉及操作系统开发的Stack Overflow上提出问题。程序员通常很难创建Minimal, Complete, and Verifiable Example。通用的样板/模板将允许其他希望在有限的麻烦下帮助测试代码的Stack Overflow用户。
我将如何构建这样一个可重用的引导程序？
2 个答案:
答案 0 :(得分：9)
我已经编写了这样的代码作为其他答案的一部分，但从未有机会展示可以从其他Stackoverflow问题中引用的简单测试工具。您要的是相当琐碎的。为此，您可以在NASM中编写一个引导加载程序，其中包含您要测试的汇编代码的二进制映像。将使用BIOS函数Int 13/ah=2从LBA 1（引导加载程序之后的第一个扇区）开始的磁盘读取该映像。然后，控制权将通过FAR JMP转移到0x0000：0x7e00。
引导加载程序代码如下：
bpb.inc ：
%define WITH_BPB 1
global bpb_disk_info
jmp boot_start
TIMES 3-($-$$) DB 0x90 ; Support 2 or 3 byte encoded JMPs before BPB.
bpb_disk_info:
; Dos 4.0 EBPB 1.44MB floppy
OEMname: db "mkfs.fat" ; mkfs.fat is what OEMname mkdosfs uses
bytesPerSector: dw 512
sectPerCluster: db 1
reservedSectors: dw 1
numFAT: db 2
numRootDirEntries: dw 224
numSectors: dw 2880
mediaType: db 0xf0
numFATsectors: dw 9
sectorsPerTrack: dw 18
numHeads: dw 2
numHiddenSectors: dd 0
numSectorsHuge: dd 0
driveNum: db 0
reserved: db 0
signature: db 0x29
volumeID: dd 0x2d7e5a1a
volumeLabel: db "NO NAME "
fileSysType: db "FAT12 "
boot.asm ：
STAGE2_ABS_ADDR equ 0x07e00
STAGE2_RUN_SEG equ 0x0000
STAGE2_RUN_OFS equ STAGE2_ABS_ADDR
; Run stage2 with segment of 0x0000 and offset of 0x7e00
STAGE2_LOAD_SEG equ STAGE2_ABS_ADDR>>4
; Segment to start reading Stage2 into
; right after bootloader
STAGE2_LBA_START equ 1 ; Logical Block Address(LBA) Stage2 starts on
; LBA 1 = sector after boot sector
STAGE2_LBA_END equ STAGE2_LBA_START + NUM_STAGE2_SECTORS
; Logical Block Address(LBA) Stage2 ends at
DISK_RETRIES equ 3 ; Number of times to retry on disk error
bits 16
ORG 0x7c00
; Include a BPB (1.44MB floppy with FAT12) to be more comaptible with USB floppy media
%include "bpb.inc"
boot_start:
xor ax, ax ; DS=SS=ES=0 for stage2 loading
mov ds, ax
mov ss, ax ; Stack at 0x0000:0x7c00
mov sp, 0x7c00
cld ; Set string instructions to use forward movement
; Read Stage2 1 sector at a time until stage2 is completely loaded
load_stage2:
mov [bootDevice], dl ; Save boot drive
mov di, STAGE2_LOAD_SEG ; DI = Current segment to read into
mov si, STAGE2_LBA_START ; SI = LBA that stage2 starts at
jmp .chk_for_last_lba ; Check to see if we are last sector in stage2
.read_sector_loop:
mov bp, DISK_RETRIES ; Set disk retry count
call lba_to_chs ; Convert current LBA to CHS
mov es, di ; Set ES to current segment number to read into
xor bx, bx ; Offset zero in segment
.retry:
mov ax, 0x0201 ; Call function 0x02 of int 13h (read sectors)
; AL = 1 = Sectors to read
int 0x13 ; BIOS Disk interrupt call
jc .disk_error ; If CF set then disk error
.success:
add di, 512>>4 ; Advance to next 512 byte segment (0x20*16=512)
inc si ; Next LBA
.chk_for_last_lba:
cmp si, STAGE2_LBA_END ; Have we reached the last stage2 sector?
jl .read_sector_loop ; If we haven't then read next sector
.stage2_loaded:
mov ax, STAGE2_RUN_SEG ; Set up the segments appropriate for Stage2 to run
mov ds, ax
mov es, ax
; FAR JMP to the Stage2 entry point at physical address 0x07e00
xor ax, ax ; ES=FS=GS=0 (DS zeroed earlier)
mov es, ax
mov fs, ax
mov gs, ax
; SS:SP is already at 0x0000:0x7c00, keep it that way
; DL still contains the boot drive number
; Far jump to second stage at 0x0000:0x7e00
jmp STAGE2_RUN_SEG:STAGE2_RUN_OFS
.disk_error:
xor ah, ah ; Int13h/AH=0 is drive reset
int 0x13
dec bp ; Decrease retry count
jge .retry ; If retry count not exceeded then try again
error_end:
; Unrecoverable error; print drive error; enter infinite loop
mov si, diskErrorMsg ; Display disk error message
call print_string
cli
.error_loop:
hlt
jmp .error_loop
; Function: print_string
; Display a string to the console on display page 0
;
; Inputs: SI = Offset of address to print
; Clobbers: AX, BX, SI
print_string:
mov ah, 0x0e ; BIOS tty Print
xor bx, bx ; Set display page to 0 (BL)
jmp .getch
.repeat:
int 0x10 ; print character
.getch:
lodsb ; Get character from string
test al,al ; Have we reached end of string?
jnz .repeat ; if not process next character
.end:
ret
; Function: lba_to_chs
; Description: Translate Logical block address to CHS (Cylinder, Head, Sector).
; Works for all valid FAT12 compatible disk geometries.
;
; Resources: http://www.ctyme.com/intr/rb-0607.htm
; https://en.wikipedia.org/wiki/Logical_block_addressing#CHS_conversion
; https://stackoverflow.com/q/45434899/3857942
; Sector = (LBA mod SPT) + 1
; Head = (LBA / SPT) mod HEADS
; Cylinder = (LBA / SPT) / HEADS
;
; Inputs: SI = LBA
; Outputs: DL = Boot Drive Number
; DH = Head
; CH = Cylinder (lower 8 bits of 10-bit cylinder)
; CL = Sector/Cylinder
; Upper 2 bits of 10-bit Cylinders in upper 2 bits of CL
; Sector in lower 6 bits of CL
;
; Notes: Output registers match expectation of Int 13h/AH=2 inputs
;
lba_to_chs:
push ax ; Preserve AX
mov ax, si ; Copy LBA to AX
xor dx, dx ; Upper 16-bit of 32-bit value set to 0 for DIV
div word [sectorsPerTrack] ; 32-bit by 16-bit DIV : LBA / SPT
mov cl, dl ; CL = S = LBA mod SPT
inc cl ; CL = S = (LBA mod SPT) + 1
xor dx, dx ; Upper 16-bit of 32-bit value set to 0 for DIV
div word [numHeads] ; 32-bit by 16-bit DIV : (LBA / SPT) / HEADS
mov dh, dl ; DH = H = (LBA / SPT) mod HEADS
mov dl, [bootDevice] ; boot device, not necessary to set but convenient
mov ch, al ; CH = C(lower 8 bits) = (LBA / SPT) / HEADS
shl ah, 6 ; Store upper 2 bits of 10-bit Cylinder into
or cl, ah ; upper 2 bits of Sector (CL)
pop ax ; Restore scratch registers
ret
; Uncomment these lines if not using a BPB (via bpb.inc)
%ifndef WITH_BPB
numHeads: dw 2 ; 1.44MB Floppy has 2 heads & 18 sector per track
sectorsPerTrack: dw 18
%endif
bootDevice: db 0x00
diskErrorMsg: db "Unrecoverable disk error!", 0
; Pad boot sector to 510 bytes and add 2 byte boot signature for 512 total bytes
TIMES 510-($-$$) db 0
dw 0xaa55
; Beginning of stage2. This is at 0x7E00 and will allow your stage2 to be 32.5KiB
; before running into problems. DL will be set to the drive number originally
; passed to us by the BIOS.
NUM_STAGE2_SECTORS equ (stage2_end-stage2_start+511) / 512
; Number of 512 byte sectors stage2 uses.
stage2_start:
; Insert stage2 binary here. It is done this way since we
; can determine the size(and number of sectors) to load since
; Size = stage2_end-stage2_start
incbin "stage2.bin"
; End of stage2. Make sure this label is LAST in this file!
stage2_end:
; Fill out this file to produce a 1.44MB floppy image
TIMES 1024*1440-($-$$) db 0x00
要使用此功能，您将首先生成一个名为stage2.bin的二进制文件。然后，您可以使用以下命令构建1.44MiB磁盘映像：
nasm -f bin boot.asm -o disk.img
stage2.bin中的代码必须在内存中ORG（原点）为0x07e00的前提下生成。
示例用法/示例
生成到名为stage2.bin的文件的代码示例，可以通过以下测试工具加载该代码：
testcode.asm ：
ORG 0x7e00
start:
mov si, testCodeStr
call print_string
cli
.end_loop:
hlt
jmp .end_loop
testCodeStr: db "Test harness loaded and is executing code in stage2!", 0
; Function: print_string
; Display a string to the console on display page 0
;
; Inputs: SI = Offset of address to print
; Clobbers: AX, BX, SI
print_string:
mov ah, 0x0e ; BIOS tty Print
xor bx, bx ; Set display page to 0 (BL)
jmp .getch
.repeat:
int 0x10 ; print character
.getch:
lodsb ; Get character from string
test al,al ; Have we reached end of string?
jnz .repeat ; if not process next character
.end:
ret
注意：顶部有一个ORG 0x7e00。这个很重要。要将文件汇编成stage2.bin，请使用：
nasm -f bin testcode.asm -o stage2.bin
然后使用以下命令创建1.44MiB磁盘映像：
nasm -f bin boot.asm -o disk.img
结果应该是大小为1.44MiB的磁盘映像，包含stage2.bin的副本，并具有我们的测试工具引导扇区。
文件stage2.bin可以是任何已编写要加载并从0x0000：0x7e00开始的二进制代码的文件。在stage2.bin中用于创建代码的语言（C，汇编语言等）无关紧要。在此示例中，我使用NASM。当使用qemu-system-i386 -fda disk.img在QEMU中执行此测试代码时，它看起来类似于：
特殊说明：：如果您不想使用bpb.inc并且不想使用FDD仿真从USB引导，则可以在{{ 1}}
boot.asm答案 1 :(得分：2)
我修改了自己的引导扇区加载器以添加新协议。它设置为es = ds = ss = 0并将整个加载文件加载到地址07E00h，然后跳转到0000h：7E00h。但是，sp仍指向7C00h以下。
问题的要求有很大的不同：此加载程序使用（FAT12或FAT16）文件系统加载下一阶段。如果找到，它将从名为KERNEL7E.BIN的文件加载。可以像编辑整个加载协议一样，通过编辑源文件或在NASM命令行中传递定义来调整文件名。
由于代码大小的限制是，发生错误时仅输出单字符错误消息：R表示磁盘读取错误，M表示要加载的文件太大（内存不足）。另一个限制是未使用RPL（远程程序加载程序）协议，因为它需要更多字节。
为减轻空间压力，可以使用-D_CHS=0 -D_QUERY_GEOMETRY=0（如果要通过ROM-BIOS的LBA接口进行加载）或-D_LBA=0（如果要通过CHS接口进行加载）来构建加载程序。
要构建加载器，请克隆lmacros和ldosboot存储库，并将它们彼此相邻。可以使用FAT12从ldosboot目录使用NASM构建加载程序：
$ nasm -I ../lmacros/ boot.asm -l boot7e12.lst -D_MAP=boot7e12.map -o boot7e12.bin -D_COMPAT_KERNEL7E
对于FAT16还是这样：
$ nasm -I ../lmacros/ boot.asm -l boot7e16.lst -D_MAP=boot7e16.map -o boot7e16.bin -D_FAT16 -D_COMPAT_KERNEL7E
how to install the loader进入现有的已经格式化的FAT12或FAT16文件系统映像：
dd if=boot7e12.bin of=floppy.img bs=1 count=11 conv=notrunc
dd if=boot7e12.bin of=floppy.img bs=1 count=$((512 - 0x3e)) seek=$((0x3e)) skip=$((0x3e)) conv=notrunc
NASM可以创建整个图像，而不是使用现有图像。我在https://bitbucket.org/ecm/bootimg/src/default/编写了这样一个程序，它的构建方式如下：
nasm -I ../lmacros/ -D_BOOTFILE="'../ldosboot/boot12.bin'" -D_MULTIPAYLOADFILE="'../ldebug/bin/ldebug.com','../ldebug/bin/lddebug.com'" bootimg.asm -o bootimg.img
请注意long def如何在单引号列表项周围有双引号。每个列表条目都被剥离为基本名称（在最后一个斜杠或反斜杠之后），其内容添加到数据区域，并且目录条目添加到根目录。文件名是ASCII且全大写。
ldosboot存储库也包含一个两个扇区的FAT32加载程序，但是我尚未对其进行修改以支持该协议。通过重定位，FAT缓冲区应该已经在内存的顶部。这意味着该文件可以加载到07E00h。但是，ss将处于高段而不是零。除此之外，还可以使用开关指定协议。构建它的命令是nasm -I ../lmacros/ boot32.asm -l boot7e32.lst -D_MAP=boot7e32.map -o boot7e32.bin -D_RELOCATE -D_MEMORY_CONTINUE=0 -D_ZERO_DS -D_ZERO_ES -D_SET_BL_UNIT=0 -D_SET_DL_UNIT=1 -D_LOAD_ADR=07E00h -D_EXEC_SEG_ADJ=-7E0h -D_EXEC_OFS=7E00h -D_OEM_NAME="'KERNEL7E'" -D_LOAD_NAME="'KERNEL7E'" -D_LOAD_EXT="'BIN'"
还有一个用于DOS的inssect程序（在其自己的存储库中），该程序是用加载程序映像构建的，并将其安装到DOS驱动器中。
- 我写了这段代码，但我无法理解我的错误
- 我无法从一个代码实例的列表中删除 None 值，但我可以在另一个实例中。为什么它适用于一个细分市场而不适用于另一个细分市场？
- 是否有可能使 loadstring 不可能等于打印？卢阿
- java中的random.expovariate()
- Appscript 通过会议在 Google 日历中发送电子邮件和创建活动
- 为什么我的 Onclick 箭头功能在 React 中不起作用？
- 在此代码中是否有使用“this”的替代方法？
- 在 SQL Server 和 PostgreSQL 上查询，我如何从第一个表获得第二个表的可视化
- 每千个数字得到
- 更新了城市边界 KML 文件的来源？