Question

我正在尝试使用IF THEN样式的AQL，但是我可以在AQL文档中找到的唯一相关运算符是三元运算符。我试图将IF THEN语法添加到我已经可以使用的AQL中，但是无论我尝试如何，都会出现语法错误。

LET doc = DOCUMENT('xp/a-b')
LET now = DATE_NOW()
doc == null || now - doc.last >= 45e3 ? 
  LET mult = (doc == null || now - doc.last >= 6e5 ? 1 : doc.multiplier)
  LET gained = FLOOR((RAND() * 3 + 3) * mult)
  UPSERT {_key: 'a-b'}
  INSERT {
    amount: gained,
    total: gained,
    multiplier: 1.1,
    last: now
  }
  UPDATE {
    amount: doc.amount + gained,
    total: doc.total + gained,
    multiplier: (mult < 4 ? FLOOR((mult + 0.1) * 10) / 10 : 4),
    last: now
  }
  IN xp
  RETURN NEW
 : 
  RETURN null

给出以下错误消息：

stacktrace: ArangoError: AQL: syntax error, unexpected identifier near 'doc == null || now - doc.last >=...' at position 1:51 (while parsing)

Answer 1

三元运算符不能像if / else构造那样用于尝试。它用于条件（子）表达式，就像您用来计算mult一样。它本身不能独立存在，如果您像if-expression一样编写它，则无法将其返回或分配给它。

此外，它需要大括号，但实际的问题是主体包含诸如LET，UPSERT和RETURN之类的操作。这些是无法在表达式内部使用的语言构造。

如果我理解正确，则您希望：

如果集合a-b中尚不存在密钥为xb的文档，请插入新文档
如果确实存在，则进行更新，但前提是上一次更新是在45秒或更长时间之前

以下查询对您有用吗？

FOR id IN [ 'xp/a-b' ]
    LET doc = DOCUMENT(id)
    LET key = PARSE_IDENTIFIER(id).key
    LET now = DATE_NOW()
    FILTER doc == null || now - doc.last >= 45e3
    LET mult = (doc == null || now - doc.last >= 6e5 ? 1 : doc.multiplier)
    LET gained = FLOOR((RAND() * 3 + 3) * mult)
    UPSERT { _key: key }
    INSERT {
        _key: key,
        amount: gained,
        total: gained,
        multiplier: 1.1,
        last: now
    }
    UPDATE {
        amount: doc.amount + gained,
        total: doc.total + gained,
        multiplier: (mult < 4 ? FLOOR((mult + 0.1) * 10) / 10 : 4),
        last: now
    }
    IN xp
    RETURN NEW

我在_key上添加了INSERT，否则文档将获得一个自动生成的密钥，这似乎不是故意的。使用FOR循环和FILTER就像是IF构造（没有ELSE）。由于这是一个数据修改查询，因此无需显式RETURN，并且在您的原始查询中，您RETURN null都必须使用ELSE。虽然您的查询结果将产生[ null ]，但是如果您尝试快速连续执行查询而没有任何内容被更新或插入，则我的结果将产生[ ]（确实为空的结果）。

请注意，必须使用PARSE_IDENTIFIER()从文档ID字符串中获取密钥并执行INSERT { _key: key }。使用INSERT { _key: doc._key }时，您会在插入情况下遇到无效的文档密钥错误，因为如果没有文档xp/a-b，DOCUMENT()返回null并且doc._key也是null，导致_key: null-无效。

在AQL中使用IF THEN的正确方法是什么？

1 个答案: