通过批处理文件将计算机的UUID和IP存储在文件中

Question

我需要通过批处理文件生成一个文本文件，其中包含计算机的UUID和IP数据，如下所示：

  

CAA8A570-86FF-81E4-3398-0071C21A28CE 192.168.0.0

我使用了这些命令，但我不知道如何将信息放入同一文件中。

wmic csproduct get "UUID" > C:\UUID.txt
ipconfig /all | find /i "phy" > C:\MAC.txt

Answer 1

可以通过批处理文件获取计算机的IP地址和UUID。但是，尚不清楚您要如何处理它们。因此，我将向您展示如何获取它们，并将它们的值存储在变量中。然后做任何你想做的事：

@echo off
rem Script to get the UUID and IP address of this computer.

rem Get IP address:
for /F "tokens=2 delims=(:" %%A IN ('ipconfig /all ^| findstr /c:"IPv4"') do (
    for /F "tokens=*" %%B IN ("%%A") do (
        rem Set the IP address into the IP_address variable:
        set "IP_address=%%B"
    )
)

rem Get UUID:
for /F %%A IN ('(wmic csproduct get "UUID"^) ^| findstr /c:"-"') do (
    rem Set the UUID in the UUID variable:
    set "UUID=%%A"
)

rem Echo the results
echo We have found that this computer has a UUID of %UUID%.
echo We have also found the IP address of this computer. It is: %IP_address%

如果要将它们重定向到问题中提到的格式的文件，请使用：

(echo %UUID%  %IP_address%)>filename.txt

如果要附加它们，请使用：

(echo %UUID%  %IP_address%)>>filename.txt

如果我向您展示已处理的每个命令的输出，您可能会更好地理解我的代码的工作原理。

---

ipconfig /all | findstr /c:"Ipv4"：

对我来说，输出是

   IPv4 Address. . . . . . . . . . . : xxx.xxx.x.x(Preferred)

我不确定您是否得到这些括号。

处理命令的for /F循环具有tokens=2和delims=(:选项。

• delims=(:选项意味着不将字符(和:解析为标记。然后，令牌将（由|分隔）：IPv4 Address. . . . . . . . . . . | xxx.xxx.x.x|Preferred)。如您所见，我已经删除了字符(:。包含IP地址的令牌是第二个，因此我使用以下命令进行选择：
• tokens=2选项。

由于开始处有一个空格，我在其中进行了另一个循环以使用tokens=*选项删除开始处的空格。

最后，将IP地址设置到IP_address变量中，即可使用！

---

(wmic csproduct get "UUID") | findstr /c:"-"：

此命令的输出仅为UUID（此处没有其他循环）：

F5A91381-529E-11CB-A155-BF406BD05412

因此，我将其设置为变量（UUID）即可使用！

---

为了解“重定向”和“附加”的含义，我建议您阅读以下链接：

• https://www.robvanderwoude.com/redirection.php
• https://ss64.com/nt/syntax-redirection.html

另外，我建议打开一个cmd，键入以下命令并仔细阅读其输出：

• for /?
• wmic /?
• findstr /?
• rem /?
• set /?
• echo /?

这肯定会帮助您理解我的代码。