Question

我正在使用Google表格查找公式，但是代码又回来了

“无法匹配'.25oz'”

工作表的链接在这里：
https://docs.google.com/spreadsheets/d/1K1Hb9xV8Ky51Vdiv0SG-zKOEH0ELPNBYwMWhDFfm4l0/edit#gid=168328825

我遇到错误的特定部分是“ Master Cocktail” D5，它尝试搜索我的Spirits表或“ Beer NA Bev”表。根据所用的盎司价格确定合适的价格。

我在单元格中使用的代码是：

=ArrayFormula(IF(C5="","",vlookup($B5,{'Beer NA Bev'!$A$63:$H$71;Spirits!$A$2:$I$325},MATCH($C5,{'Beer NA Bev'!$A$62:$K$62;Spirits!$A$3:$J$3},0),FALSE)))

Answer 1

首先需要{'Beer NA Bev'!$A$63:$H$71; Spirits!$A$2:$I$325}
是：{'Beer NA Bev'!$A$63:$I$71; Spirits!$A$2:$I$325}例如相同数量的列
然后，您可以将整个MATCH放到IFERROR处，在其中放置IF和两个VLOOKUP（一个用于TRUE一面和FALSE一面）来区分啤酒和烈酒，因为两张纸上都有.25oz。然后您可以插入简单的IFS来检查/搜索正确的.25oz价格并返回主要VLOOKUP的列号。
请检查以下类似问题：{{3} }

类似这样的东西：

 IFERROR(IF(VLOOKUP(B5, 'Beer NA Bev'!$A$63:$I$71, 1, 0)<>"", IFS(C5=".25oz", 5, 
                                                                  C5=".5oz",  6, 
                                                                  C5=".75oz", 7, 
                                                                  C5="1oz",   8,
                                                                  C5="2oz",   9), ), 
         IF(VLOOKUP(B5, Spirits!$A$2:$I$325,       1, 0)<>"", IFS(C5="2oz",   4,
                                                                  C5="1.5oz", 5,
                                                                  C5="1oz",   6,
                                                                  C5=".75oz", 7,
                                                                  C5=".5oz",  8,
                                                                  C5=".25oz", 9), ))

整个公式将是：

=ARRAYFORMULA(IF(C5="", "",
 VLOOKUP($B5, {'Beer NA Bev'!$A$63:$I$71;
                     Spirits!$A$2:$I$325},
 IFERROR(IF(VLOOKUP(B5, 'Beer NA Bev'!$A$63:$I$71, 1, 0)<>"", IFS(C5=".25oz", 5, 
                                                                  C5=".5oz",  6, 
                                                                  C5=".75oz", 7, 
                                                                  C5="1oz",   8,
                                                                  C5="2oz",   9), ), 
         IF(VLOOKUP(B5, Spirits!$A$2:$I$325,       1, 0)<>"", IFS(C5="2oz",   4,
                                                                  C5="1.5oz", 5,
                                                                  C5="1oz",   6,
                                                                  C5=".75oz", 7,
                                                                  C5=".5oz",  8,
                                                                  C5=".25oz", 9), )), 0)))

https://stackoverflow.com/a/54680420/5632629

Vlookup无法找到参考单元格

1 个答案: