Question

我正在寻找将一个Evernote笔记本导出到不同部分的可能性，例如：

Notebook = Eingang （2000Notes）

导出到

Eingang1.enex （500Notes）
Eingang2.enex （500个注释）
Eingang3.enex （500个注释）
Eingang3.enex （500个注释）

因为处理（即导入到Onenote）经常失败，导致ENEX文件中的注释太多或太大。也许有一些脚本或其他任何可行的方法。仅手工导出是不正确的方法，因为我的笔记本中装有14k +笔记。我希望我的意图已经明确。预先感谢您的帮助。

Answer 1

如果您使用的是Mac，则Evernote的AppleScript词典会公开一个export动词，您可以根据该动词来构建工具。这是一个略微但功能强大的AppleScript，可以完成您要查找的内容，只需编辑批处理大小，笔记本名称以及您要放置ENEX文件的路径即可：

tell application "Evernote"
    # Set batch size, notebook to export, and destination path
    set batchSize to 500
    set theNotebookName to "MyNotebook"
    set theExportFolder to "/tmp"

    # Enumerate the notes into batches and export them
    set theNotebook to the first notebook whose name is theNotebookName
    set theNotes to the notes in theNotebook
    set currentBatchIndex to 0
    set currentNoteIndex to 1
    repeat until currentNoteIndex = (count of theNotes)
        # Collect up to batchSize notes
        set thisExportBatch to {}
        repeat until ((count of thisExportBatch) = batchSize or (currentNoteIndex = (count of theNotes)))
            set currentItem to theNotes's item currentNoteIndex
            set thisExportBatch to thisExportBatch & {currentItem}
            set currentNoteIndex to currentNoteIndex + 1
        end repeat
        # Export this batch. Set the destination path to where you want them.
        set exportPath to (theExportFolder & "/" & theNotebookName & currentBatchIndex & ".enex")
        export thisExportBatch to exportPath
        set currentBatchIndex to (currentBatchIndex + 1)
    end repeat
end tell

我不确定Windows上的等效方法，但是我希望有一些等效的方法可以使它自动化。

有什么办法可以导出整个笔记本的不同部分

1 个答案: