Question

我编写了以下函数，该函数从sql表中获取数据。

get_sql_table:{[usr;psswd;server;db;tbl]
    usr: "'", usr, "'";
    psswd: "'", psswd, "'";
    new_tbl: "'", tbl, "'\"";
    map:(`date`datetime`bigint`char`decimal`double`int`varchar)!("DZJCFFIS");
    schema:exec column_name!native from (update native:map[data_type] from (2#"S";enlist"\t") 0: 
        schema:system "mysql --user=",usr," --password=",psswd," -h ",server, " ", db, " --execute=\"select column_name, data_type from information_schema.columns WHERE table_name = ", new_tbl) 
        where not null native;
    query: system "mysql --user=",usr," --password=",psswd," -h ",server, " ", db, " --execute=\"select * from ", tbl, ";\"";
    data:(count["\t" vs query 0]#"S";enlist"\t") 0: query;
    :![data;();0b;k!{($;schema[x];(string;x))} each k:key[schema] inter cols data];
 };

当我加载脚本并尝试运行该函数时，有时会在最后一行（return语句）出现类型错误。最后一行用于将适当的数据类型映射到kdb表。

但是，代码有时会成功。看来成功和失败的表是任意的，并且与列类型无关（实际上，在成功之前的表上失败，反之亦然）。

此外，代码本身没有错。当我在函数外部编写代码时，它每次都可以工作，但表的数据类型不在map中（但在这种情况下，我可以将其添加到map中）。 仅当代码包装在函数中时，该代码才会失败。

我想念什么？

Answer 1

您的schema变量是在函数中定义的，而不是全局定义的，因此无法在此lambda中进行访问

{($;schema[x];(string;x))}

您必须像这样传递它

{($;y[x];(string;x))}[;schema] each k:key[schema] inter cols data

它可能已在函数外部起作用，因为您意外地全局定义了schema

KDB-将工作代码包装在函数中时出错

1 个答案: