Question

我需要声明一条可以处理两种请求的路由：

GET /api/vote/:value 
GET /api/vote/:value/:date

在两种情况下，我对待数据的方式并没有什么不同，因此我希望将它们定义在同一位置。

我现在所做的是我使用了wilcard placeholder：

use Mojolicious::Lite -signatures;
use DateTime;

get '/vote/*values' => sub ($c) {
    my $datetime = DateTime->now;
    # Then we process the route parameters
    my @params = split('/', $c->param('values'), 2);
     # Optional if no date provided in the route
    if ( defined $params[1] ) {
        my @dates_params = split('-', $params[1], 3);
        my %datetime = (
            year  => $dates_params[0],
            month => $dates_params[1],
            day   => $dates_params[2],
        );
        $datetime =  DateTime->new(%datetime);
    }
    my %vote = (
        value => $params[0],
        datetime => $datetime,
    );
    # ... More code here
    $c->render(json => $data);
}

这种方法可以很好地工作，但是我对这种解决方案不太满意，因为它不是很明确也不易读，而且我知道其他框架也允许以看起来更令人满意的方式做类似的事情。 / p>

例如，以下使用Express.js routing capabilities，仅允许在一条路由声明中到达/vote/123和/vote/123/2019-01-13。

router.get('/vote/:value/:date*?', function(req, res, next) {
    // Processing here...
    res.json(// etc.);
});

注意：此示例来自this SO question。

在尝试使用Mojolicious::Lite的各种可能性之后，我发现Mojolicious路由中的正则表达式不是问题，而我发现的最佳解决方案是通配符占位符。我想念什么吗？

Answer 1

% mojo generate lite_app optional
...
% $EDITOR optional

可以通过将日期的默认值设置为undef将日期标记为可选：

#!/usr/bin/env perl
use Mojolicious::Lite -signatures;

get '/vote/:value/*when' => { when => undef } => sub ($c) {
    my $value = $c->stash('value');
    my $when  = $c->stash('when');
    $c->render(
        format => 'txt',
        text   => $value . ' ' . ( defined $when ? $when : 'nope' ) . "\n"
    );
};

app->start;

然后允许有或没有日期查询：

% ./optional get /vote/42 2>/dev/null
42 nope
% ./optional get /vote/42/2020/01/07 2>/dev/null
42 2020/01/07
%

如何在Mojolicious :: Lite中使用可选的占位符声明路由路径？

1 个答案: