Question

在Chapel中，最惯用的方法是以固定的增量循环一系列实数？

C等效代码为：

for (x = 0.0; x<1.0; x+=0.1) {}

在Python / Numpy中，可能会写

x = numpy.arange(0.0, 1.0, 0.1)

我可以想象如下编写迭代器，但是在语言/标准模块中是否内置了等效项？（当然，还有与此平行的版本编写问题）

iter arange(start, stop, step) {
  var x = start;
  while (x < stop) {
     yield x;
     x += step;
  }
}

Answer 1

只需在iterator选项上进行扩展：定义一个iterator即可获得不错的数组语义，而无需进行额外的工作（谢谢，Chapel！）。使用上面的代码并使用一些测试用例对其进行扩展：

// Define the general case
iter arange(type t, start, stop, step=1:t) {
  assert(stop > start, "Stop must be greater than start");
  assert(step > 0, "Step must be greater than 0");
  var x : t = start;
  while (x < stop) {
    yield x;
    x += step;
  }
}

// Overload for type from arguments
iter arange(start:?t, stop:t, step:t=1:t) {
  for x in arange(t, start, stop, step) do yield x;
}

// Overload for no start and default step = 1
iter arange(type t, stop) {
  for x in arange(t, 0, stop, 1) do yield x;
}

// Overload for no start and default step = 1
iter arange(stop:?t) {
  for x in arange(t, 0, stop, 1) do yield x;
}


// Example of simple iteration
for xi in arange(0.0,1.0,0.1) do writef(" %r",xi);
writef("\n");
for xi in arange(real,0,1,0.1) do writef(" %r",xi);
writef("\n");


// But Chapel allows other wonderful things once you
// define an iterator

// Array assignment
var x = arange(real, 0, 1, 0.1);
writeln(x);

// Promote a scalar function
var y = sin(2*pi*arange(real, 0, 1, 0.1));
for yi in y do writef(" %.3r",yi);
writef("\n");

// Step is optional
writeln(arange(real, 0, 10));
writeln(arange(0.0, 10.0));

运行此操作会产生

 0 0.1 0.2 0.3 0.4 0.5 0.6 0.7 0.8 0.9 1
 0 0.1 0.2 0.3 0.4 0.5 0.6 0.7 0.8 0.9 1
0.0 0.1 0.2 0.3 0.4 0.5 0.6 0.7 0.8 0.9 1.0
 0 0.588 0.951 0.951 0.588 1.22e-16 -0.588 -0.951 -0.951 -0.588 -1.13e-15
0.0 1.0 2.0 3.0 4.0 5.0 6.0 7.0 8.0 9.0
0.0 1.0 2.0 3.0 4.0 5.0 6.0 7.0 8.0 9.0

Answer 2

Chapel当前不具有对浮点值的常规序列进行迭代的内置支持。有时，我们已经讨论了扩展Chapel的范围类型以支持浮点索引类型，但是到目前为止还没有实现这一想法。我相信，目前，对于这种模式也没有任何标准的库支持。这些都是在Chapel's GitHub issues page上做出的合理功能请求。

如果我今天正在编写此模式，则可以编写您执行的迭代器，也可以直接将while循环直接放入我的代码中。对于浮点值范围内的并行迭代，如Chapel parallel iterators primer中所述，创建一系列迭代器重载是可行的方法。

教堂相当于numpy`arange` /相当于C的循环

2 个答案: