Question

我想证明在有限数量的情况下参数化的属性。我想将问题分为每种情况一个实例，然后分别解决每个实例。这是清除问题的示例：

module Minimal
open FStar.List
open FStar.Tactics
open FStar.Reflection.Data

unfold let lst = [0;1]

unfold let prop i = 
  match i with
  | 0 -> i == 0
  | 1 -> i == 1
  | _ -> False

val propHolds (i:int) : Lemma (requires (List.mem i lst)) (ensures (prop i))

在这种情况下，情况由列表lst定义。我可以轻松证明propHolds：

let propHolds i =
  assert_by_tactic (prop 0) (fun () -> norm[delta;primops;iota;zeta]; dump "normalized"; trivial ());
  assert_by_tactic (prop 1) (fun () -> norm[delta;primops;iota;zeta]; dump "normalized"; trivial ())

但是我显然不想为每种情况编写一个单独的assert_by_tactic（不是当可能有成千上万时..）。我想以某种方式自动为lst中的所有元素生成上述证明。

我尝试了各种事情，这是其中之一：

  assert_by_tactic (let rec props i =
                       if i = 0 then prop 0
                       else (prop i) /\ (props (i-1))
                    in
                      props 1) (fun () -> norm[delta;primops;iota;zeta]; dump "normalized")

不幸的是，这并没有完全达到我的期望，assert_by_tactic失败了（并且没有以我期望的方式减少）。我想我缺少关于归一化的明显知识，但是在F *中执行此操作的规范方法是什么？如果解决方案指向“案例” /断言，如果存在则失败，则奖励点。

Answer 1

F *的类型系统仅确保对术语的弱归一化。例如，当在不一致的上下文中简化时，类型良好的开放术语可能会有所不同。为了防止这种情况，F *规范化器采用了各种启发式方法，默认情况下，保守地拒绝减少未归约匹配项中的递归调用。这就是阻止List.mem完全还原为级联的未还原if / then / else（如果/ then / else只是用于匹配布尔值的糖）。

List.memP是F *标准库中的一个相关函数，在这种情况下，它更易于还原，因为它不会在内部阻止未归约的匹配。请注意，List.memP不必总是比List.mem更友好地归约-后者是布尔值，因此在某些情况下它可以进行更多的计算（例如List.mem 3 [1;2;3]可以简化为true ）;

尝试此程序：

module Minimal
open FStar.Tactics

let lst = [0;1;2;3;4;5;6;7;8;9;10]

let prop i =
  match i with
  | 0 -> i == 0
  | 1 -> i == 1
  | 2 -> i == 2
  | 3 -> i == 3
  | 4 -> i == 4
  | 5 -> i == 5
  | 6 -> i == 6
  | 7 -> i == 7
  | 8 -> i == 8
  | 9 -> i == 9
  | 10 -> i == 10
  | _ -> False

let propHolds (i:int) =
  assert (List.memP i lst ==> prop i) 
      by (dump "A";
          norm [delta_only [`%List.memP; `%lst]; iota; zeta; simplify];
          dump "B")

在dump B，您将看到假设简化为嵌套析取。 Z3可以从那里轻松证明目标。

这是另一种方法，这次没有战术。

let trigger_norm (a:Type) 
  : Lemma
    (requires a)
    (ensures (Pervasives.norm [delta_only [`%List.memP; `%lst]; iota; zeta; simplify] a))
  = ()


let propHolds (i:int) 
  : Lemma
    (requires List.memP i lst)
    (ensures prop i)
  = trigger_norm (List.memP i lst)

现在，针对jebus的以下评论，您可以进一步采用策略来证明后置条件，尽管SMT求解器确实非常快地执行了此操作……因此，除非您这样做，否则我不会使用策略这样做有一些特定的强烈理由。

这是另一个解决方案：

module SO
open FStar.Tactics

let lst = [0;1;2;3;4;5;6;7;8;9;10]

let pred i =
  match i with
  | 0 -> i == 0
  | 1 -> i == 1
  | 2 -> i == 2
  | 3 -> i == 3
  | 4 -> i == 4
  | 5 -> i == 5
  | 6 -> i == 6
  | 7 -> i == 7
  | 8 -> i == 8
  | 9 -> i == 9
  | 10 -> i == 10
  | _ -> False

let case_impl (a b c:Type) 
  : Lemma
    (requires (a ==> c) /\ (b ==> c))
    (ensures (a \/ b) ==> c) 
  = ()

let solve_pred_impl () : Tac unit =
    let eq = implies_intro () in
    rewrite eq;
    norm [delta_only [`%pred]; iota];
    trivial()

let test i =  
  assert (List.memP i lst ==> pred i)
      by (norm [delta_only [`%List.memP; `%lst]; iota; zeta; simplify];
          let _ = repeat 
            (fun () ->
              mapply (`case_impl); 
              split();
              solve_pred_impl()) in
          solve_pred_impl())

使用规范化器减少递归函数

1 个答案: