Question

由于我一直在使用 kotlin-reflect 调用默认值并声明了一个默认值，所以我看到了第二个不同的构造函数。

我认识到两个不同的字段 int arg3 和 kotlin.jvm.internal.DefaultConstructorMarker arg4 添加到了我的构造函数。

data class Model(
    @SerializedName("xyz") val entity: String?,
    @SerializedName("abc") val id: Long? = null
)
val constructors = clazz.declaredConstructors // how I call the constructors

我的实际问题是为什么我要拥有这两个字段，其背后的逻辑是什么？

谢谢。

Answer 1

这两个参数被添加到Kotlin编译器为具有默认参数的所有函数和构造函数生成的特殊合成成员中。

借助Java反射，您可以通过检查isSynthetic()并查找不存在的函数来构造这些合成函数和构造函数。

整数参数是位掩码。当从Kotlin调用此类函数时，将生成位掩码并将其作为参数传递。这些位显示函数的哪些默认参数是传递的显式参数，哪些应使用默认值。

DefaultConstructorMarker参数用于确保合成构造函数（接受位掩码）与其他具有相同参数签名和最后一个Int签名的构造函数不发生冲突。传递给marker参数的参数不会被使用，它始终为null。

实际上，分别为每个函数或构造函数生成的两个方法或构造函数，至少具有一个默认参数：一个具有与声明的签名相同且没有其他参数的默认参数，另一个也接受位掩码和标记。

如果检查此类函数的字节码，则对于函数声明，您会发现大致如下：

fun foo(bar: String, baz: List<String> = emptyList(), qux: Set<String> = emptySet()) = 0

字节码中的实际方法是：

// access flags 0x19
// signature (Ljava/lang/String;Ljava/util/List<Ljava/lang/String;>;Ljava/util/Set<Ljava/lang/String;>;)I
// declaration: int foo(java.lang.String, java.util.List<java.lang.String>, java.util.Set<java.lang.String>)
public final static foo(
    Ljava/lang/String;
    Ljava/util/List;
    Ljava/util/Set;
)I
  // annotable parameter count: 3 (visible)
  // annotable parameter count: 3 (invisible)
  @Lorg/jetbrains/annotations/NotNull;() // invisible, parameter 0
  @Lorg/jetbrains/annotations/NotNull;() // invisible, parameter 1
  @Lorg/jetbrains/annotations/NotNull;() // invisible, parameter 2
L0
  ALOAD 0
  LDC "bar"
  INVOKESTATIC kotlin/jvm/internal/Intrinsics.checkParameterIsNotNull (Ljava/lang/Object;Ljava/lang/String;)V
  ALOAD 1
  LDC "baz"
  INVOKESTATIC kotlin/jvm/internal/Intrinsics.checkParameterIsNotNull (Ljava/lang/Object;Ljava/lang/String;)V
  ALOAD 2
  LDC "qux"
  INVOKESTATIC kotlin/jvm/internal/Intrinsics.checkParameterIsNotNull (Ljava/lang/Object;Ljava/lang/String;)V
L1
  LINENUMBER 16 L1
  ICONST_0
  IRETURN
L2
  LOCALVARIABLE bar Ljava/lang/String; L0 L2 0
  LOCALVARIABLE baz Ljava/util/List; L0 L2 1
  LOCALVARIABLE qux Ljava/util/Set; L0 L2 2
  MAXSTACK = 2
  MAXLOCALS = 3

生成的处理位掩码并在必要时计算默认值的包装器是一个单独的方法：

// access flags 0x1009
public static synthetic foo$default(
    Ljava/lang/String;
    Ljava/util/List;
    Ljava/util/Set;
    I
    Ljava/lang/Object;
)I
  ILOAD 3
  ICONST_2
  IAND
  IFEQ L0
L1
  LINENUMBER 16 L1
  INVOKESTATIC kotlin/collections/CollectionsKt.emptyList ()Ljava/util/List;
  ASTORE 1
L0
  ILOAD 3
  ICONST_4
  IAND
  IFEQ L2
  INVOKESTATIC kotlin/collections/SetsKt.emptySet ()Ljava/util/Set;
  ASTORE 2
L2
  ALOAD 0
  ALOAD 1
  ALOAD 2
  INVOKESTATIC FooKt.foo (Ljava/lang/String;Ljava/util/List;Ljava/util/Set;)I
  IRETURN
  MAXSTACK = 3
  MAXLOCALS = 5

请注意后者如何检查位掩码（使用ILOAD 3，ICONST_x，IAND）然后有条件地（当IFEQ Lx不跳过它时）评估默认值争论。

构造函数与普通函数的不同之处在于它们的名称中不能带有后缀$default，因此标记是必需的，以避免可能的签名冲突。

Kotlin中默认构造函数中的两个其他类型？

1 个答案: