Question

我正在尝试生成地图（原子）中不存在的新密钥，然后立即将其添加到地图中并返回该密钥。但是，密钥的检查和更新不是自动完成的。我想知道如何自动执行此操作，以确保并发安全。

理想情况下，此密钥足够短但难以猜测（因此用户可以创建会话，并且他/她的朋友可以加入该密钥）。所以0,1,2,3 ...并不理想，因为用户可以尝试输入会话n-1。像UUID之类的我不必担心冲突的东西也不理想。我正计划生成一个短随机字符串（例如“ udibwi”），但是我在下面的代码片段中使用了rand-int 25来简化问题。

我编写了一个函数，该函数随机生成一个密钥。它检查地图是否包含地图。如果已经存在，请尝试新的密钥。如果没有，请将其关联到我的地图，然后返回密钥。

这可行，但是我认为多线程是不安全的。有没有办法使用原子来做到这一点，还是有更好的办法？

(defonce sessions (atom {}))

(defn getNewSessionId []
  (let [id (rand-int 25)]
    (if (contains? @sessions id) 
      (createNewId) 
      (do 
        (swap! sessions assoc id "")
        id))))

Answer 1

您正尝试一次做太多事情。具有一个函数生成ID并更新原子会使事情变得复杂。我将其分解为三个功能：

基于现有地图生成ID的功能
使用上述功能更新纯净，不变地图的功能
一个更新原子的函数（尽管在实现前两个函数之后这将是如此简单，以至于根本没有必要）。

类似的东西：

; Notice how this doesn't deal with atoms at all
(defn generate-new-id [old-map]
  (let [new-id (rand-int 25)]
    (if (old-map new-id) ; or use "contains?"
      (recur old-map) ; Using "recur" so we don't get a StackOverflow
      new-id)))

; Also doesn't know anything about the atom
(defn assoc-new-id [old-map]
  (let [new-id (generate-new-id old-map)]
    (assoc old-map new-id "")))

(defonce data (atom {}))

(defn swap-new-id! []
  (swap! data assoc-new-id))

主要变化：

所有可以从原子交换逻辑中删除的东西都移到了自己的功能上。这样一来，您就可以将处理所有逻辑的函数传递给swap!，它将自动进行处理。
Clojure使用破折号而不是camelCase。
我使用了recur而不是实际的递归，因此在ID遭到强行使用时您不会得到StackOverflow。

当然，如果剩余可用ID数量很少，则会遇到问题。通过蛮力“查找”可用的ID可能要花费很长时间。您最好使用由atom支持的“生成器”生成原子地从0开始的ID：

(defn new-id-producer []
  (atom -1))

(defn generate-id [producer]
  (swap! producer inc)) ; "swap!" returns the new value that was swapped in

(let [producer (new-id-producer)]
 ; Could be run on multiple threads at once
 (doseq [id (repeatedly 5 #(generate-id producer))]
   (println id))) 
0
1
2
3
4
=> nil

我试图同时编写一个在多个线程上运行的示例：

(let [producer (new-id-producer)

      ; Emulate the "consumption" of IDs
      consume (fn []
                (doseq [id (repeatedly 20 #(generate-id producer))]
                  (println (.getId (Thread/currentThread)) id)))]

  (doto (Thread. consume)
        (.start))

  (doto (Thread. consume)
        (.start)))

37 0
3738 1
38 3
38 4
38 5
38 6
38 7
38 8
38 9
38 10
38 11
38 12
38 13
38 14
38 15
38 16
38 17
38 18
38 19
38 20
38 21
 2
37 22
37 23
37 24
37 25
37 26
37 27
37 28
37 29
37 30
37 31
37 32
37 33
37 34
37 35
37 36
37 37
37 38
37 39

但是打印到输出的不同步特性使输出变得一团糟。不过，如果斜视一下，您会发现线程（线程ID为37和38）正在轮流使用。

如果您需要返回新的ID，据我所知，唯一不涉及locking的简单方法是使用 second 原子从交换中获取返回的ID。功能。这需要摆脱assoc-new-id：

(defn generate-new-id [old-map]
  (let [new-id (rand-int 25)]
    (if (old-map new-id)
      (recur old-map)
      new-id)))

(defn swap-new-id! [old-map]
  (let [result-atom (atom nil)]

    (swap! data (fn [m]
                  (let [id (generate-new-id m)]
                    (reset! result-promise id) ; Put the ID in the result atom
                    (assoc m id ""))))

    @result-promise)) ; Then retrieve it here

或者，如果效率很低的解决方案很好，而您正在使用Clojure 1.9.0，则只需搜索地图即可找到使用clojure.set.difference添加的键：

(defn find-new-id [old-map new-map]
  (clojure.set/difference (set (keys new-map))
                          (set (keys old-map))))

(defn swap-new-id! []
  (let [[old-map new-map] (swap-vals! data assoc-new-id)] ; New in 1.9.0
    (find-new-id new-map old-map)))

但是，这又非常效率低下。每个地图需要两次迭代。

Answer 2

您能否以尝试这样做的原因来更新您的问题？几乎肯定有比您建议的更好的解决方案。

如果您真的想为地图生成唯一键，则有2个简单答案。

（1）对于协调键，可以使用atom来保存最后生成的键的整数。

(def last-map-key (atom 0))
(defn new-map-key (swap! last-map-key inc))

保证可以生成唯一的新地图密钥。

（2）对于不协调的键，请使用UUID as with clj-uuid/v1

（3）如果您确实坚持使用原始算法，则可以使用Clojure ref，但这是对它的预期目的的滥用。

Answer 3

您还可以存储有关哪个ID是原子中最后一个ID的信息。

(defonce data
  (atom {:sessions {}
         :latest-id nil}))

(defn generate-session-id [sessions]
  (let [id (rand-int 25)]
    (if (contains? sessions id)
      (recur sessions)
      id)))

(defn add-new-session [{:keys [sessions] :as data}]
  (let [id (generate-session-id sessions)]
    (-> data
        (assoc-in [:sessions id] {})
        (assoc :latest-id id))))

(defn create-new-session! []
  (:latest-id (swap! data add-new-session)))

如致癌物质所示，通过使用swap-vals!，它可以从之前和之后的状态衍生而来，但是保持周围状态更为简单。

如何自动检查地图中是否存在键，如果不存在则添加键

3 个答案: