Question

我开始学习XSLT，在编写将xslt中的小写字母转换为大写字母并将大写字母转换为小写字母的xslt函数时有点卡住了

我通过编写不同的xslt函数进行了很多尝试，但是我认为我在代码中做错了一些地方

fopen

输入将是以下任意一个值

1。自雇/雇员 2.技能贸易 3.政府

预期输出如下

自雇/就业
技能贸易
政府

但是实际结果是

自雇人士
技能/贸易
政府

Answer 1

正如我在评论中提到的那样，您的代码不可复制。根据您报告的结果，很明显第二个定界符未应用。 AFAICT，这是因为您首先检查第一个定界符的存在-如果找到它，就不必费心测试第二个定界符是否在第一个定界符之前。

考虑以下示例（改编自Converting first letter of a string to capital in xslt）：

XML

<input>
    <item>Self/Employed</item>
    <item>Skill Trade</item>
    <item>Government</item>
    <item>a combi/na/tion of various de/limi/ters</item>
</input>

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:template match="/input">
    <output>
        <xsl:for-each select="item">
            <caps>
                <xsl:call-template name="capitalize">
                    <xsl:with-param name="text" select="."/>
                </xsl:call-template>
            </caps>
        </xsl:for-each>
    </output>
</xsl:template>

<xsl:template name="capitalize">
    <xsl:param name="text"/>
    <xsl:param name="delimiter" select="' '"/>

    <xsl:variable name="upper-case" select="'ABCDEFGHIJKLMNOPQRSTUVWXYZ'"/>
    <xsl:variable name="lower-case" select="'abcdefghijklmnopqrstuvwxyz'"/>

    <xsl:variable name="word" select="substring-before(concat($text, $delimiter), $delimiter)" />
    <xsl:choose>
        <xsl:when test="$delimiter=' '">
            <!-- tokenize word by 2nd delimiter -->
            <xsl:call-template name="capitalize">
                <xsl:with-param name="text" select="$word"/>
                <xsl:with-param name="delimiter" select="'/'"/>
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <!-- capitalize word -->
            <xsl:value-of select="translate(substring($word, 1, 1), $lower-case, $upper-case)"/>    
            <xsl:value-of select="translate(substring($word, 2), $upper-case, $lower-case)"/>
        </xsl:otherwise>
    </xsl:choose>
    <xsl:if test="contains($text, $delimiter)">
        <xsl:value-of select="$delimiter"/>
        <!-- recursive call -->
        <xsl:call-template name="capitalize">
            <xsl:with-param name="text" select="substring-after($text, $delimiter)"/>
            <xsl:with-param name="delimiter" select="$delimiter"/>
        </xsl:call-template>
    </xsl:if>
</xsl:template>

</xsl:stylesheet>

结果

<?xml version="1.0" encoding="UTF-8"?>
<output>
  <caps>Self/Employed</caps>
  <caps>Skill Trade</caps>
  <caps>Government</caps>
  <caps>A Combi/Na/Tion Of Various De/Limi/Ters</caps>
</output>

Answer 2

将来可以有两个以上的定界符吗？如果是这样，请尝试使用此XSLT，它可以很容易地扩展为具有更多（单个字符）定界符。只需更改delimiters模板中的ConvertXmlStyleToCamelCase参数即可。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes"/>

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="item">
        <item>
            <xsl:call-template name="ConvertXmlStyleToCamelCase" />
        </item>
    </xsl:template>

    <xsl:template name="ConvertXmlStyleToCamelCase">
        <xsl:param name="text" select="."/>
        <xsl:param name="delimiters" select="' /'"/>

        <xsl:variable name="upper" select="'ABCDEFGHIJKLMNOPQRSTUVWXYZ'"/>
        <xsl:variable name="lower" select="'abcdefghijklmnopqrstuvwxyz'"/>
        <xsl:variable name="nextDelimiter" select="substring(translate($text, translate($text, $delimiters, ''), ''), 1, 1)" />
        <xsl:variable name="string" select="substring-before(concat($text, ' '), substring(concat($nextDelimiter, ' '), 1, 1))" />

        <xsl:message terminate="no">Next delimiter is <xsl:value-of select="$nextDelimiter" /></xsl:message>

        <xsl:value-of select="translate(substring($string, 1, 1), $lower, $upper)"/>
        <xsl:value-of select="translate(substring($string, 2), $upper, $lower)"/>

        <xsl:if test="$nextDelimiter">
            <xsl:value-of select="$nextDelimiter" />
            <xsl:call-template name="ConvertXmlStyleToCamelCase">
                <xsl:with-param name="text" select="substring-after($text, $nextDelimiter)"/>
                <xsl:with-param name="delimiters" select="$delimiters"/>  
            </xsl:call-template>
        </xsl:if>
    </xsl:template>
</xsl:stylesheet>

在http://xsltfiddle.liberty-development.net/gWvjQeR上可以看到它的作用，我以第三个定界符为例。

关于double-translate，它的目的是在字符串中找到下一个定界符。为此（在XSLT 1.0中），您需要删除所有不是定界符的字符。进行translate($text, $delimiters, '')会删除所有定界符，因此将返回所有不是定界符的字符。如果然后将此结果应用于原始字符串，则只剩下分隔符。然后，第一个字符将是下一个定界符。

使用两个定界符将第一个字符串字母转换为大写字母，其余的字母转换为小写字母

2 个答案: