Question

=“”

我正在尝试执行If条件在xsl：next-iteration中的xsl：with-param中。

我的xml如下：

<?xml version="1.0" encoding="UTF-8"?>
<XmlRoot>
   <Rec>
      <pD>20181221</pD>
      <gl>00001</gl>
      <le_Ac>29246</le_Ac>
      <eid>009158099</eid>
      <tA>9.61</tA>
   </Rec>
   <Rec>
      <pD>20181221</pD>
      <gl>00001</gl>
      <le_Ac>29246</le_Ac>
      <eid>009158099</eid>
      <tA>10.61</tA>
   </Rec>   
   <Rec>
      <pD>20181221</pD>
      <gl>00001</gl>
      <le_Ac>60300</le_Ac>
      <eid>909154343</eid>
      <tA>11.61</tA>
   </Rec>   
   <Rec>
      <pD>20181221</pD>
      <gl>00001</gl>
      <le_Ac>60300</le_Ac>
      <eid>909154343</eid>
      <tA>12.61</tA>
   </Rec>
</XmlRoot>

我的xslt如下所示，我正在尝试流式传输非常大的xml。

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:math="http://www.w3.org/2005/xpath-functions/math"
    xmlns:map="http://www.w3.org/2005/xpath-functions/map" exclude-result-prefixes="xs math map"
    version="3.0">

    <xsl:mode streamable="yes"/>

    <xsl:output method="text"/>

    <xsl:template match="/">
        <xsl:iterate select="XmlRoot/Rec">
            <xsl:param name="mapAllKeys" as="map(xs:string, xs:float?)" select="map{}"/>
            <xsl:param name="map29246" as="map(xs:string, xs:float?)" select="map{}"/>
            <xsl:param name="mapDummy" as="map(xs:string, xs:float?)" select="map{}"/>
            <xsl:on-completion>
                <!--<xsl:value-of select="map:keys($mapAllKeys)!(. || concat('&quot;',',','&quot;') || $mapAllKeys(.))" separator="&#10;"/>-->
                    <xsl:for-each 
                        select="map:for-each($mapAllKeys,function ($k, $v){$k})">
                            <xsl:value-of select="."/>
                        <xsl:value-of select="'&#10;'"/>
                        <xsl:value-of select="if(map:contains($map29246,.)) then map:get($map29246,.) else 0"/>
                        <xsl:value-of select="'&#10;'"/>
                    </xsl:for-each>
               </xsl:on-completion>
            <xsl:variable name="current-entry" select="copy-of()"/>
            <xsl:variable name="pDt">
                <xsl:choose>
                    <xsl:when test="$current-entry/pD = ''"><xsl:value-of select="$current-entry/aD"/></xsl:when>
                    <xsl:otherwise><xsl:value-of select="$current-entry/pD"/></xsl:otherwise>
                </xsl:choose>
            </xsl:variable>
            <xsl:variable name="key" select="$current-entry/concat(pD, eid, gl,na)"/>
            <xsl:next-iteration>
                <xsl:with-param name="mapAllKeys"
                    select="
                    if (map:contains($mapAllKeys, xs:string($key))) then
                        map:put($mapAllKeys, xs:string($key), map:get($mapAllKeys, xs:float(1.0)))
                    else
                        map:put($mapAllKeys, xs:string($key), xs:float(1.0))"
                />

                <xsl:with-param name="map29246"
                    select="
                    if($current-entry/le_Ac = '29246') then
                       if (map:contains($map29246, xs:string($key))) then
                          map:put($map29246, xs:string($key), map:get($map29246, xs:string($key)) + xs:float($current-entry/tA))
                       else
                          map:put($map29246, xs:string($key), xs:float($current-entry/tA))
                    else
                    map:put($mapDummy, 'DUMMY', xs:float('0.0'))
                    "/>

            </xsl:next-iteration>
        </xsl:iterate>
    </xsl:template>

</xsl:stylesheet>

主要问题是代码 if（$ current-entry / le_Ac ='29246'）然后永远不会满足。

我只想在le_Ac = 29246时添加到地图

此外，它总是要求其他部分，无论如何要避免其他部分？我正在尝试使用虚拟地图绕过它。

感谢您的帮助！谢谢！

Answer 1

关于不向地图添加任何内容的问题，我认为在最后一个else而不是map:put($mapDummy, 'DUMMY', xs:float('0.0'))中，我期望else $map29246。

您也将问题标记为xslt-grouping，则可能可以通过以下方式解决整个问题

<xsl:template match="/">
    <xsl:for-each-group select="XmlRoot/Rec!map:merge(*!map { local-name() : string() })" composite="yes" group-by="?pD, ?eid, ?gl, ?na">
        <xsl:value-of select="string-join(current-grouping-key()), sum(current-group()[?le_Ac = '29246']?tA!xs:decimal(.))" separator="&#10;"/>
        <xsl:text>&#10;</xsl:text>
    </xsl:for-each-group>
</xsl:template>

在oXygen中使用Saxon 9.8.0.12 EE的样品的输出为

2018122100915809900001
20.22
2018122190915434300001
0

另一种方法是

<xsl:template match="/">
    <xsl:for-each-group select="XmlRoot/Rec!copy-of()" composite="yes" group-by="pD, eid, gl,na">
        <xsl:value-of select="string-join(current-grouping-key()), sum(current-group()[le_Ac = 29246]/tA)" separator="&#10;"/>
        <xsl:text>&#10;</xsl:text>
    </xsl:for-each-group>
</xsl:template>

我没有使用大输入进行任何测量，以查看哪个执行得更好或至少使用更少的内存。

<xsl：next-iteration> <xsl：with-param

1 个答案: