Question

我有一个用于注册用户的命令对象，我想检查用户的年龄。此命令对象具有服务依赖性。如何为dateOfBirth属性测试自定义验证器？现在看来，直接来自文档，here。

class RegisterUserCommand {

  def someService

  String username
  String password
  String password2
  String email
  Date dateOfBirth

  static constraints = {
    // other constraints
    dateOfBirth blank: false, validator: {val, obj ->
      return obj.someService.calculateAge(val) >= 18
    }
  }

所以基本上问题是：如何模拟验证器闭包的'obj'参数？

Answer 1

在命令对象上测试验证的最简单方法是使用GrailsUnitTestCase.mockForConstraintsTests。模拟验证方法将应用于您的命令对象，您可以像在测试之外一样调用validate()。

这是一个如何编写单元测试的示例。 blank约束对日期没有意义，因此我将其更改为nullable: false。

import grails.test.GrailsUnitTestCase

class RegisterUserCommandTests extends GrailsUnitTestCase {
    RegisterUserCommand cmd

    protected void setUp() {
        super.setUp()
        cmd = new RegisterUserCommand()
        mockForConstraintsTests RegisterUserCommand, [cmd]
    }

    void testConstraintsNull() {
        cmd.dateOfBirth = null
        cmd.someService = [calculateAge: { dob -> 18 }]
        def result = cmd.validate()
        assert result == false
        assert cmd.errors.getFieldErrors('dateOfBirth').code ==  ['nullable']
    }

    void testConstraintsCustom() {
        cmd.dateOfBirth = new Date()
        cmd.someService = [calculateAge: { dob -> 17 }]
        def result = cmd.validate()
        assert result == false
        assert cmd.errors.getFieldErrors('dateOfBirth').code == ['validator.invalid']
    }
}

请注意，您的服务不会在单元测试中注入（尽管将在集成测试中），因此您需要模拟它，如上所述，或创建实例并将其分配给cmd.someservice。

单元测试具有依赖性的命令对象的自定义验证器

1 个答案: