Question

我有以下输入内容

<?xml version="1.0" encoding="UTF-8"?>
<catalog>
    <cd>
        <carac NAME="aaa" NOT="10"/>
        <value VAL="1"/>
    </cd>
    <cd>
        <carac NAME="aaa" NOT="10"/>
        <value VAL="2"/>
    </cd>
    <cd>
        <carac NAME="aaa" NOT="20"/>
        <value VAL="3"/>
    </cd>
    <cd>
        <carac NAME="aaa" NOT="10"/>
        <value VAL="4"/>
    </cd>
    <cd>
        <carac NAME="bbb" NOT="30"/>
        <value VAL="5"/>
    </cd>
    <cd>
        <carac NAME="bbb" NOT="30"/>
        <value VAL="6"/>
    </cd>
    <cd>
        <carac NAME="ccc" NOT="40"/>
        <value VAL="7"/>
    </cd>
    <cd>
        <carac NAME="ccc" NOT="50"/>
        <value VAL="8"/>
    </cd>
</catalog>

并且我想为每个不同的名称获取所有不同的NOT的总和，因此，如果对于同一个名称，NOT重复出现，则必须只求和一次。

此示例的输出必须为：aaa30 bbb30 ccc90

我的XSL看起来像这样，但是没有给出我想要的结果，而是显示了aaa1020 bbb30 ccc4050

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:key name="nameList" match="catalog/cd/carac" use="@NAME"/>
<xsl:key name="notList" match="catalog/cd/carac" use="concat(@NAME,'_',@NOT)"/>
<xsl:template match="/">
<html> 
<body>
    <xsl:for-each select="//carac[generate-id()=generate-id(key('nameList', @NAME)[1])]">
        <xsl:variable name="name" select="./@NAME"/>
        <xsl:variable name="lines">
            <xsl:for-each select="//carac[generate-id()=generate-id(key('notList',concat($name,'_',@NOT))[1])]">
                <noti>
                    <xsl:value-of select="@NOT"/>
                </noti>
            </xsl:for-each>
        </xsl:variable>
        <xsl:value-of select="$name"/>
        <xsl:value-of select="sum($lines)"/>
    </xsl:for-each>
</body>
</html>
</xsl:template>
</xsl:stylesheet>

Answer 1

这样尝试吗？

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:key name="nameList" match="catalog/cd/carac" use="@NAME"/>
<xsl:key name="notList" match="catalog/cd/carac" use="concat(@NAME, '_', @NOT)"/>

<xsl:template match="/catalog">
    <html> 
        <body>
            <xsl:for-each select="cd/carac[generate-id()=generate-id(key('nameList', @NAME)[1])]">
                <xsl:value-of select="@NAME"/>
                <xsl:variable name="current-group" select="key('nameList', @NAME)" />
                <xsl:value-of select="sum($current-group[generate-id()=generate-id(key('notList', concat(@NAME, '_', @NOT))[1])]/@NOT)"/>
            </xsl:for-each>
        </body>
    </html>
</xsl:template>

</xsl:stylesheet>

XSLT总和串联而不是总和

1 个答案: