Java字节码中的Stack = 4。 Java编译器如何计算4值？ （堆栈深度）

Question

Java代码：

public class SimpleRecursion {

    public int factorial(int n) {
        if (n == 0) {
            return 1;
        }
        return n*factorial(n - 1);
    }

}

为阶乘方法提供以下字节码（我执行javap来生成它）：

public int factorial(int); 
descriptor: (I)I 
flags: ACC_PUBLIC 
Code:   
  stack=4, locals=2, args_size=2
     0: iload_1
     1: ifne          6
     4: iconst_1
     5: ireturn
     6: iload_1
     7: aload_0
     8: iload_1
     9: iconst_1
    10: isub
    11: invokevirtual #2                  // Method factorial:(I)I
    14: imul
    15: ireturn   
  LineNumberTable:
    line 4: 0
    line 5: 4
    line 7: 6   
  StackMapTable: number_of_entries = 1
    frame_type = 6 /* same */

我了解到，在上面代码块的第五行中， stack = 4表示堆栈最多可以有4个对象。

但是编译器如何计算呢？

Answer 1

由于堆栈的初始状态以及每条指令对堆栈的影响是众所周知的，因此您可以随时准确地预测哪种类型的项将在操作数堆栈上随时出现：

[ ]            // initially empty
[ I ]          0: iload_1
[ ]            1: ifne          6
[ I ]          4: iconst_1
[ ]            5: ireturn
[ I ]          6: iload_1
[ I O ]        7: aload_0
[ I O I ]      8: iload_1
[ I O I I ]    9: iconst_1
[ I O I ]     10: isub
[ I I ]       11: invokevirtual #2   // Method factorial:(I)I
[ I ]         14: imul
[ ]           15: ireturn   

JVM的验证程序将精确地执行此操作，在每条指令后预测堆栈的内容，以检查其是否适合作为后续指令的输入。但这在这里有帮助，具有声明的最大大小，因此验证程序不需要维护动态增长的数据结构或为理论上可能的64k堆栈条目预分配内存。有了声明的最大大小，它在遇到一条可能会推送更多内容的指令时可以停止，因此它永远不需要比声明的内存更多的内存。

如您所见，在索引9的iconst_1指令之后，声明的最大堆栈大小恰好达到一次。

但是，这并不意味着编译器将必须执行这种指令分析。编译器具有从源代码派生的更高级别的代码模型，称为Abstract syntax tree。

此结构将用于生成结果字节码，它也可能已经能够在该级别上预测所需的堆栈大小。但是编译器实际上是如何实现的，取决于实现。