Question

我遇到一个分组问题，我需要将一个节点下具有相同编号的所有键分组。例如，我的XML如下：

<results>
   <status>completed</status>
   <info>success</info>
   <prod1>abc</prod1>
   <pub1>test</pub1>
   <sub1>123</sub1>
   <subtype1>pt</subtype1>
   <prod2>def</prod2>
   <pub2>test22</pub2>
   <sub2>456</sub2>
   <subtype2>pt</subtype2>
   <prod3>ghi</prod3>
   <pub3>test33</pub3>
   <sub3>789</sub3>
   <subtype3>pt</subtype3>
</results>

我需要将以上内容转换为：

<results>
   <status>completed</status>
   <info>success</info>
   <products>
      <product>
         <prod>abc</prod>
         <pub>test</pub>
         <sub>123</sub>
         <subtype>pt</subtype>
       </product>
       <product>
         <prod>def</prod>
         <pub>test22</pub>
         <sub>456</sub>
         <subtype>pt</subtype>
       </product>
       <product>
         <prod>ghi</prod>
         <pub>test33</pub>
         <sub>789</sub>
         <subtype>pt</subtype>
       </product>
    </products>
</results>

在解决上述问题方面的任何帮助均受到高度赞赏。我目前一直困扰于此问题，无法继续。

下面的xslt将每个元素拉入一个节点，并且我无法将所有以特定数字结尾的元素组合到一个节点中。

<?xml version="1.0" encoding="UTF-8"?>
   <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
   <xsl:key name="elementByRow" match="/*/*"
           use="(name(.)[1])" />

   <xsl:template match="/messages">
    <messages>
      <!-- pick out the first RowN.* element for each N -->
      <xsl:apply-templates select="*[generate-id() =
         generate-id(key('elementByRow', name(.))[1])]" />
    </messages>
   </xsl:template>

   <xsl:template match="*">
    <row>
      <!-- process _all_ the elements that belong to this row -->
      <xsl:for-each select="key('elementByRow', name(.))[1]">
        <xsl:element name="{name(.)[1]}">
          <xsl:value-of select="." />
        </xsl:element>
      </xsl:for-each>
     </row>
    </xsl:template>
   </xsl:stylesheet>

Answer 1

如果输入结构是恒定的，我将利用它，而不是尝试按尾随数字进行分组。

例如，您可以这样做：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:template match="/results">
    <xsl:copy>
        <xsl:copy-of select="status | info"/>
        <products>
            <xsl:for-each select="*[starts-with(name(), 'prod')]">
                <product>
                    <prod>
                        <xsl:value-of select="." />
                    </prod>
                    <pub>
                        <xsl:value-of select="following-sibling::*[1]" />
                    </pub>
                    <sub>
                        <xsl:value-of select="following-sibling::*[2]" />
                    </sub>
                    <subtype>
                        <xsl:value-of select="following-sibling::*[3]" />
                    </subtype>
                </product>
            </xsl:for-each>
        </products>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

Answer 2

这是一种更精细的方法，将元素按其编号分组；请注意，但是，这假设元素的名称除末尾的组号外将不包含任何数字。

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:key name="field-by-group" match="*" use="translate(name(), translate(name(), '0123456789', ''), '')" />

<xsl:template match="/results">
    <xsl:copy>
        <xsl:copy-of select="status | info"/>
        <products>
            <xsl:for-each select="*[starts-with(name(), 'prod')]">
                <product>
                    <xsl:for-each select="key('field-by-group', substring-after(name(), 'prod'))">
                        <xsl:element name="{translate(name(), '0123456789', '')}">
                            <xsl:value-of select="."/>
                        </xsl:element>
                    </xsl:for-each>
                </product>
            </xsl:for-each>
        </products>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

使用XSLT1.0将平面XML数据转换为嵌套XML

2 个答案: