Question

我有两个如下文件：

文件1：

column1 column2
---------------
h1      0
h2      0
h3      0
h4      0

文件2：

column1 column2
---------------
h1      1
h2      1

我想比较这两个文件并编写一个新文件，如下所示：

column1 column2
---------------
h1      1
h2      1
h3      0
h4      0

最好的方法是什么，因为将文件读取到数组并进行循环并不能完全得到file3的输出。

Answer 1

假设每个文件中每一行的第一个字段都是一个“键”，该键指示是否应将file1.txt中的行替换为file2.txt中的行，您可以尝试：

use feature qw(say);
use strict;
use warnings;

my %lines;
my @lines;
my $fn = 'file1.txt';
open ( my $fh, '<', $fn ) or die "Could not open file '$fn': $!";
while (my $line = <$fh>) {
    chomp $line;
    my ( $key, @rest ) = split " ", $line;
    push @{ $lines{$key} }, $. ;
    push @lines, $line;
}
close $fh;
my $fn2 = 'file2.txt';
open ( my $fh2, '<', $fn2 ) or die "Could not open file '$fn2': $!";
while( my $line = <$fh2> ) {
    chomp $line;
    my ( $key, @rest ) = split " ", $line;
    if ( exists $lines{$key} ) {
        for my $line_no (@{ $lines{$key} }) {
            $lines[$line_no -1] = $line;
        }
    }
}
close $fh2;

say for @lines;

输出：

h1 1
h2 1
h3 0
h4 0

编辑：还将未由file2.txt更新的所有行都设置为“ $ key 0”：

[...]
my %used_keys;
while( my $line = <$fh2> ) {
    chomp $line;
    my ( $key, @rest ) = split " ", $line;
    if ( exists $lines{$key} ) {
        for my $line_no (@{ $lines{$key} }) {
            $lines[$line_no -1] = $line;
        }
        $used_keys{$key} = 1;
    }
}
close $fh2;
delete @lines{ keys %used_keys };
for my $key (keys %lines) {
    for my $line_no (@{ $lines{$key} }) {
        $lines[$line_no -1] = "$key 0";
    }
}
[...]

如何从Perl中的另一个文件覆盖一个文件的更改列

1 个答案: