PIVOT / UNPIVOT多于一列

Question

是否有一种方法可以使用SQL Pivot / Unpivot从表Converted在下面的Original下生成输出？

Answer 1

否，没有PIVOT / UNPIVOT的变体，它使您可以在“转换后的”输出中创建第一行，其中id位于一列中，而每个列的值为type其他列。

这将需要一些自定义选择来创建第一行，然后需要UNION和UNPIVOT来创建其余行。

由于没有执行聚合，所以我不知道为什么要在SQL中执行此操作。我个人将在表示层中执行此操作。

Answer 2

您可以使用动态sql实现“转换”布局，但是请注意这种方法的性能和安全性问题。

此外，正如Tab Alleman在回答中所说的，这显然是表示层的工作。

如果您仍然想在SQL Server中执行此操作，则可以采用以下解决方案：

CREATE TABLE [dbo].[Test] (
     [id]     int
    ,[type]   varchar(50)
    ,NBR      varchar(50)
    ,c1_pos   int
    ,c1_neg   int
    ,c2_pos   int
    ,c2_neg   int   )

INSERT INTO [dbo].[Test]
values 
 (8375, 'Type #1', 'P #1', 1, 0, 0, 0)
,(8375, 'Type #2', 'P #2', 0, 1, 0, 0)
,(8375, 'Type #3', 'P #1', 0, 1, 0, 0)
,(8375, 'Type #4', 'P #1', 1, 0, 0, 0)
,(8375, 'Type #5', 'P #1', 0, 0, 0, 0)

--this variable holds the value that will become the header of the first column 
declare @first_column_header nvarchar(10)
--this variable holds all the dates that will become column names 
declare @headers nvarchar(max)=''
--this variable contains the TSQL dinamically generated 
declare @sql nvarchar(max)=''  

SELECT @first_column_header = max(id) FROM [dbo].[Test]  group by [id]
select @headers = @headers + ', ' + QUOTENAME([type]) from [dbo].[Test] 
set @headers = RIGHT(@headers, len(@headers) - 2) 

set @sql = @sql + 'select piv.col as ' + QUOTENAME(@first_column_header) + ', ' + @headers + ' ' 
set @sql = @sql + 'from ' 
set @sql = @sql + '( ' 
set @sql = @sql + ' select [type], col, val, ord ' 
set @sql = @sql + ' from [dbo].[Test] ' 
set @sql = @sql + ' CROSS APPLY (' 
set @sql = @sql + '  VALUES (''NBR''    , cast(NBR    as varchar(10)) , 1), ' 
set @sql = @sql + '         (''c1_pos'' , cast(c1_pos as varchar(10)) , 2), ' 
set @sql = @sql + '         (''c1_neg'' , cast(c1_neg as varchar(10)) , 3), ' 
set @sql = @sql + '         (''c2_pos'' , cast(c2_pos as varchar(10)) , 4), ' 
set @sql = @sql + '         (''c2_neg'' , cast(c2_neg as varchar(10)) , 5) ' 
set @sql = @sql + ' )CS (col, val, ord) ' 
set @sql = @sql + ') src ' 
set @sql = @sql + 'pivot ( max(val) for [type] in (' + @headers + ') ) piv ' 
set @sql = @sql + 'order by ord' 

exec(@sql)

结果：