Question

我有以下json

{
    "namespace": "monitoring",
    "name": "alok",
    "spec": {
        "replicas": 1,
        "template": {
            "metadata": "aaa",
            "spec": {
                "containers": [
                    {
                        "image": "practodev/test:test",
                        "env": [
                            {
                                "name":"GF_SERVER_HTTP_PORT",
                                "value":"3000"
                            },
                            {
                                "name":"GF_SERVER_HTTPS_PORT",
                                "value":"443"
                            },
                        ]
                    }
                ]
            }
        }
    }
}

如何使用jsonnet添加deployment_env.json？

{
    "env": [
        {
            "name":"GF_AUTH_DISABLE_LOGIN_FORM",
            "value":"false"
        },
        {
            "name":"GF_AUTH_BASIC_ENABLED",
            "value":"false"
        },

    ]
}

我需要将其添加到spec.template.containers [0] .env = deployment_env.json

我写了下面的jsonnet来做到这一点。它追加了一个新元素。但是我需要更改json中现有的第0个容器元素。 请提出建议。

local grafana_envs = (import 'custom_grafana/deployment_env.json');
local grafanaDeployment = (import 'nested.json') + {
    spec+: {
        template+: {
            spec+: {
                containers:+ [{
                    envs: grafana_envs.env,
                }]
            }
        }
    },
};
grafanaDeployment

Answer 1

有关允许通过env数组中的索引向现有容器添加containers[]的实现，请参见下文。

请注意，jsonnet比数组更适合用于对象（即字典/地图），因此它需要通过std.mapWithIndex()进行人为处理，以便能够从其修改条目匹配索引。

local grafana_envs = (import 'deployment_env.json');

// Add extra_env to a container by its idx passed containers array
local override_env(containers, idx, extra_env) = (
  local f(i, x) = (
    if i == idx then x {env+: extra_env} else x
  );
  std.mapWithIndex(f, containers)
);
local grafanaDeployment = (import 'nested.json') + {
    spec+: {
        template+: {
            spec+: {
                containers: override_env(super.containers, 0, grafana_envs.env)
            }
        }
    },
};
grafanaDeployment

Answer 2

另一种实现方式，不依赖于数组索引位置，而是依靠image值（在这里更有意义，因为图像实现必须理解env）

local grafana_envs = (import 'deployment_env.json');

local TARGET_CONTAINER_IMAGE = 'practodev/test:test';

local grafanaDeployment = (import 'nested.json') + {
  spec+: {
    template+: {
      spec+: {
        containers: [
          // TARGET_CONTAINER_IMAGE identifies which container to modify
          if x.image == TARGET_CONTAINER_IMAGE
          then x { env+: grafana_envs.env }
          else x
          for x in super.containers
        ],
      },
    },
  },
};
grafanaDeployment

使用jsonnet覆盖嵌套列表元素

2 个答案: