Question

我对XSLT还是很陌生，不知道如何为所需的转换找到解决方案。我们收到一个SOAP请求，需要检查是否存在某个标记（步骤）。如果不存在，我想将其添加到SOAP消息中。

我们正在Azure API Management上运行该接口，该接口仅在版本1.0中允许XSLT。

XML示例

<?xml version="1.0" encoding="utf-8"?>
<soap:Envelope xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" 
xmlns:xsd="http://www.w3.org/2001/XMLSchema" 
xmlns:soap="http://schemas.xmlsoap.org/soap/envelope/">
<soap:Body>
   <ProductionToSupply xmlns="http://somenamespace.com">
      <ProductionDataList>
         <ProductionData>
            <Material_Number>5</Material_Number>
            <Doc_Number>1234</Doc_Number>
            <Description>abcde</Description>
         </ProductionData>
      </ProductionDataList>
   </ProductionToSupply>
</soap:Body>
</soap:Envelope>

XSLT

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" 
xmlns:soap="http://schemas.xmlsoap.org/soap/envelope/"  
xmlns:ns1="http://somenamespace.com" exclude-result-prefixes="ns1">

<xsl:output method="xml" indent="yes"/>

<xsl:template match="@*|node()">
  <xsl:copy>
    <xsl:apply-templates select="@*|node()"/>
  </xsl:copy>
</xsl:template>

<xsl:template match="soap:Envelope/soap:Body/ns1:ProductionToSupply/ns1:ProductionDataList/ns1:ProductionData/ns1:Doc_Number">
<xsl:if test="not(soap:Envelope/soap:Body/ns1:ProductionToSupply/ns1:ProductionDataList/ns1:ProductionData/ns1:Steps)">
    <Steps xmlns="http://somenamespace.com">NA</Steps>
</xsl:if>
  <xsl:copy>
    <xsl:apply-templates select="@*|node()"/>
  </xsl:copy>
</xsl:template>


</xsl:stylesheet>

所需的输出

<?xml version="1.0" encoding="utf-8"?>
<soap:Envelope xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" 
xmlns:xsd="http://www.w3.org/2001/XMLSchema" 
xmlns:soap="http://schemas.xmlsoap.org/soap/envelope/">
<soap:Body>
   <ProductionToSupply xmlns="http://somenamespace.com">
      <ProductionDataList>
         <ProductionData>
            <Material_Number>5</Material_Number>
            <Doc_Number>1234</Doc_Number>
            <Description>abcde</Description>
            <Steps>NA</Steps>
         </ProductionData>
      </ProductionDataList>
   </ProductionToSupply>
</soap:Body>
</soap:Envelope>

如果“ ProductionData”组中不存在标签，则预期结果将是仅添加标签“ Steps”，但我不知道如何设置适当的匹配模式。

在此先感谢您的帮助蒂姆

Answer 1

如果仅当组ProductionData不具有Steps元素时才匹配它，则模板匹配就是这样

 <xsl:template match="ns1:ProductionData[not(ns1:Steps)]">

然后，您可以复制ProductionData元素及其子节点，并同时滑入Steps元素

尝试使用此XSLT

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" 
xmlns:soap="http://schemas.xmlsoap.org/soap/envelope/"  
xmlns:ns1="http://somenamespace.com" exclude-result-prefixes="ns1">

<xsl:output method="xml" indent="yes"/>

<xsl:template match="@*|node()">
  <xsl:copy>
    <xsl:apply-templates select="@*|node()"/>
  </xsl:copy>
</xsl:template>

<xsl:template match="ns1:ProductionData[not(ns1:Steps)]">
  <xsl:copy>
    <xsl:apply-templates select="@*|node()"/>
    <Steps xmlns="http://somenamespace.com">NA</Steps>
  </xsl:copy>
</xsl:template>
</xsl:stylesheet>

这会将Steps添加为最后一个孩子。如果您想在Doc_Number之后立即使用它，请用此模板替换

<xsl:template match="ns1:ProductionData[not(ns1:Steps)]/ns1:Doc_Number">
  <xsl:copy>
    <xsl:apply-templates select="@*|node()"/>
  </xsl:copy>
  <Steps xmlns="http://somenamespace.com">NA</Steps>
</xsl:template>

如果标签不存在，则使用XSLT将XML标签添加到SOAP消息中

1 个答案: