如何使用NSIS在Windows Installer的Finish页面中默认选中复选框

Question

我想使用NSIS在Windows安装程序的“完成”页面中将复选框默认设置为选中。为此，我使用了以下代码。但是它甚至没有在“完成”页面中显示复选框。请帮助我。

Var Checkbox
Var CheckState ; Stored globally so we remember the choice if the user presses the back button and goes back to our page
!define CheckHeight 28
!macro CreateNativeControl hParent cls style exstyle x y w h text ; Note: Only supports pixel coordinates
System::Call 'USER32::CreateWindowEx(i ${exstyle}, t "${cls}", ts, i ${style}, i ${x}, i ${y}, i ${w}, i ${h}, p ${hParent}, i0, i0, i0)p.s' "${text}"
!macroend

 !define MUI_PAGE_CUSTOMFUNCTION_SHOW FinishShow
 !insertmacro MUI_PAGE_FINISH

Function FinishShow

  System::Call *(i,i,i,i)p.r0 ; NSIS 2.51+
  System::Call 'USER32::GetWindowRect(p$mui.FinishPage.Text, pr0)'
  System::Call 'USER32::MapWindowPoints(i0,p$mui.FinishPage,p$0,i2)'
  System::Call '*$0(i.r2,i.r3,i.r4,i.r5)'
  System::Free $0
  IntOp $5 $5 - ${CheckHeight}
  System::Call 'USER32::SetWindowPos(i$mui.FinishPage.Text,i,i,i,i$4,i$5,i0x6)'

  ; Create and initialize the checkbox
  IntOp $5 $3 + $5 ; y = TextTop + TextHeight
  !insertmacro CreateNativeControl $mui.FinishPage ${__NSD_CheckBox_CLASS} "${__NSD_CheckBox_STYLE}" "${__NSD_CheckBox_EXSTYLE}" 0 $5 300 ${CheckHeight} "CheckboxTest"
  Pop $Checkbox
  SendMessage $mui.FinishPage ${WM_GETFONT} 0 0 $0 
  SendMessage $Checkbox ${WM_SETFONT} $0 1 
  System::Call 'USER32::SetWindowPos(i$Checkbox,i0,i,i,i,i,i0x33)' 
  ${IfThen} $CheckState == "" ${|} StrCpy $CheckState 1 ${|} 
  ${NSD_SetState} $Checkbox $CheckState
FunctionEnd

下面是“完成”屏幕，在该屏幕的中间，我需要显示复选框（默认情况下为选中状态）

Answer 1

完成页面对两个可选复选框具有内置支持：

!include MUI2.nsh
!insertmacro MUI_PAGE_WELCOME
!insertmacro MUI_PAGE_INSTFILES
!define MUI_FINISHPAGE_RUN ""
!define MUI_FINISHPAGE_RUN_TEXT "Run Foo"
!define MUI_FINISHPAGE_RUN_FUNCTION MyRunFoo
;define MUI_FINISHPAGE_RUN_NOTCHECKED
!define MUI_FINISHPAGE_SHOWREADME "$InstDir\Bar.exe"
!define MUI_FINISHPAGE_SHOWREADME_TEXT "Run Bar"
;define MUI_FINISHPAGE_SHOWREADME_FUNCTION
!define MUI_FINISHPAGE_SHOWREADME_NOTCHECKED
!insertmacro MUI_PAGE_FINISH
!insertmacro MUI_LANGUAGE English

Function MyRunFoo
; Exec '"$InstDir\Foo.exe"'
FunctionEnd

Section
SectionEnd

您的示例代码也缺少对!insertmacro MUI_LANGUAGE的重要调用。

仅当选中此复选框时，才执行由MUI_FINISHPAGE_RUN_FUNCTION指定的功能。这是正常的预期行为。

如果要进行自定义处理，可以在请假页面上进行：

!include nsDialogs.nsh
!include LogicLib.nsh
!include MUI2.nsh
!insertmacro MUI_PAGE_WELCOME
!insertmacro MUI_PAGE_INSTFILES
!define MUI_FINISHPAGE_RUN "" 
!define MUI_FINISHPAGE_RUN_TEXT "Blah blah" 
!define MUI_PAGE_CUSTOMFUNCTION_LEAVE FinishLeave 
!insertmacro MUI_PAGE_FINISH
!insertmacro MUI_LANGUAGE English

Function FinishLeave 
${NSD_GetState} $mui.FinishPage.Run $0 ; or $mui.FinishPage.ShowReadme
${If} $0 <> 0 
MessageBox mb_ok "Checkbox checked"
${Else} 
MessageBox mb_ok "Checkbox not checked" 
${EndIf}
FunctionEnd