Question

我需要使用xslt将xml转换为另一种xml格式的帮助。尝试使用下面的.xsl文件，但无法正常工作，请帮助。

proguardFiles

下面是源XML

 <?xml version="1.0" encoding="UTF-8"?>
  <xsl:stylesheet version="1.0"   
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method ="xml" indent ="yes"/>
  <xsl:template match="Mappings/Source/MapToType/MapTo/*">
  <xsl:copy>
      <xsl:for-each-group select="Source" group-by="name">
          <xsl:apply-templates select="." />
      </xsl:for-each-group>
  </xsl:copy>
  </xsl:template>

    <xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
   </xsl:template>
   </xsl:stylesheet>

预期输出如下。

  <?xml version='1.0' encoding='UTF-8'?>
   <Mappings version="1.0">
   <Source name="testA" type="testType" reg="Good">
    <MapToType type="Tiger">
        <MapTo name="Org" reg="Ver1.0"/>
    </MapToType>
   </Source>
  <Source name="testB" type="testType" reg="Good">
    <MapToType type="Tiger">
        <MapTo name="Org2" reg="Ver2.0"/>
    </MapToType>
  </Source>
  <Source name="testA" type="testType" reg="Good">
    <MapToType type="Tiger">
        <MapTo name="Org3" reg="Ver3.0"/>
    </MapToType>
   </Source>
</Mappings>

有人对如何编写条件以显示为output.xml有解决方案吗？

Answer 1

首先请注意，xsl:for-each-group是XSLT 2.0命令，因此您应该确保使用的处理器可以处理XSLT 2.0

无论如何，它不起作用的一个原因是，当您执行<xsl:for-each-group select="Source" group-by="name">时，您所使用的模板与MapTo相匹配。由于选择将相对于此MapTo元素，因此您将寻找名为Source的子元素，其中没有子元素。

（编辑：或者，正如Martin Honnen在评论中正确指出的那样，模板实际上匹配MapTo的子元素，而不匹配MapTo本身的子元素，因此不会匹配任何东西，因此永远不会匹配....）

您应该真正更改模板以匹配Mappings ...

<xsl:template match="Mappings">
  <xsl:copy>
    <xsl:apply-templates select="@*" />
     <xsl:for-each-group select="Source" group-by="@name">

请注意，假设在分组的MapToType元素中可能有Source个元素，而不同类型的元素，那么您可能需要在该元素中嵌套xsl:for-each-group。

尝试此XSLT。...

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method ="xml" indent ="yes"/>

  <xsl:template match="Mappings">
    <xsl:copy>
      <xsl:apply-templates select="@*" />
      <xsl:for-each-group select="Source" group-by="@name">
        <xsl:copy>
          <xsl:apply-templates select="@*" />
          <xsl:for-each-group select="current-group()/MapToType" group-by="@type">
            <xsl:copy>
             <xsl:apply-templates select="@*" />
             <xsl:apply-templates select="current-group()/MapTo" />
            </xsl:copy>
          </xsl:for-each-group>
        </xsl:copy>
      </xsl:for-each-group>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>
</xsl:stylesheet>

或者，如果MapToType对于每个分组的type元素总是具有相同的Source，则可以将XSLT简化为此。

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method ="xml" indent ="yes"/>

  <xsl:template match="Mappings">
    <xsl:copy>
      <xsl:apply-templates select="@*" />
      <xsl:for-each-group select="Source" group-by="@name">
        <xsl:copy>
          <xsl:apply-templates select="@*" />
          <MapToType>
            <xsl:apply-templates select="MapToType/@*" />
            <xsl:apply-templates select="current-group()/MapToType/MapTo" />
          </MapToType>
        </xsl:copy>
      </xsl:for-each-group>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>
</xsl:stylesheet>

编辑：如果仅使用XSLT 1.0，则需要使用一种称为Muenchian分组的技术。如果您是XSLT的新手，这将是不堪重负的，尤其是在这种情况下，如果您有嵌套分组，需要考虑父级分组。

然后尝试此XSLT：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method ="xml" indent ="yes"/>

  <xsl:key name="Sources" match="Source" use="@name" />
  <xsl:key name="MapToTypes" match="MapToType" use="concat(../@name, @type)" />

  <xsl:template match="Mappings">
    <xsl:copy>
      <xsl:apply-templates select="@*" />
      <xsl:for-each select="Source[generate-id() = generate-id(key('Sources', @name)[1])]">
        <xsl:copy>
          <xsl:apply-templates select="@*" />
          <xsl:for-each select="key('Sources', @name)/MapToType[generate-id() = generate-id(key('MapToTypes', concat(../@name, @type))[1])]">
            <xsl:copy>
             <xsl:apply-templates select="@*" />
             <xsl:apply-templates select="key('MapToTypes', concat(../@name, @type))/MapTo" />
            </xsl:copy>
          </xsl:for-each>
        </xsl:copy>
      </xsl:for-each>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>
</xsl:stylesheet>

在http://xsltfiddle.liberty-development.net/jyRYYhX上查看它的运行情况

在http://www.jenitennison.com/xslt/grouping/muenchian.html上阅读Muenchian分组。然后，再次阅读。再来一次...

使用节点和属性上的分组依据将xslt从xml转换为xml

1 个答案: