Question

我正在使用Android支持库com.android.support:appcompat-v7:28.0.0。但是，我也使用com.google.android.gms:play-services-nearby:16.0.0，这取决于支持库的早期版本。

为解决此问题，我使用了resolutionStrategy来将支持库强制为28.0.0版，但它无法正常工作。 Android Studio仍在抱怨依赖项冲突。为什么我的解决方案策略不起作用？

apply plugin: 'com.android.application'


apply plugin: 'kotlin-android'

apply plugin: 'kotlin-android-extensions'

android {
    compileSdkVersion 28
    defaultConfig {
        applicationId "rstudio.vedantroy.swarm"
        minSdkVersion 21
        targetSdkVersion 28
        versionCode 1
        versionName "1.0"
        testInstrumentationRunner "android.support.test.runner.AndroidJUnitRunner"
    }
    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
        }
    }
    configurations.all {
        resolutionStrategy.force 'com.android.support:appcompat-v7:28.0.0'
    }
}

dependencies {

    //Developer-added dependencies
    implementation 'com.google.android.gms:play-services-nearby:16.0.0'
    implementation 'com.airbnb.android:mvrx:0.7.0'


    implementation fileTree(dir: 'libs', include: ['*.jar'])
    implementation"org.jetbrains.kotlin:kotlin-stdlib-jdk7:$kotlin_version"
    implementation 'com.android.support:appcompat-v7:28.0.0'
    implementation 'com.android.support.constraint:constraint-layout:1.1.3'
    testImplementation 'junit:junit:4.12'
    androidTestImplementation 'com.android.support.test:runner:1.0.2'
    androidTestImplementation 'com.android.support.test.espresso:espresso-core:3.0.2'
}

Answer 1

您可以使用此配置来统一所有支持库版本：

configurations.all {
    resolutionStrategy.eachDependency { details ->
        if (details.requested.group == 'com.android.support'
                && !details.requested.name.contains('multidex') ) {
            details.useVersion "28.0.0"
        }
    }
}

此代码段将查找每个具有组名com.android.support的依赖项，并强制将版本28.0.0应用于内部依赖项。这样，您还可以在项目范围内指定其他依赖项以使用显式版本，例如毕加索或滑翔。您只需指定其组并在details.useVersion中指定其特定版本。

希望这会有所帮助：）

Answer 2

如果有需要，Gradle Kotlin DSL的脚本如下：

configurations.all {
    resolutionStrategy {
        eachDependency {
            when (requested.module.toString()) {
                "androidx.fragment:fragment" -> useVersion("1.3.0")
                // ...etc
            }
        }
    }
}

此外，您可能还想看看 official docs。

如何使用Gradle resolutionStrategy强制依赖版本？

2 个答案: