Question

我正在使用JavaExec任务来运行不同的类，但是每当我尝试使用gradle <task>运行其中一个任务时，都会收到错误消息Error: JavaFX runtime components are missing, and are required to run this application。

如果我只是设置mainClassName='exercise1.Cards'或其他任何className，则运行gradle run完全可以。我猜想用JavaExec运行类时找不到JavaFX类，我想知道如何包含它们。

build.gradle：

plugins {
    id 'java'
    id 'application'
    id 'org.openjfx.javafxplugin' version '0.0.7'
}

version '1.0-SNAPSHOT'

sourceCompatibility = 11

repositories {
    mavenCentral()
}

dependencies {
    testCompile group: 'junit', name: 'junit', version: '4.12'
}

javafx {
    modules = [ 'javafx.controls' ]
}

task runExercise1(type: JavaExec) {
    classpath = sourceSets.main.runtimeClasspath
    main = 'exercise1.Cards'
}

task runExercise2(type: JavaExec) {
    classpath = sourceSets.main.runtimeClasspath
    main = 'exercise2.InvestmentCalculator'
}

task runExercise3(type: JavaExec) {
    classpath = sourceSets.main.runtimeClasspath
    main = 'exercise3.PointCircle'
}

task runExercise4(type: JavaExec) {
    classpath = sourceSets.main.runtimeClasspath
    main = 'exercise4.OccurrenceHistogram'
}

Answer 1

org.openjfx.javafxplugin plugin为您管理一些事情。

添加到构建文件时：

javafx {
    modules = [ 'javafx.controls' ]
}

插件translates如下所示：

run {
    doFirst {
        jvmArgs = ['--module-path', classpath.asPath,
                   '--add-modules', 'javafx.controls']
    }
}

但是，如果您创建一个新的JavaExec任务，则似乎插件无法对其进行处理。

鉴于您发布的错误：

错误：缺少JavaFX运行时组件

很明显，可能的解决方法是完全使用插件进行操作，并在使用模块化依赖项时添加预期的jvm args。

所以这应该起作用：

task runExercise1(type: JavaExec) {
    classpath = sourceSets.main.runtimeClasspath
    jvmArgs = ['--module-path', classpath.asPath, 
               '--add-modules', 'javafx.controls' ]
    main = 'exercise1.Cards'
}

或者，您可以创建一个不从Application扩展的启动程序类，因为它会绕过模块化检查（如here所述）。

public class Launcher {

    public static void main(String[] args) {
        // optionally process args to select class to run
        Cards.main(args);
    }
}

然后，您可以添加任务，甚至使用运行时参数来选择要从启动器运行的主类。

task runExercise1(type: JavaExec) {
    classpath = sourceSets.main.runtimeClasspath
    main = 'exercise1.Launcher'
    args 'exercise1' // <-- optionally select class to run
}

如何在JavaExec任务类路径中包含插件依赖项？

1 个答案: