Question

我有一个批处理文件，用于替换csv中的文本-代码是从此处复制的（Replace specific text in csv via commandline，我需要对其进行更改，以便它替换输入文件中的向右箭头符号。该代码不起作用如下所示，因此我必须以某种方式错误地表示该符号/字符。

）

Answer 1

如果您的目标是使用特殊字符编辑/替换文件，这可能会对您有所帮助。

除了原始脚本存在的问题外，我不仅创建了一个可行的解决方案，而且还重新设计了具有更好执行性能的功能。您正在使用的当前脚本不会保留空行。

@echo off
@setLocal enableDelayedExpansion

set "InputFile=file.csv"
set "OriginalText=Hello There"
set "ReplacedText=Hello > There"

REM | Make sure we only edit the proper line.
FOR /F "delims=" %%n IN ('findstr /n "^" %InputFile%') DO (
    SET "line=%%n"
    SET "Modified=!line:%OriginalText%=%ReplacedText%!"
    SET "Modified=!Modified:*:=!"

    REM | Output the entire edited CSV to a temporary file.
    >> %InputFile%.TEMP ECHO(!Modified!
)

Rem | Delete Original File, Restore New
DEL %InputFile%
REN %InputFile%.TEMP %InputFile%

goto :EOF

下面我将尝试解释每个SET命令的作用。

SET "line=%%n"-将当前%%A设置为字符串。（这是一行）
SET "Modified=!line:%OriginalText%=%ReplacedText%!"-将包含%OriginalText%的字符串替换为受尊重的%ReplaceText%结果。
SET "Modified=!Modified:*:=!"-删除1:创建的2:，3:，findstr /n

>> %InputFile%.TEMP ECHO(!Modified!将把这些垂直行输出到新的文本文件中。

我个人建议，如果您将set "String="与引号一起使用，则每隔set命令也会使用它们。有一些例外，但是在这种情况下，请使用它们！

编辑：

由于OP似乎要求特殊字符支持from和to文本，因此这是更新的方法。

首先，可以使用15个字符的powershell命令来完成此操作。如果您不需要纯批处理方法，并且愿意将其混合使用，则建议这样做。但是，对于纯批处理解决方案，请继续阅读。

批处理程序很难将特殊字符处理为功能而不会中断。但是，仍然可以做到，我将带您走上正确的道路。

下面有两个脚本，ReplaceScript.bat和MainCode.Bat。

MainCode.Bat是您的主要批处理脚本。可以是任何名称。
ReplaceScript.bat是一个脚本，如果需要，我们将call从MainCode.Bat. This replace script file can be pasted at the bottom of MainCode.Bat`跳转到该脚本，但由于大小原因，我想省略它。

要使用ReplaceScript.bat-如下：

Rem | Usage: call "1" "2" "3" "4" "5"
Rem | call - Calls external script
Rem | "1" - Name of External script
Rem | "2" - File to Edit
Rem | "3" - Text to replace ex: red apple
Rem | "4" - Text to replace to ex: green apple
Rem | "5" - Output file

call "%ReplaceScript%" "%InputTEXT%" "%SEARCHTEXT%" "%REPLACETEXT%" "%OutputTEXT%"

MainCode.bat：

@ECHO OFF

set "InputFile=file.csv"
set "OriginalText=Hello There"
set "ReplacedText=Hello > There"

Rem | Call Replace Script
call "ReplaceScript.bat" "%CustomINI%" "%OriginalText%" "%ReplacedText%"  "%InputFile%.TEMP"

Rem | Delete Original File, Restore New
DEL %InputFile%
REN %InputFile%.TEMP %InputFile%

goto :EOF

ReplaceScript.bat：（不是由我制作；尊敬的所有者未知-如果您的所有者与我联系）

@echo off
setlocal EnableExtensions DisableDelayedExpansion

set "FILE_I=%~1"
set "SEARCH=%~2"
set "REPLAC=%~3"
set "FILE_O=%~4"
set "FLAG=%~5"
if not defined FILE_I exit /B 1
if not defined SEARCH exit /B 1
if not defined FILE_O set "FILE_O=con"
if defined FLAG set "FLAG=#"

for /F "delims=" %%L in ('
    findstr /N /R "^" "%FILE_I%" ^& break ^> "%FILE_O%"
') do (
    set "STRING=%%L"
    setlocal EnableDelayedExpansion
    set "STRING=!STRING:*:=!"
    call :REPL RETURN STRING SEARCH REPLAC %FLAG%
    >> "%FILE_O%" echo(!RETURN!
    endlocal
)

endlocal
exit /B


:REPL  rtn_string  ref_string  ref_search  ref_replac  flag
setlocal EnableDelayedExpansion
set "STR=!%~2!"
set "SCH=!%~3!"
set "RPL=!%~4!"
if not defined SCH endlocal & set "%~1=" & exit /B 1
set "SCH_CHR=!SCH:~,1!"
if not "%~5"=="" set "SCH_CHR="
if "!SCH_CHR!"=="=" set "SCH_CHR=" & rem = terminates search string
if "!SCH_CHR!"==""^" set "SCH_CHR=" & rem " could derange syntax
if "!SCH_CHR!"=="%%" set "SCH_CHR=" & rem % ends variable expansion
if "!SCH_CHR!"=="^!" set "SCH_CHR=" & rem ! ends variable expansion
call :LEN SCH_LEN SCH
call :LEN RPL_LEN RPL
set /A RED_LEN=SCH_LEN-1
set "RES="
:LOOP
call :LEN STR_LEN STR
if not defined STR goto :END
if defined SCH_CHR (
    set "WRK=!STR:*%SCH_CHR%=!"
    if "!WRK!"=="!STR!" (
        set "RES=!RES!!STR!"
        set "STR="
    ) else (
        call :LEN WRK_LEN WRK
        set /A DFF_LEN=STR_LEN-WRK_LEN-1,INC_LEN=DFF_LEN+1,MOR_LEN=DFF_LEN+SCH_LEN
        for /F "tokens=1,2,3 delims=," %%M in ("!DFF_LEN!,!INC_LEN!,!MOR_LEN!") do (
            rem set "RES=!RES!!STR:~,%%M!"
            if defined WRK set "WRK=!WRK:~,%RED_LEN%!"
            if "!STR:~%%M,1!!WRK!"=="!SCH!" (
                set "RES=!RES!!STR:~,%%M!!RPL!"
                set "STR=!STR:~%%O!"
            ) else (
                set "RES=!RES!!STR:~,%%N!"
                set "STR=!STR:~%%N!"
            )
        )
    )
) else (
    if "!STR:~,%SCH_LEN%!"=="!SCH!" (
        set "RES=!RES!!RPL!"
        set "STR=!STR:~%SCH_LEN%!"
    ) else (
        set "RES=!RES!!STR:~,1!"
        set "STR=!STR:~1!"
    )
)
goto :LOOP
:END
if defined RES (
    for /F delims^=^ eol^= %%S in ("!RES!") do (
        endlocal
        set "%~1=%%S"
    )
) else endlocal & set "%~1="
exit /B


:LEN  rtn_length  ref_string
setlocal EnableDelayedExpansion
set "STR=!%~2!"
if not defined STR (set /A LEN=0) else (set /A LEN=1)
for %%L in (4096 2048 1024 512 256 128 64 32 16 8 4 2 1) do (
    if defined STR (
        set "INT=!STR:~%%L!"
        if not "!INT!"=="" set /A LEN+=%%L & set "STR=!INT!"
    )
)
endlocal & set "%~1=%LEN%"
exit /B

我个人建议，如果您将set "String="与引号一起使用，则每隔set命令也会使用它们。有一些例外，但是在这种情况下，请使用它们！

要获得任何命令的进一步帮助或理解，请执行以下操作：

call /?
set /?
for /?
if /?
goto /?
等等。

如何表示批处理文件中CSV文件中存在的向右箭头符号

1 个答案: