Question

我正在为Access窗体中的按钮编写VBA代码。我希望用户插入的信息可以将新记录添加到特定的表Funcionario中。当我仅将数据插入必填字段时，如果启用了以下代码行，则会收到错误消息：

Observacoes = Me.Observacoes.Value

错误显示Invalid use of Null。

这是我正在处理的完整代码：

Private Sub new_func_Click()

    Dim Id_Funcionario As Integer
    Dim Primeiro_Nome, Ultimo_Nome, NIF, Sexo, Morada, Localidade, Email, Contacto, Foto, Observacoes As String
    Dim Data_Nascimento, Data_contrato_i, Data_contrato_f As Date

    Id_Funcionario = Me.Id_Funcionario.Value
    Primeiro_Nome = Me.Primeiro_Nome.Value
    Ultimo_Nome = Me.Ultimo_Nome.Value
    NIF = Me.NIF.Value
    Data_Nascimento = Me.Data_Nascimento.Value
    Sexo = Me.Sexo.Value
    Morada = Me.Morada.Value
    Localidade = Me.Localidade.Value
    Email = Me.Email.Value
    Contacto = Me.Contacto.Value
    Data_contrato_i = Me.Data_contrato_i.Value
    Observacoes = Me.Observacoes.Value
    Foto = Me.Foto.Value
    Data_contrato_f = ""

    'If IdFunc, NIF and Data_contrato_i empty:

    If IsNull(Me.Id_Funcionario.Value) = True Or IsNull(Me.NIF.Value) = True Or IsNull(Me.Data_contrato_i.Value) = True Then
        MsgBox "Please insert data in the required fields", vbExclamation, "Warning"
    Else
        DoCmd.RunSQL "INSERT INTO Funcionario (Id_Funcionario, Primeiro_Nome, Ultimo_Nome, NIF, Data_Nascimento, Sexo, Morada, Localidade, Email, Contacto, Data_contrato_i, Data_contrato_f, Observacoes, Foto) VALUES ('" & Id_Funcionario & "', '" & Primeiro_Nome & "', '" & Ultimo_Nome & "', " & NIF & ", '" & Data_Nascimento & "', '" & Sexo & "', '" & Morada & "', '" & Localidade & "', '" & Email & "', '" & Contacto & "', '" & Data_contrato_i & "', '" & Data_contrato_f & "', '" & Observacoes & "', '" & Foto & "')"
    End If
End Sub

有人可以帮我吗？我不知道我在做什么错，谢谢。

Answer 1

此行

Dim Primeiro_Nome, Ultimo_Nome, NIF, Sexo, Morada, Localidade, Email, Contacto, Foto, Observacoes As String

仅将Observacoes声明为String，其他所有变量均为Variants。要将它们全部作为字符串，应使用：

Dim Primeiro_Nome As String, Ultimo_Nome As String,....

Variant可以包含Null值，而String不能包含值。

您可以将行更改为：

Observacoes = NZ(Me.Observacoes.Value,"")

，它将用空字符串替换Null值。

接受答案后编辑：

@Erik使用parameters进行了评论，使整个过程变得更加简单。以下代码中的参数是MyID和MyPrimeiro，但是您可以在参数名称中使用几乎任何文本。

Private Sub new_func_Click()

    If IsNull(Me.Id_Funcionario) Or IsNull(Me.Primeiro_Nome) Then
        MsgBox "Please insert data in the required fields.", vbOKOnly + vbExclamation, "Warning"
    Else
        With CurrentDb.CreateQueryDef("", _
            "PARAMETERS MyID LONG, MyPrimeiro TEXT(255); " & _
            "INSERT INTO Funcionario (Id_Funcionario, Primeiro_Nome) VALUES (MyID, MyPrimeiro)")

            .Parameters("MyID") = Me.Id_Funcionario
            .Parameters("MyPrimeiro") = Me.Primeiro_Nome
            .Execute

        End With
    End If

End Sub

访问-VBA无效使用null

1 个答案: