Question

我正在尝试使用XSLT将具有多个输出的XML转换（拼合）为具有单个输出的XML。但是将忽略每个节点必须重复的节点。 XML文件具有两个输出：HEAD和EXPERIMENT。

原始XML文档：

<?xml version="1.0" encoding="utf-8"?>
<ELEMENT>
    <HEAD>
        <FIRSTNAME>Anton</FIRSTNAME>
        <SURNAME>Konchik</SURNAME>
        <REPORTDATE>01.01.2019</REPORTDATE>
    </HEAD>
    <EXPERIMENT>
        <NAME>EXPERIMENT1</NAME>
        <DATE>01.01.2018</DATE>
        <RESULT>POSITIVE</RESULT>
    </EXPERIMENT>
    <EXPERIMENT>
        <NAME>EXPERIMENT2</NAME>
        <DATE>01.01.2019</DATE>
        <RESULT>NEGATIVE</RESULT>
    </EXPERIMENT>
    <EXPERIMENT>
        <NAME>EXPERIMENT3</NAME>
        <DATE>01.01.2017</DATE>
        <RESULT>NOTSURE</RESULT>
    </EXPERIMENT>
</ELEMENT>

通过使用下面的代码，我想在每个EXPERIMENT节点内复制HEAD节点。 XSLT转换代码：

<?xml version='1.0' ?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="yes" version="2.0" encoding="UTF-8" />
    <xsl:template match="/">
        <xsl:element name="ELEMENT">
            <xsl:for-each select="ELEMENT/EXPERIMENT">
                <xsl:element name="EXPERIMENT">

                    <xsl:element name="NAME">
                          <xsl:value-of select="./NAME"/>
                    </xsl:element>

                    <xsl:element name="DATE">
                          <xsl:value-of select="./DATE"/>
                    </xsl:element>

                    <xsl:element name="RESULT">
                          <xsl:value-of select="./RESULT"/>
                    </xsl:element>

                        <xsl:for-each select="ELEMENT/HEAD">
                           <xsl:element name="FIRSTNAME">
                                  <xsl:value-of select="./FIRSTNAME"/>
                            </xsl:element>
                           <xsl:element name="SURNAME">
                                  <xsl:value-of select="./SURNAME"/>
                            </xsl:element>
                           <xsl:element name="REPORTDATE">
                                  <xsl:value-of select="./REPORTDATE"/>
                            </xsl:element>
                        </xsl:for-each>

                </xsl:element>          
            </xsl:for-each>
        </xsl:element>
    </xsl:template>
</xsl:stylesheet>

例外结果：

<?xml version="1.0" encoding="utf-8"?>
<ELEMENT>
    <EXPERIMENT>
        <NAME>EXPERIMENT1</NAME>
        <DATE>01.01.2018</DATE>
        <RESULT>POSITIVE</RESULT>
        <FIRSTNAME>Anton</FIRSTNAME>
        <SURNAME>Konchik</SURNAME>
        <REPORTDATE>01.01.2019</REPORTDATE>
    </EXPERIMENT>
    <EXPERIMENT>
        <NAME>EXPERIMENT2</NAME>
        <DATE>01.01.2019</DATE>
        <RESULT>NEGATIVE</RESULT>
        <FIRSTNAME>Anton</FIRSTNAME>
        <SURNAME>Konchik</SURNAME>
        <REPORTDATE>01.01.2019</REPORTDATE>
    </EXPERIMENT>
    <EXPERIMENT>
        <NAME>EXPERIMENT3</NAME>
        <DATE>01.01.2017</DATE>
        <RESULT>NOTSURE</RESULT>
        <FIRSTNAME>Anton</FIRSTNAME>
        <SURNAME>Konchik</SURNAME>
        <REPORTDATE>01.01.2019</REPORTDATE>
    </EXPERIMENT>
</ELEMENT>

但是HEAD节点被忽略。实际结果：

<?xml version="1.0" encoding="utf-8"?>
<ELEMENT>
  <EXPERIMENT>
    <NAME>EXPERIMENT1</NAME>
    <DATE>01.01.2018</DATE>
    <RESULT>POSITIVE</RESULT>
  </EXPERIMENT>
  <EXPERIMENT>
    <NAME>EXPERIMENT2</NAME>
    <DATE>01.01.2019</DATE>
    <RESULT>NEGATIVE</RESULT>
  </EXPERIMENT>
  <EXPERIMENT>
    <NAME>EXPERIMENT3</NAME>
    <DATE>01.01.2017</DATE>
    <RESULT>NOTSURE</RESULT>
  </EXPERIMENT>
</ELEMENT>

感谢您的帮助。

Answer 1

更改：

<xsl:for-each select="ELEMENT/HEAD">

收件人：

<xsl:for-each select="/ELEMENT/HEAD">

或：

<xsl:for-each select="../HEAD">

您正在寻找的是ELEMENT的子项EXPERIMENT。您需要的是从树的根部开始或在层次结构中向上滚动。

请注意，您可以简单地进行以下操作：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:template match="/ELEMENT">
    <xsl:copy>
        <xsl:for-each select="EXPERIMENT">
            <xsl:copy>
                <xsl:copy-of select="*"/>
                <xsl:copy-of select="../HEAD/*"/>
            </xsl:copy>
        </xsl:for-each>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

使用XSLT将具有多个输出的XML转换为具有单个输出的XML

1 个答案: