Question

我有一个TListView，其项目是文件，用户可以通过双击打开它们。

为此，我将文件保存在Windows temp文件夹中，启动一个线程，以ShellExecuteEx()打开保存的文件，然后让其等待ShellExecuteInfo.hProcess，如下所示：

TNotifyThread = class(TThread)
private
  FFileName: string;
  FFileAge: TDateTime;
public
  constructor Create(const FileName: string; OnClosed: TNotifyEvent); overload;
  procedure Execute; override;

  property FileName: String read FFileName;
  property FileAge: TDateTime read FFileAge;
end;

{...}

constructor TNotifyThread.Create(const FileName: string; OnClosed: TNotifyEvent);
begin
  inherited Create(True);
  if FileExists(FileName) then
    FileAge(FileName, FFileAge);

  FreeOnTerminate := True;
  OnTerminate := OnClosed;
  FFileName := FileName;

  Resume;
end;

procedure TNotifyThread.Execute;
var
  se: SHELLEXECUTEINFO;
  ok: boolean;
begin
  with se do
  begin
    cbSize := SizeOf(SHELLEXECUTEINFO);
    fMask := SEE_MASK_INVOKEIDLIST or SEE_MASK_NOCLOSEPROCESS or SEE_MASK_NOASYNC;
    lpVerb := PChar('open');
    lpFile := PChar(FFileName);
    lpParameters := nil;
    lpDirectory := PChar(ExtractFilePath(ParamStr(0)));
    nShow := SW_SHOW;
  end;

  if ShellExecuteEx(@se) then
  begin
    WaitForSingleObject(se.hProcess, INFINITE);
    if se.hProcess <> 0 then
      CloseHandle(se.hProcess);
  end;
end;

这样，我可以使用TThread.OnTerminate事件在用户关闭文件后回写对该文件所做的任何更改。

我现在借助JclShell.DisplayContextMenu()（使用IContextMenu）显示Windows上下文菜单。

我的目标：等待上下文菜单中选择的已执行操作（例如，“属性”，“删除”等）完成（或以任何方式获得通知），以便我可以检查临时文件中的更改以将其写回，或者在删除的情况下删除TListItem。

由于CMINVOKECOMMANDINFO不会像SHELLEXECUTEINFO那样返回进程句柄，因此我无法以相同的方式进行操作。

将MakeIntResource(commandId-1)分配给SHELLEXECUTEINFO.lpVerb导致对ShellExecuteEx()的呼叫因EAccessViolation而崩溃。 SHELLEXECUTEINFO不支持此方法。

我尝试使用IContextMenu.GetCommandString()获取命令字符串，并从TrackPopupMenu()获取命令ID，以便稍后将其传递给SHELLEXECUTEINFO.lpVerb，但是GetCommandString()不会为以下命令返回命令点击了一些项目。

工作菜单项：

属性，编辑，复制，剪切，打印，7z：添加到存档（动词为“ SevenZipCompress”，不会返回processHandle），KaspserskyScan（动词是“ KL_scan”，不会返回processHandle）

不起作用：

“打开方式”或“发送给”中的任何内容

这仅仅是IContextMenu实现的错误吗？

也许与我使用AnsiString有关？不过，我无法GCS_VERBW工作。有没有比这更好的方法来可靠地获得CommandString？

function CustomDisplayContextMenuPidlWithoutExecute(const Handle: THandle; 
const Folder: IShellFolder;
  Item: PItemIdList; Pos: TPoint): String;
var
  ContextMenu: IContextMenu;
  ContextMenu2: IContextMenu2;
  Menu: HMENU;
  CallbackWindow: THandle;
  LResult: AnsiString;
  Cmd: Cardinal;
begin
  Result := '';
  if (Item = nil) or (Folder = nil) then
    Exit;
  Folder.GetUIObjectOf(Handle, 1, Item, IID_IContextMenu, nil,
    Pointer(ContextMenu));
  if ContextMenu <> nil then
  begin
    Menu := CreatePopupMenu;
    if Menu <> 0 then
    begin
      if Succeeded(ContextMenu.QueryContextMenu(Menu, 0, 1, $7FFF, CMF_EXPLORE)) then
      begin
        CallbackWindow := 0;
        if Succeeded(ContextMenu.QueryInterface(IContextMenu2, ContextMenu2)) then
        begin
          CallbackWindow := CreateMenuCallbackWnd(ContextMenu2);
        end;
        ClientToScreen(Handle, Pos);
        cmd := Cardinal(TrackPopupMenu(Menu, TPM_LEFTALIGN or TPM_LEFTBUTTON or
          TPM_RIGHTBUTTON or TPM_RETURNCMD, Pos.X, Pos.Y, 0, CallbackWindow, nil));
        if Cmd <> 0 then
        begin
          SetLength(LResult, MAX_PATH);
          cmd := ContextMenu.GetCommandString(Cmd-1, GCS_VERBA, nil, LPSTR(LResult), MAX_PATH);
          Result := String(LResult);
        end;
        if CallbackWindow <> 0 then
          DestroyWindow(CallbackWindow);
      end;
      DestroyMenu(Menu);
    end;
  end;
end;

我已经阅读了How to host an IContextMenu上Raymond Chen的博客，以及关于MSDN的研究（例如CMINVOKECOMMANDINFO，GetCommandString()，SHELLEXECUTEINFO和TrackPopupMenu()），但我可能错过了一些琐碎的事情。

Answer 1

我最终使用TJvChangeNotify来监视Windows临时文件夹，同时将受监视的文件保留在TDictionary<FileName:String, LastWrite: TDateTime>中。

因此，每当TJvChangeNotify触发OnChangeNotify事件时，我都可以检查哪些监视文件已删除（通过检查是否存在）或已更改（通过比较上次写入时间）。

示例ChangeNotifyEvent：

procedure TFileChangeMonitor.ChangeNotifyEvent(Sender: TObject; Dir: string;
  Actions: TJvChangeActions);
var
  LFile: TPair<String, TDateTime>;
  LSearchRec: TSearchRec;
  LFoundErrorCode: Integer;
begin
  for LFile in FMonitoredFiles do
  begin
    LFoundErrorCode := FindFirst(LFile.Key, faAnyFile, LSearchRec);
    try
      if LFoundErrorCode = NOERROR then
      begin
        if LSearchRec.TimeStamp > LFile.Value then
        begin
          // do something with the changed file
          {...}

          // update last write time
          FMonitoredFiles.AddOrSetValue(LFile.Key, LSearchRec.TimeStamp);
        end;
      end // 
      else if (LFoundErrorCode = ERROR_FILE_NOT_FOUND) then
      begin
        // do something with the deleted file
        {...}

        // stop monitoring the deleted file
        FMonitoredFiles.Remove(LFile.Key);
      end;
    finally
      System.SysUtils.FindClose(LSearchRec);
    end;
  end;
end;

等待IContextMenu.InvokeCommand

1 个答案: