Question

我有一个属性，其值可能是一个或多个由逗号分隔的文本字符串。我希望使用XSL将属性值转换为它们自己的元素;

e.g

<post title='Hello World" tags="Test,Hello,World />

我希望它转变为;

<post>
<title>Hello World</title>
<tag>Test</tag>
<tag>Hello</tag>
<tag>World</tag>
</post>

这可能吗？ TIA

Answer 1

有几种方法可以做到这一点。

<强>予。在XSLT 1.0中使用递归调用的命名模板这种转变：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

    <xsl:template match="/*">
      <xsl:copy>
        <xsl:apply-templates select="node()|@*"/>
      </xsl:copy>
    </xsl:template>

    <xsl:template match="@*[not(name()='tags')]">
      <xsl:element name="{name()}">
        <xsl:value-of select="."/>
      </xsl:element>
    </xsl:template>

    <xsl:template match="@tags">
      <xsl:call-template name="tokenize">
        <xsl:with-param name="pText" 
         select="concat(., ',')"/>
      </xsl:call-template>
    </xsl:template>

    <xsl:template name="tokenize">
      <xsl:param name="pText"/>

      <xsl:if test="string-length($pText)">
        <tag>
          <xsl:value-of select=
           "substring-before($pText, ',')"/>
        </tag>

        <xsl:call-template name="tokenize">
          <xsl:with-param name="pText" select=
           "substring-after($pText, ',')"/>
        </xsl:call-template>
      </xsl:if>
    </xsl:template>
</xsl:stylesheet>

应用于最初提供的XML文档（已更正为格式良好）：

<post title="Hello World" 
      tags="Test,Hello,World" />

产生所需的结果：

<post>
   <title>Hello World</title>
   <tag>Test</tag>
   <tag>Hello</tag>
   <tag>World</tag>
</post>

<强> II。使用FXSL 1.x

中的str-split-to-words模板/功能

此处FXSL提供标记化功能：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ext="http://exslt.org/common"
>

   <xsl:import href="strSplit-to-Words.xsl"/>

   <xsl:output indent="yes" omit-xml-declaration="yes"/>

    <xsl:template match="/*">
      <xsl:copy>
        <xsl:apply-templates select="node()|@*"/>
      </xsl:copy>
    </xsl:template>

    <xsl:template match="@*[not(name()='tags')]">
      <xsl:element name="{name()}">
        <xsl:value-of select="."/>
      </xsl:element>
    </xsl:template>

    <xsl:template match="@tags">
    <xsl:variable name="vwordNodes">
      <xsl:call-template name="str-split-to-words">
        <xsl:with-param name="pStr" select="."/>
        <xsl:with-param name="pDelimiters" 
                  select="','"/>
      </xsl:call-template>
    </xsl:variable>

    <xsl:apply-templates select="ext:node-set($vwordNodes)/*"/>
    </xsl:template>

  <xsl:template match="word">
    <tag>
      <xsl:value-of select="."/>
    </tag>
  </xsl:template>

</xsl:stylesheet>

当应用于与以前相同的XML文档时，会生成相同的正确输出。

<强> III。使用XSLT 2.0转换中的XPath 2.0标准函数tokenize()

这是最简单的方法 - 如果可以使用XSLT 2.0处理器。

以下XSLT 2.0转换：

<xsl:stylesheet version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    >
    <xsl:output omit-xml-declaration="yes" indent="yes"/>

    <xsl:template match="/*">
      <xsl:copy>
        <xsl:apply-templates select="node()|@*"/>
      </xsl:copy>
    </xsl:template>

    <xsl:template match="@*[not(name()='tags')]">
      <xsl:element name="{name()}">
        <xsl:value-of select="."/>
      </xsl:element>
    </xsl:template>

    <xsl:template match="@tags">
    <xsl:for-each select="tokenize(.,',')">
      <tag><xsl:value-of select="."/></tag>
    </xsl:for-each>
    </xsl:template>
</xsl:stylesheet>

再次应用于同一XML文档时会产生想要的结果。

Answer 2

我真的很喜欢Dimitre的答案，但他的XSLT 1.0解决方案有一个小错误。当我有 “价值，价值，价值”，它只会拆分前两个并跳过最后一个。

编辑这不是错误，我没注意到他用CONCAT调用模板

这是我对他的tokenize xslt 1模板的修改。

<xsl:template name="tokenize">
  <xsl:param name="pText"/>
  <xsl:param name="pTag"/>
  <xsl:if test="string-length($pText)">
    <xsl:element name="{$pTag}">
             <xsl:choose>
                  <xsl:when test="string-length(substring-before($pText, ','))">
                      <xsl:value-of select="substring-before($pText, ',')"/>
                  </xsl:when>
                  <xsl:otherwise><xsl:value-of select="$pText" /></xsl:otherwise>
              </xsl:choose>
    </xsl:element>

    <xsl:call-template name="tokenize">
      <xsl:with-param name="pText" select=
       "substring-after($pText, ',')"/>
      <xsl:with-param name="pTag"><xsl:value-of select="$pTag" /></xsl:with-param>
    </xsl:call-template>
  </xsl:if>

用法示例

<xsl:call-template name="tokenize">
        <xsl:with-param name="pText">123,234,345</xsl:with>
        <xsl:with-param name="pTag">tag</xsl:with-param >
</xsl:call-template>

输出

  <tag>123</tag>
  <tag>234</tag>
  <tag>345</tag>

Answer 3

你应该做的第一件事是找到使用属性的人，他应该使用元素并让他停下来。我们接受XML冗长的原因是它为我们提供了不必弄清楚如何解析数据的好处。如果您要使用必须解析的数据打包XML，为什么首先使用XML？

如何将具有由a分隔的值的属性分解为单独的元素

3 个答案: