Question

我有一个谓词，它将模态逻辑公式与其否定范式相关联。除模态运算符，并词和析取词外的所有连接词都将被消除，并且将否定词尽可能推入表达式的叶子。

rewrite/2谓词有一个包罗万象的子句rewrite(A, A).，在文本上是最后一个。有了这个包罗万象的条款，就可以提取否定范式的公式。在此示例中，e是类似于Łukasiewicz表示法的双条件连接词，并且4和7是模态逻辑中的变量（因此是Prolog常数）。

Z与公式统一为负范式。

?- rewrite(e(4, 7), Z).
Z = a(k(4, 7), k(n(4), n(7)))

但是，rewrite(<some constant>, <some constant>)总是会成功，但我希望它不会成功。包罗万象的条款实际上应该是包罗万象的，而不是如果适用其他条款可能会触发的东西。

?- rewrite(e(4, 7), e(4, 7)).
true.

我尝试用受保护的版本替换rewrite(A, A).：

wff_shallowly(WFF) :-
  WFF = l(_);
  WFF = m(_);
  WFF = c(_, _);
  WFF = f;
  WFF = t;
  WFF = k(_, _);
  WFF = a(_, _);
  WFF = n(_);
  WFF = e(_, _).

rewrite(A, A) :- \+ wff_shallowly(A).

我认为，如果且仅当 A不是由具有特殊含义的原子/构造函数作为首字母时，这会阻止catch-all子句适用。但是，进行更改后，rewrite如果递归调用，总是会失败。

?- rewrite(4, Z).
Z = 4.

?- rewrite(c(4, 7), Z).
false.

设置catch all子句的正确方法是什么。

✱程序全文供参考：

% so the primitive connectives are
% l <-- necessity
% m <-- possibility
% c <-- implication
% f <-- falsehood
% t <-- truth
% k <-- conjunction
% a <-- alternative
% n <-- negation
% e <-- biconditional

wff_shallowly(WFF) :-
  WFF = l(_);
  WFF = m(_);
  WFF = c(_, _);
  WFF = f;
  WFF = t;
  WFF = k(_, _);
  WFF = a(_, _);
  WFF = n(_);
  WFF = e(_, _).

% falsehood is primitive
rewrite(f, f).

% truth is primitive
rewrite(t, t).

% positive connectives
rewrite(a(A, B), a(C, D)) :- rewrite(A, C), rewrite(B, D).
rewrite(k(A, B), k(C, D)) :- rewrite(A, C), rewrite(B, D).
rewrite(l(A), l(C)) :- rewrite(A, C).
rewrite(m(A), m(C)) :- rewrite(A, C).

% implication
rewrite(c(A, B), a(NC, D)) :-
  rewrite(n(A), NC), rewrite(B, D).

% biconditional
rewrite(e(A, B), a(k(C, D), k(NC, ND))) :-
  rewrite(A, C),
  rewrite(n(A), NC),
  rewrite(B, D),
  rewrite(n(B), ND).

% negated falsehood is truth
rewrite(n(f), t).

% negated truth is falsehood
rewrite(n(t), f).

% double negation elimination
rewrite(n(n(A)), C) :- rewrite(A, C).

% negated alternation
rewrite(n(a(A, B)), k(NC, ND)) :-
  rewrite(n(A), NC), rewrite(n(B), ND).

% negated conjunction
rewrite(n(k(A, B)), a(NC, ND)) :-
  rewrite(n(A), NC), rewrite(n(B), ND).

% negated biconditional
rewrite(n(e(A, B)), a(k(C, ND), k(NC, D))) :-
  rewrite(A, C),
  rewrite(n(A), NC),
  rewrite(B, D),
  rewrite(n(B), ND).

% negated necessity
rewrite(n(l(A)), m(NC)) :- rewrite(n(A), NC).

% negated possibility
rewrite(n(m(A)), l(NC)) :- rewrite(n(A), NC).

% catch all, rewrite to self
rewrite(A, A) :- \+ wff_shallowly(A).

Answer 1

如果您使用数据的 clean 表示，这些问题都会消失。

在这种情况下，这意味着您应完全类似于通过不同的 functors 系统地表示所有其他实体的方式，还应使用专用的函子来表示（模态）变量< / em>。

例如，让我们使用函子v/1来表示变量。这意味着我们使用v(1)，v(7)等来表示模式变量1、7等。

我添加以下子句来说明模态变量的含义，而不是“ catch all”子句：

% (negated) variable rewrite(n(v(V)), n(v(V))). rewrite(v(V), v(V)).

现在我们得到：

?- rewrite(e(v(4), v(7)), Z). Z = a(k(v(4), v(7)), k(n(v(4)), n(v(7)))).

请注意，我们当然必须在查询中使用v/1包装器，并在答案中获取包装器。与不存在包装器的情况相比，这更难读写。但是，这样使推理更加容易，因此我强烈建议使用它。

这是在此类公式与您当前使用的 defaulty 表示形式之间进行转换的直接方法。之所以将其称为“默认”，是因为它需要 default （“全部捕获”）情况，也因为它被认为是故障。优良作法是尽快消除此类表示形式，然后围绕清晰的表示形式编写主要逻辑。

简洁的表示形式对通用性和效率都有好处：您的Prolog系统的自变量索引现在可以通过第一个自变量的主要函子将所有子句区分开，从而提高了性能。完全实例化该参数的重要用例（例如，在您发布的示例中）。

prolog捕获仅在没有其他子句的情况下才是活动的所有子句

1 个答案: