Question

使用以下代码，我可以在openGL控件中显示图像。呈矩形。现在我要将这个矩形的顶部和底部投影到圆柱形状，这意味着需要在openGL上执行从矩形到圆柱的投影。我该如何实现？

private void CreateShaders()
{
    /***********Vert Shader********************/
    vertShader = GL.CreateShader(ShaderType.VertexShader);
    GL.ShaderSource(vertShader, @"attribute vec3 a_position;
                                varying vec2 vTexCoord;
                                void main() {
                                vTexCoord = (a_position.xy + 1) / 2;
                                gl_Position = vec4(a_position, 1);
                                }");
    GL.CompileShader(vertShader);

    /***********Frag Shader ****************/
    fragShader = GL.CreateShader(ShaderType.FragmentShader);
    GL.ShaderSource(fragShader, @"precision highp float;
    uniform sampler2D sTexture; varying vec2 vTexCoord;
                         void main ()
                         {
            //  vec4 color  = texture2D (sTexture, vTexCoord);
            vec2 x =vTexCoord - vec2(0.5);
            float r = length(x);//radious
            float u = r*atan( vTexCoord.x/sqrt(r*r-(vTexCoord.x*vTexCoord.x )));
            float v = (r*vTexCoord.y)/sqrt(r*r );
            vec4 color   = texture2D(sTexture, vec2(u, v));
            gl_FragColor = color;
                         }");
    GL.CompileShader(fragShader);
}

希望对着色器代码的vTexCoord进行一些更改即可得到结果。

Answer 1

如果要将2D纹理投影到2D平面上（就像3D圆柱体一样），则必须通过arcus function（asin或acos变换纹理坐标）在片段着色器中。

必须使用asin函数将[0，1]范围内的纹理坐标与[-90°，90°]范围内的圆角关联。该角度可以线性映射到[0，1]范围内的新纹理坐标。

该函数的输入是一个角度，返回值是一个距离：

float u = asin( vTexCoord.x*2.0-1.0 ) / 3.141593 + 0.5;

顶点着色器：

attribute vec3 a_position;
varying vec2 vTexCoord;

void main()
{
    vTexCoord   = (a_position.xy + 1) / 2;
    gl_Position = vec4(a_position, 1);
}

片段着色器：

precision highp float;
uniform sampler2D sTexture;
varying vec2 vTexCoord;

void main()
{
    float u = asin( vTexCoord.x*2.0-1.0 ) / 3.141593 + 0.5;
    float v = vTexCoord.y; 

    vec4 color   = texture2D(sTexture, vec2(u, v));
    gl_FragColor = color;
}

查看原始代码的结果和使用asin映射的代码之间的区别：

在2D平面的投影中，圆柱的顶部和底部是ellipse，可以表示为：

float b = 0.3;
float y = b * sqrt(1.0 - x*x)

纹理的投影必须在顶部和底部被挤压以形成椭圆形：

float v_scale = (1.0 + b) / (1.0 + y);
float v = (pos.y * v_scale) * 0.5 + 0.5;

必须使用discard中的fragment shader关键字丢弃被裁剪的区域：

if ( v < 0.0 || v > 1.0 )
    discard;

查看没有椭圆形失真的结果和使用椭圆形失真的代码之间的区别：

结合了asin纹理坐标映射和椭圆形失真的片段着色器：

片段着色器：

precision highp float;
uniform sampler2D sTexture;
varying vec2 vTexCoord;

void main()
{
    vec2  pos     = vTexCoord.xy * 2.0 - 1.0;
    float b       = 0.3;
    float v_scale = (1.0 + b) / (1.0 + b * sqrt(1.0 - pos.x*pos.x));

    float u = asin( pos.x ) / 3.1415 + 0.5;
    float v = (pos.y * v_scale) * 0.5 + 0.5;
    if ( v < 0.0 || v > 1.0 )
        discard;

    vec3 texColor = texture2D( u_texture, vec2(u, v) ).rgb;
    gl_FragColor  = vec4( texColor.rgb, 1.0 );
}

组合结果：

如何投影openGL控件的顶部和底部区域

1 个答案: