Question

我正在尝试使用xslt渲染由我在工作中使用的软件生成的xml文件。 xml中有一些CDATA内容。当我转换它时，CDATA的内容显示为文本，但我希望仅不显示它。我找到了一种使它为空的方法，以便在我不需要利用它时什么也不会出现，但我必须处理所有情况。

我的问题是：如何将所有CDATA内容作为标准文本（可通过value-of访问）管理，以便在我不选择呈现时将其显示？

xml文件如下：

<?xml version="1.0" encoding="UTF-8"?>
<Domain>
  <Properties>
    <Property id="DOM00000" key="mykey1" value="value1"/>
    <Property id="DOM00001" key="mykey2" value="value2"/>
  </Properties>
  <Tokens>
    <Token name="token1" comment=""><![CDATA[mydata1---blah-blah-blah]]></Token>
    <Token name="token2" comment=""><![CDATA[mydata2---blah-blah-blah]]></Token>
  </Tokens>
  <Resources>
    <Resource name="res1" type="W" current="0">
      <Value><![CDATA[10]]></Value>
    </Resource>
    <Resource name="res2" type="W" current="0">
      <Value><![CDATA[10]]></Value>
    </Resource>
  </Resources>
</Domain>

我正在使用的xsl文件是这个：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="/Domain/Properties">
  <table border="1">
    <tr bgcolor="#9acd32">
      <th style="text-align:left">id</th>
      <th style="text-align:left">key</th>
      <th style="text-align:left">value</th>
    </tr>
    <xsl:for-each select="/Domain/Properties/Property">
    <tr>
      <td><xsl:value-of select="@id" /></td>
      <td><xsl:value-of select="@key" /></td>
      <td><xsl:value-of select="@value" /></td>
    </tr>
    </xsl:for-each>
  </table>
  </xsl:template>
  <xsl:template match="/Domain/Tokens/Token">
  </xsl:template>
</xsl:stylesheet>

编辑这是我使用的：

<form method="POST">
    <label for="xmlfileinput">Fichier XML</label><input type="file" name="myxmlfile" id="xmlfileinput" accept=".xml"><br>
    <label for="xslfileinput">Fichier XSL</label><input type="file" name="myxslfile" id="xslfileinput" accept=".xsl"><br>       
    <input type="button" onclick="handleFiles()">
</form>

function handleFiles(e) {
    var myxmlfile = document.getElementById("xmlfileinput").files;
    var myxslfile = document.getElementById("xslfileinput").files;
    var xmlreader = new FileReader();
    var xslreader = new FileReader();
    xmlreader.onload = function() {
        var xml = new DOMParser().parseFromString(xmlreader.result, "text/xml");
        xslreader.onload = function() {
            var xsl = new DOMParser().parseFromString(xslreader.result, "text/xml");
            if (window.ActiveXObject /*|| xhttp.responseType == "msxml-document"*/)
              {
              ex = xml.transformNode(xsl);
              document.getElementById("example").innerHTML = ex;
              }
            // code for Chrome, Firefox, Opera, etc.
            else if (document.implementation && document.implementation.createDocument)
              {
              xsltProcessor = new XSLTProcessor();
              xsltProcessor.importStylesheet(xsl);
              resultDocument = xsltProcessor.transformToFragment(xml, document);
              while (document.getElementById("example").firstChild) {
document.getElementById("example").removeChild(document.getElementById("example").firstChild);
                }
             document.getElementById("example").appendChild(resultDocument);
              }
        };
        xslreader.readAsText(myxslfile[0]); 
    };
    xmlreader.readAsText(myxmlfile[0]);   
}

在这些文件的结果中，未显示令牌中的“ mydata ...”，但此处显示了资源中的“ 10”。

谢谢

Answer 1

您对built-in template rules有疑问，尤其是

<xsl:template match="*|/">
  <xsl:apply-templates/>
</xsl:template>

这意味着所有文档都遍历到Value个元素。

解决方案：：添加另一个空模板，如您已有的模板。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="/Domain/Properties">
  <table border="1">
    <tr bgcolor="#9acd32">
      <th style="text-align:left">id</th>
      <th style="text-align:left">key</th>
      <th style="text-align:left">value</th>
    </tr>
    <xsl:for-each select="/Domain/Properties/Property">
    <tr>
      <td><xsl:value-of select="@id" /></td>
      <td><xsl:value-of select="@key" /></td>
      <td><xsl:value-of select="@value" /></td>
    </tr>
    </xsl:for-each>
  </table>
  </xsl:template>
  <xsl:template match="/Domain/Tokens/Token|/Domain/Resources"/>
</xsl:stylesheet>

Answer 2

我认为这里的问题不是包含CDATA节的元素，而是模板的匹配模式。

您从以下位置开始：

<xsl:template match="/Domain/Properties">

保留根元素Domain的其他子元素（即Tokens和Resources），以供其他模板处理。

您确实有一个与Token匹配的模板，但没有一个与Resource匹配的模板。因此Resources（以及XML可能具有的其他任何分支）都由built-in template rules处理。这样会导致所有文本（不仅是CDATA部分中的文本）被复制到输出中。

在前面的答案中已经提到了这一点。但是，解决方案不是追逐单个马匹，而是关上谷仓门：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:template match="/Domain">
  <table border="1">
    <tr bgcolor="#9acd32">
      <th style="text-align:left">id</th>
      <th style="text-align:left">key</th>
      <th style="text-align:left">value</th>
    </tr>
    <xsl:for-each select="Properties/Property">
    <tr>
      <td><xsl:value-of select="@id" /></td>
      <td><xsl:value-of select="@key" /></td>
      <td><xsl:value-of select="@value" /></td>
    </tr>
    </xsl:for-each>
  </table>
</xsl:template>

</xsl:stylesheet>

XSLT-如何将CDATA作为通用内容进行管理？

2 个答案: